Domino 9 und frühere Versionen > ND8: Administration & Userprobleme

Ansicht auf Posteingang und Feldabfrage

<< < (4/4)

ascabg:

--- Zitat von: Peter Klett am 19.11.10 - 13:45:41 ---
--- Zitat von: ascabg am 19.11.10 - 13:33:07 ---Hallo,

Peter,
Ich glaube die Funktion, auf die Du Dich beziehst ist @WhichFolder.

Diese Funktioniert jedoch nur, soweit ich mich noch daran erinnern kann, in Ansichten.

Fuer das was Judith123 haben moechte, gibt es aus meiner sich so schnell keine einfache Loesung.
So wie ich sie verstanden habe, moechte sie alle Dokumente angezeigt bekommen, die NUR im Posteingang sich befinden und bei denen das Feld "Categories" leer ist.

Woran erkenne ich nun, dass sich die Mail nur im Posteingang befindet?


Andreas

--- Ende Zitat ---
Ist die Inbox nicht auch ein Ordner?

--- Ende Zitat ---
@Peter
Ich habe mich etwas ungluecklich ausgedrueckt.

Die von mir genannte Formel kann nur zur Anzeige in einer Spelate verwendet werden, nicht jedoch in SELECT-Formeln fuer die Anzeige von Daten.

Andreas

Peter Klett:
Hallo Andreas,

das hatte ich bald vermutet, aber dann muss man damit ja zumindest eine kategorisiert angezeigte Spalte hinbekommen.

M.E. ist die ganze Anforderung bei einigermaßen sinnvoller Nutzung der Maildatenbank durch Organisation der Mails in Ordnern hinfällig, außer wenn die Mails schon vom Absender kategorisiert sind (davon steht jedoch nichts in der gesamten Diskussion), aber dann läßt sich mit Regeln sicherlich auch etwas bewerkstelligen.

Ich habe den Eindruck, dass hier eine Arbeitsweise, die in Outlook bisher praktiziert wurde, auf Notes exakt gleich übertragen werden soll, ohne darüber nachzudenken, wie man das vorliegende "Problem" mit Notesmitteln bewältigen könnte. Manchmal muss man bei anderen Werkzeugen auf Ähnliches zurückgreifen, wenn es das Gleiche nicht gibt.

Judith123:
Naja, scheinbar ist es doch in 2,5 sek. auch von jemanden der Notes kennt nicht erledigt, denn es gibt ja (für mich) keine praktikable Lösung.

Ein Ordner-System nutze ich zur Ablage. Mit Kategorien arbeite ich um E-Mails bestimmten Aufgaben zuzuordnen. D.h. ich benötige beides und Kategorien lassen sich (in meinem Fall) nicht durch Ordner ersetzen.

Ich habe das mal probiert, ist jedoch absolut unübersichtlich.

Aber vielen Dank für die Versuche.

Peter Klett:
Du hast leider recht, in 2,5 Sekunden schaffe ich es auch nicht. Habe es nun selbst ausprobiert. Die Funktion @WhichFolders funktioniert nur in nicht kategorisierten Spalten (würde mich sehr interessieren, bei welcher Betriebsfeier die das Ding hingefrickelt haben).

Mein Lösungsvorschlag lautet daher:

Erstelle Dir einen eigenen Ordner

In diesem Ordner erstellst Du eine Aktion, die folgendes LotusScript ausführt (Du musst nur den Namen Deines Ordners anpassen):

Sub Click(Source As Button)
   Const meinordner = "MeinOrdner"
   Const inbox = "($Inbox)"
   
   Dim session As New NotesSession
   Dim db As NotesDatabase
   Set db = session.CurrentDatabase
   Dim viewmeinordner As NotesView
   Set viewmeinordner = db.GetView (meinordner)
   Dim viewinbox As NotesView
   Set viewinbox = db.GetView (inbox)
   Dim doc As NotesDocument
   Dim liste List As Integer
   
   'Alle Dokumente im Ordner merken
   Set doc = viewmeinordner.GetFirstDocument
   Do While Not doc Is Nothing
      liste (doc.UniversalID) = 1
      Set doc = viewmeinordner.GetNextDocument (doc)
   Loop
   
   'Alle Dokumente aus Inbox ohne Kategorie in meinordner verschieben, falls nicht enthalten
   Set doc = viewinbox.GetFirstDocument
   Do While Not doc Is Nothing
      If doc.Categories (0) = "" Then
         If Iselement (liste (doc.UniversalID)) Then
            Erase liste (doc.UniversalID)
         Else
            Call doc.PutInFolder (meinordner, False)
         End If
      End If
      Set doc = viewinbox.GetNextDocument (doc)
   Loop
   
   'Überflüssige Dokumente aus meinordner entfernen
   Forall l In liste
      Set doc = db.GetDocumentByUnid (Listtag (l))
      Call doc.RemoveFromFolder (meinordner)
   End Forall
End Sub

Zum Aktualisieren des Ordners startest Du dann die Aktion.

Judith123:
Wahnsinn! Ich brech ab! Es geht!

Du bist mein absoluter Held und ich verspreche heute auch einen ganzen Tag nicht über Notes zu meckern ;-)

Nein also im Ernst: Vielen, vielen herzlichen Dank. So kann ich meine E-Mails im Überblick beahlten und effektiv arbeiten ohne jede drucken zu müssen.

Navigation

[0] Themen-Index

[*] Vorherige Sete