Gruppen kopieren aus altem names.nsf?

[jimmyone]

Hallo zusammen,

ich habe hier einen 7er Server, der komplett abgelöst wird... Ich kann keinen zusätzlichen Server aufnehmen, weil man irgendwie (nicht ich) an dem names.nsf rum geschraubt hat.
Ich habe mir dazu auch einen IBM Partner kommen lassen, der hat sich das ganze angeschaut und hat dann gemeint, aufgrund der Fehler die wir haben, das ganze wirklich einmal von vorne auf Basis der bestehenden Certifier IDs und Dokumente neu aufzusetzen und dann die Finger vom names.nsf und besonders von der admin4.nsf zu lassen... Er hat das auch angeboten inkl. Übernahme aus altem Verzeichnis ins neue, aber naja...

Benutzer verschieben etc. klappt ganz gut, mit ein paar Dummy Usern...
Was ich gerne wissen würde, wenn ich aus dem aktuellen names.nsf die Gruppen quasi per Copy & Paste rüberschiebe ob es da Probleme gibt.

Weil immer wenn ich das mache, dann stürtzt der Domino Admin Client ab.
Nach einem restart ist die Gruppe aber da inkl. der Benutzer und ich kann auch zugreifen und diese verändern bzw. anpassen...

Also kann man das so wohl so machen?

Gruß,
Jimmy

[Axel]

Weil immer wenn ich das mache, dann stürtzt der Domino Admin Client ab.
Nach einem restart ist die Gruppe aber da inkl. der Benutzer und ich kann auch zugreifen und diese verändern bzw. anpassen...

Das ist ein Problem im 8.5.2er Template pubnames.ntf.

The Public Address Book template, released with 8.5.2, caused the problem with cut and paste operations within the Public Address Book. The agent (RenamePastedAccounts) creates an infinite loop which can only be terminated by using pressing the Control+Break keys.

...
   While Not doc Is Nothing
      If doc.getitemvalue(TYPE_FIELD)(0) = ACCT_TYPE Then
         strName = doc.getitemvalue(ACCT_NAME)(0)
         Call doc.ReplaceItemValue(ACCT_NAME, str1 + strName)
         Call doc.save(True, False)
         Set doc = dc.getnextdocument(doc)
      End If
   Wend
End Sub

Move the line “Set doc = dc.getnextdocument(doc)” out of the IF statement (as in the example below)

%REM
   Agent RenamePastedAccounts
   Created Mar 29, 2010 by Ana Kapetanakis/Westford/IBM
   Description: Comments for Agent
%END REM
Option Public
Option Declare

'Begin DNT
Const ACCT_NAME = "AccountName"
Const ACCT_TYPE = "Account"
Const TYPE_FIELD = "Type"
'End DNT
Sub Initialize
   Dim ws As New NotesUIWorkspace
   Dim uidb As NotesUIDatabase
   Dim db As NotesDatabase
   Dim dc As NotesDocumentCollection
   Dim doc As NotesDocument
   Dim strName As String
   Dim str1, str2 As String
   
   str1 = "Copy of "
   
   Set uidb = ws.currentdatabase
   Set db = uidb.Database
   Set dc = db.UnprocessedDocuments
   Set doc = dc.getfirstdocument
   While Not doc Is Nothing
      If doc.getitemvalue(TYPE_FIELD)(0) = ACCT_TYPE Then
         strName = doc.getitemvalue(ACCT_NAME)(0)
         Call doc.ReplaceItemValue(ACCT_NAME, str1 + strName)
         Call doc.save(True, False)
      End If
      Set doc = dc.getnextdocument(doc)
   Wend
End Sub

Ich denke schon, dass du die Gruppen per Copy&Paste übernehmen kannst.

Axel
 
Axel

[jimmyone]

...Danke für den Hinweis.