Autor Thema: [Fixed] Lx client: "Zuweisen" -> Fehler  (Gelesen 13513 mal)

Offline Dr.Domino

  • Senior Mitglied
  • ****
  • Beiträge: 287
  • Geschlecht: Männlich
  • LN since 1996 ...
[Fixed] Lx client: "Zuweisen" -> Fehler
« am: 09.11.06 - 13:46:16 »
Hallo,
im Linux Client läßt sich ein Ticket unter 1.5.1 nicht zuweisen:
- es wird noch die Auswahl der Supporter angezeigt
- nach Auswahl eines Supporters aber:
  a) in der Statuszeile: CHECKANDEVALUATE: 48 on line 30: Error in loading DLL
  b) Notes-Popup: Variant does not contain a container
- im Windoofs-Client funktioniert's ganz normal
« Letzte Änderung: 09.11.06 - 15:11:32 von Dr.Domino »
VG,
Markus

IBM Domino 9.0.1, Lotus Domino 8.5.3 (QuickR), CentOS 6, Win64)

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: Lx client: "Zuweisen" -> Fehler
« Antwort #1 am: 09.11.06 - 13:50:41 »
Zitat
Error in loading DLL

Linux kennt keine DLL ;-)
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline Dr.Domino

  • Senior Mitglied
  • ****
  • Beiträge: 287
  • Geschlecht: Männlich
  • LN since 1996 ...
Re: Lx client: "Zuweisen" -> Fehler
« Antwort #2 am: 09.11.06 - 13:53:46 »
Ja, schon klar ... nur für die nächste Version könnte man das vielleicht mal "angehen", was auch immer er da macht und das vielleicht umgehen.
VG,
Markus

IBM Domino 9.0.1, Lotus Domino 8.5.3 (QuickR), CentOS 6, Win64)

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: Lx client: "Zuweisen" -> Fehler
« Antwort #3 am: 09.11.06 - 13:57:39 »
Da könntest du vlt. aushelfen.

Wir greifen an der Stelle auf Notes Api Call zu. die liegen in der Declare Function NSFFormulaCompile Lib "nnotes.dll" ( _

Wie heißt die datei unter LINUX? ist das nnotes.so?

wenn das so ist, kannst du das in der lib.Notes.API LS Bibliothek ja mal ändern und sehen, ob es funktioniert ...
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: Lx client: "Zuweisen" -> Fehler
« Antwort #4 am: 09.11.06 - 14:04:05 »
"libnotes.so" heisst das unter Linux
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline Dr.Domino

  • Senior Mitglied
  • ****
  • Beiträge: 287
  • Geschlecht: Männlich
  • LN since 1996 ...
Re: Lx client: "Zuweisen" -> Fehler
« Antwort #5 am: 09.11.06 - 15:04:56 »
Funktioniert einwandfrei ... jetzt müßte man in der Lib.appl.NotesAPI
nur noch irgendwie nach OS des Clients das Eine oder das Andere
schalten ...
VG,
Markus

IBM Domino 9.0.1, Lotus Domino 8.5.3 (QuickR), CentOS 6, Win64)

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: Lx client: "Zuweisen" -> Fehler
« Antwort #6 am: 09.11.06 - 15:07:13 »
Zitat
Funktioniert einwandfrei
Prima  :D

Zitat
jetzt müßte man in der Lib.appl.NotesAPI
nur noch irgendwie nach OS des Clients das Eine oder das Andere
schalten ...

Das ist kein Problem; bin schon dabei, das zu coden ...
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #7 am: 09.11.06 - 15:16:12 »
ok, dann ersetze mal den bestehenden Code durch folgenden

Code
'Lib.appl.NotesAPI: 

'lib.appl.NotesAPI: 

Option Public

Const NULLHANDLE = 0
Const NO_ERROR = 0
Const ERR_FORMULA_COMPILATION = &h500 + 1

' ================================================================================
' CheckSelectionFormulaValid - This function uses the Lotus C API to check thesyntax of a Notes formula.
'
' Return Value: Variant - A 3 elements array containing:
' Index 0 - The compilation error code or NO_ERROR (0) if valid
' Index 1 - The compilation error offset in formula or NO_ERROR if valid 
' Index 2 - The compilation error length or NO_ERROR if valid
'
' Note: The compilation error code at Index 0 can then be passed to GetAPIError () to get more info about the error.
' ================================================================================
' ================================================================================
' GetAPIError - This function uses the Lotus C API to return a Notes error's text message.
'
' Return Value: String - The text associated with the Notes API error code.
' ================================================================================



Declare Function NSFFormulaCompile Lib "nnotes.dll" ( _
Byval FormulaName As Long, _
Byval FormulaNameLength As Integer, _
Byval FormulaText As Lmbcs String, _
Byval FormulaTextLength As Integer, _
rethFormula As Long, _
retFormulaLength As Integer, _
retCompileError As Integer, _
retCompileErrorLine As Integer, _
retCompileErrorColumn As Integer, _
retCompileErrorOffset As Integer, _
retCompileErrorLength As Integer _
) As Integer
Declare Sub OSMemFree Lib "nnotes.dll" (Byval hHandle As Long)
Declare Function OSLoadString Lib "nnotes.dll" ( _
Byval hmodule As Long, _
Byval status As Integer, _
Byval s As String, _
Byval slen As Integer _
) As Integer

Declare Function LX_NSFFormulaCompile Lib "libnotes.so" Alias "NSFFormulaCompile" ( _
Byval FormulaName As Long, _
Byval FormulaNameLength As Integer, _
Byval FormulaText As Lmbcs String, _
Byval FormulaTextLength As Integer, _
rethFormula As Long, _
retFormulaLength As Integer, _
retCompileError As Integer, _
retCompileErrorLine As Integer, _
retCompileErrorColumn As Integer, _
retCompileErrorOffset As Integer, _
retCompileErrorLength As Integer _
) As Integer

Declare Sub LX_OSMemFree Lib "libnotes.so" Alias "OSMemFree" (Byval hHandle As Long)

Declare Function LX_OSLoadString Lib "libnotes.so" Alias "OSLoadString" ( _
Byval hmodule As Long, _
Byval status As Integer, _
Byval s As String, _
Byval slen As Integer _
) As Integer

Sub Initialize
	
End Sub
Function CheckSelectionFormulaValid(sFormula) As Variant
	
	Dim iError As Integer
	Dim hFormula As Long
	Dim wFormulaLen As Integer
	Dim iCompileError As Integer
	Dim iCompileErrorLine As Integer
	Dim iCompileErrorColumn As Integer
	Dim iCompileErrorOffset As Integer
	Dim iCompileErrorLength As Integer
	Dim iArray(2) As Integer
	
	If get_platform = "w32" Then
		iError = NSFFormulaCompile(0, 0, _
		sFormula, _
		Len(sFormula), _
		hFormula, _
		wFormulaLen, _
		iCompileError, _
		iCompileErrorLine, _
		iCompileErrorColumn, _
		iCompileErrorOffset, _
		iCompileErrorLength)
		
	Else
		
		iError = LX_NSFFormulaCompile(0, 0, _
		sFormula, _
		Len(sFormula), _
		hFormula, _
		wFormulaLen, _
		iCompileError, _
		iCompileErrorLine, _
		iCompileErrorColumn, _
		iCompileErrorOffset, _
		iCompileErrorLength)
		
	End If
	
	If hFormula <> NULLHANDLE Then
		If get_platform = "w32" Then
			Call OSMemFree(hFormula)
		Else
			Call LX_OSMemFree(hFormula)
		End If
	End If
	
	If iError = ERR_FORMULA_COMPILATION Then
		iArray(0) = iCompileError
		iArray(1) = iCompileErrorOffset
		iArray(2) = iCompileErrorLength
		CheckSelectionFormulaValid = iArray
	Else
		iArray(0) = NO_ERROR
		iArray(1) = NO_ERROR
		iArray(2) = NO_ERROR
		CheckSelectionFormulaValid = iArray
	End If
	
End Function
Function GetAPIError(iErrorCode As Integer) As String
	
	Dim iRetVal As Integer
	Dim sError As String * 1024
	
	sError = String(1024, 0)
	
	iRetVal = OSLoadString(0&, iErrorCode, sError, 1023)
	
	If iRetval <> 0 Then
		GetApiError = Left$(sError, iRetVal)
	End If
	
End Function
Function get_platform () As String
	
	Dim tmp_platform As Variant
	Dim lower_platform As String
	tmp_platform = Evaluate(|@Implode(@Platform([Specific]);" ")|)
	
	lower_platform = Lcase(Cstr(tmp_platform(0)))
	
REM Messagebox Cstr(tmp_platform(0))
	
	If (Instr (lower_platform, "aix")) Then
		get_platform = "aix"
	Elseif (Instr (lower_platform, "solaris")) Then
		get_platform = "solaris"
	Elseif (Instr (lower_platform, "linux")) Then
		get_platform = "linux"
	Elseif (Instr (lower_platform, "win")) Then
		get_platform = "w32"
	Elseif (Instr (lower_platform, "mac")) Then
		get_platform = "mac"
	Else 
		Messagebox "Unsupported Platform : >" + lower_platform + "<"
		get_platform = ""
	End If
End Function

Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline Dr.Domino

  • Senior Mitglied
  • ****
  • Beiträge: 287
  • Geschlecht: Männlich
  • LN since 1996 ...
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #8 am: 09.11.06 - 15:26:49 »
Super - jetzt funktionieren beide Welten ... ääh, die ersten
beiden - fehlen noch die Tester für MacOS, AIX, Solaris ...

 ;D
VG,
Markus

IBM Domino 9.0.1, Lotus Domino 8.5.3 (QuickR), CentOS 6, Win64)

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #9 am: 09.11.06 - 15:30:49 »
wenn das gewünscht wird ... kein Problem
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline Dr.Domino

  • Senior Mitglied
  • ****
  • Beiträge: 287
  • Geschlecht: Männlich
  • LN since 1996 ...
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #10 am: 09.11.06 - 15:32:28 »
Vielen Dank für die fixe Hilfe, Ulrich - wenn Du mal wieder was Lx-mäßiges zu testen hast, ich hab immer nen Client für Dich am Rennen :knuddel:  :o  ;D
VG,
Markus

IBM Domino 9.0.1, Lotus Domino 8.5.3 (QuickR), CentOS 6, Win64)

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #11 am: 09.11.06 - 15:33:08 »
MAC = "NotesLib"
SOLARIS = libnotes.so
AIX = libnotes_r.a
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #12 am: 09.11.06 - 15:35:47 »
Zitat
wenn Du mal wieder was Lx-mäßiges zu testen hast, ich hab immer nen Client für Dich am Rennen
Besten Dank, ich komme drauf zurück ...
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #13 am: 12.11.06 - 16:45:21 »
Ich habe jetzt aus den core libs alle Verweise auf Windows API durch Notes API Calls ersetzt. Damit sollte die Anwendung jetzt unter WIN, LINUX und auf dem MAC laufen.

Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline I.h.a.D.

  • Frischling
  • *
  • Beiträge: 22
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #14 am: 24.06.10 - 11:20:46 »
Hallo,

ein Kollege hat jetzt einen Mac-Rechner erhalten (Mac OS 10.6.4).

Bei uns wird die HELP123 in Version 1.6 eingesetzt.

Der in diesem Thread beschriebene Fehler tritt bei Ihm auf.

Was muss ich wo tun, damit der Fehler behoben wird?

Offline Tim Pistor

  • Aktives Mitglied
  • ***
  • Beiträge: 229
  • Geschlecht: Männlich
    • www.pistor.is - Tim Pistor IT-Beratung
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #15 am: 24.06.10 - 16:43:04 »
Was muss ich wo tun, damit der Fehler behoben wird?

Ich hab keine Ahnung vom MAC aber hast du die in diesem Thread beschrieben Problemlösung schon
versucht?

MAC = "NotesLib"
SOLARIS = libnotes.so
AIX = libnotes_r.a


Offline I.h.a.D.

  • Frischling
  • *
  • Beiträge: 22
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #16 am: 24.06.10 - 17:18:33 »
Was muss ich wo tun, damit der Fehler behoben wird?

Ich hab keine Ahnung vom MAC aber hast du die in diesem Thread beschrieben Problemlösung schon
versucht?

MAC = "NotesLib"
SOLARIS = libnotes.so
AIX = libnotes_r.a



Ich muss leider gestehen, dass ich nicht weiß was und wo diese Problemlösung angewendet wird  :(

Offline I.h.a.D.

  • Frischling
  • *
  • Beiträge: 22
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #17 am: 25.06.10 - 10:13:13 »
Hallo,

kann mir jemand sagen wo und wie ich etwas einbauen muss, damit der Kollege die Funktion auf dem Mac nutzen kann?
Ich bin leider kein Entwickler und habe mit Notes nur noch am Rande was zu tun.

Danke.

Gruß
I.h.a.D.

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #18 am: 25.06.10 - 11:03:35 »
Du musst die ScriptLib lib.appl.NotesAPI entsprechend abändern.

Deklaration
Code
Declare Function NEMGetFile Lib "nnotesws" ( wUnk As Integer, Byval szFileName As String, Byval szFilter As String, Byval szTitle As String ) As Integer 
Declare Function LX_NEMGetFile Lib "libnotes.so" Alias "NEMGetFile"( wUnk As Integer, Byval szFileName As String, Byval szFilter As String, Byval szTitle As String ) As Integer 
Declare Function MAC_NEMGetFile Lib "NotesLib" Alias "NEMGetFile"( wUnk As Integer, Byval szFileName As String, Byval szFilter As String, Byval szTitle As String ) As Integer 
Declare Function NEMPutFile Lib "nnotesws" ( wHandle As Integer, Byval szFileName As String, Byval szFilter As String, Byval szTitle As String ) As Integer
Declare Function LX_NEMPutFile Lib "libnotes.so" Alias "NEMPutFile" ( wHandle As Integer, Byval szFileName As String, Byval szFilter As String, Byval szTitle As String ) As Integer
Declare Function MAC_NEMPutFile Lib "NotesLib" Alias "NEMPutFile" ( wHandle As Integer, Byval szFileName As String, Byval szFilter As String, Byval szTitle As String ) As Integer

' WIN
Declare Function NSFFormulaCompile Lib "nnotes.dll" ( _
Byval FormulaName As Long, _
Byval FormulaNameLength As Integer, _
Byval FormulaText As Lmbcs String, _
Byval FormulaTextLength As Integer, _
rethFormula As Long, _
retFormulaLength As Integer, _
retCompileError As Integer, _
retCompileErrorLine As Integer, _
retCompileErrorColumn As Integer, _
retCompileErrorOffset As Integer, _
retCompileErrorLength As Integer _
) As Integer

Declare Sub OSMemFree Lib "nnotes.dll" (Byval hHandle As Long)

Declare Function OSLoadString Lib "nnotes.dll" ( _
Byval hmodule As Long, _
Byval status As Integer, _
Byval s As String, _
Byval slen As Integer _
) As Integer

' LINUX
Declare Function LX_NSFFormulaCompile Lib "libnotes.so" Alias "NSFFormulaCompile" ( _
Byval FormulaName As Long, _
Byval FormulaNameLength As Integer, _
Byval FormulaText As Lmbcs String, _
Byval FormulaTextLength As Integer, _
rethFormula As Long, _
retFormulaLength As Integer, _
retCompileError As Integer, _
retCompileErrorLine As Integer, _
retCompileErrorColumn As Integer, _
retCompileErrorOffset As Integer, _
retCompileErrorLength As Integer _
) As Integer

Declare Sub LX_OSMemFree Lib "libnotes.so" Alias "OSMemFree" (Byval hHandle As Long)

Declare Function LX_OSLoadString Lib "libnotes.so" Alias "OSLoadString" ( _
Byval hmodule As Long, _
Byval status As Integer, _
Byval s As String, _
Byval slen As Integer _
) As Integer

' MAC
Declare Function MAC_NSFFormulaCompile Lib "NotesLib" Alias "NSFFormulaCompile" ( _
Byval FormulaName As Long, _
Byval FormulaNameLength As Integer, _
Byval FormulaText As Lmbcs String, _
Byval FormulaTextLength As Integer, _
rethFormula As Long, _
retFormulaLength As Integer, _
retCompileError As Integer, _
retCompileErrorLine As Integer, _
retCompileErrorColumn As Integer, _
retCompileErrorOffset As Integer, _
retCompileErrorLength As Integer _
) As Integer

Declare Sub MAC_OSMemFree Lib "NotesLib" Alias "OSMemFree" (Byval hHandle As Long)

Declare Function MAC_OSLoadString Lib "NotesLib" Alias "OSLoadString" ( _
Byval hmodule As Long, _
Byval status As Integer, _
Byval s As String, _
Byval slen As Integer _
) As Integer


Const NULLHANDLE = 0
Const NO_ERROR = 0
Const ERR_FORMULA_COMPILATION = &h500 + 1

' ================================================================================
' CheckSelectionFormulaValid - This function uses the Lotus C API to check thesyntax of a Notes formula.
'
' Return Value: Variant - A 3 elements array containing:
' Index 0 - The compilation error code or NO_ERROR (0) if valid
' Index 1 - The compilation error offset in formula or NO_ERROR if valid 
' Index 2 - The compilation error length or NO_ERROR if valid
'
' Note: The compilation error code at Index 0 can then be passed to GetAPIError () to get more info about the error.
' ================================================================================
' ================================================================================
' GetAPIError - This function uses the Lotus C API to return a Notes error's text message.
'
' Return Value: String - The text associated with the Notes API error code.
' ================================================================================


Und dann noch die einzelnen Funktionen

Code
Function CheckSelectionFormulaValid(sFormula) As Variant
	
	Dim iError As Integer
	Dim hFormula As Long
	Dim wFormulaLen As Integer
	Dim iCompileError As Integer
	Dim iCompileErrorLine As Integer
	Dim iCompileErrorColumn As Integer
	Dim iCompileErrorOffset As Integer
	Dim iCompileErrorLength As Integer
	Dim iArray(2) As Integer
	Dim szVersion As String
	szVersion = get_platform()
	
	Select Case szVersion
	Case "w32"
		iError = NSFFormulaCompile(0, 0, _
		sFormula, _
		Len(sFormula), _
		hFormula, _
		wFormulaLen, _
		iCompileError, _
		iCompileErrorLine, _
		iCompileErrorColumn, _
		iCompileErrorOffset, _
		iCompileErrorLength)
	Case "linux"
		iError = LX_NSFFormulaCompile(0, 0, _
		sFormula, _
		Len(sFormula), _
		hFormula, _
		wFormulaLen, _
		iCompileError, _
		iCompileErrorLine, _
		iCompileErrorColumn, _
		iCompileErrorOffset, _
		iCompileErrorLength)
	Case "mac"
		iError = MAC_NSFFormulaCompile(0, 0, _
		sFormula, _
		Len(sFormula), _
		hFormula, _
		wFormulaLen, _
		iCompileError, _
		iCompileErrorLine, _
		iCompileErrorColumn, _
		iCompileErrorOffset, _
		iCompileErrorLength)
	End Select
	
	If hFormula <> NULLHANDLE Then
		Select Case szVersion
		Case "w32"
			Call OSMemFree(hFormula)
		Case "linux"
			Call LX_OSMemFree(hFormula)
		Case "mac"
			Call MAC_OSMemFree(hFormula)
		End Select		
	End If
	
	If iError = ERR_FORMULA_COMPILATION Then
		iArray(0) = iCompileError
		iArray(1) = iCompileErrorOffset
		iArray(2) = iCompileErrorLength
		CheckSelectionFormulaValid = iArray
	Else
		iArray(0) = NO_ERROR
		iArray(1) = NO_ERROR
		iArray(2) = NO_ERROR
		CheckSelectionFormulaValid = iArray
	End If
	
End Function

Code
Function get_platform () As String
	
	Dim tmp_platform As Variant
	Dim lower_platform As String
	tmp_platform = Evaluate(|@Implode(@Platform([Specific]);" ")|)
	
	lower_platform = Lcase(Cstr(tmp_platform(0)))
	
	If (Instr (lower_platform, "linux")) Then
		get_platform = "linux"
	Elseif (Instr (lower_platform, "win")) Then
		get_platform = "w32"
	Elseif (Instr (lower_platform, "mac")) Then
		get_platform = "mac"
	Else 
		Print "Unsupported Platform : >" + lower_platform + "<"
		get_platform = ""
	End If
End Function

Code
Function GetAPIError(iErrorCode As Integer) As String
	
	Dim iRetVal As Integer
	Dim sError As String * 1024
	Dim szVersion As String
	szVersion = get_platform()
	
	sError = String(1024, 0)
	Select Case szVersion
	Case "w32"
		iRetVal = OSLoadString(0&, iErrorCode, sError, 1023)
	Case "linux"
		iRetVal = LX_OSLoadString(0&, iErrorCode, sError, 1023)
	Case "mac"
		iRetVal = MAC_OSLoadString(0&, iErrorCode, sError, 1023)
	End Select	
	
End Function


Kann es nicht testen, da ich keinen Mac habe; daher keine Garantie.
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

Offline eknori

  • @Notes Preisträger
  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 11.710
  • Geschlecht: Männlich
Re: [Fixed] Lx client: "Zuweisen" -> Fehler
« Antwort #19 am: 25.06.10 - 12:45:34 »
Scheint mit den Declarationen im MAC wohl nicht zu funktionieren. Evtl kann das jemand mal mit der entsprechenden Ausstattung testen und gegebenenfalls korrigieren.

Die Funktion "Zuweisen" verwendet tatsächlich die API. Als Workaround könnte man den Aufruf auskommentieren.

In der lib.appl.functions in der Function CheckAndEvaluate

   On Error Goto ERRHANDLE
   ' -> Dim OK As Variant
   '- > OK = CheckSelectionFormulaValid(formula)
   '- > If OK(0) = NO_ERROR Then
      CheckAndEvaluate = Evaluate(formula, doc)
   '- > End If

die markierten Zeilen auskommentieren.
Egal wie tief man die Messlatte für den menschlichen Verstand auch ansetzt: jeden Tag kommt jemand und marschiert erhobenen Hauptes drunter her!

 

Impressum Atnotes.de  -  Powered by Syslords Solutions  -  Datenschutz