Bug Report : Mails in Inbox wieder da

[Meff]

Hallo Forum,

wieder wurde ein schöner Bug reportet :

In Version 6 erscheinen gelöschte oder in einen Ordner verschobene Mails wieder in der Inbox auf. Weder ein Compact noch ein Fixup beheben das Problem.

Lt. IBM soll dieser Bug in Version 6.0.3 gefixt sein.

Meff

[eknori]

ja, das hatte ich auch nach dem Upgrade.

bei uns trat das im Cluster auf; die Db auf dem einen Server war i.O. auf dem anderen waren die Dokumente wieder in der Inbox.

Ich habe die kaputte DB gelöscht und eine neue Replik gezogen. Das brachte aber auch nichts. Ich habe dann über das OS eine neue "Replik" gezogen ( Kopieren der Datenbank über OS ).
Dann trat der Fehler nicht mehr auf. Eine der Ursachen laut IBM /Lotus ist eine falsche ODS Version. Alle betroffenen Datenbanken hatten noch die ODS 41. Der Compact lief nicht sauber durch, weil genau diese User die Datenbanken beim Compact noch im Zugriff hatten. Auch der Compact mit hilfe einer Kopie und Zugriff erlauben war nicht die richtige Lösung.

Ich habe dann in einer stillen Stunde den Server heruntergefahren und alle Datenbanken mit compact -c -i behandelt. Seitdem ist Ruhe.

Um die Dokumente wieder an ihren ursprünglichen Platz zu befördern habe ich folgendes Script

Dim session As New NotesSession
Dim db As NotesDatabase
Dim view As NotesView
Dim doc As NotesDocument
Dim maildoc As NotesDocument
Dim rtitem As NotesRichTextItem
Dim agent As NotesAgent
Dim i As Integer
Dim j As Integer
Dim thisAgent As NotesAgent
Dim serverName As NotesName
Dim server As String
Dim countdocs As Integer
Dim dc As NotesDocumentCollection

Set db = session.CurrentDatabase
Set thisAgent = session.Currentagent
Set serverName = session.CreateName(db.server)

Set view = db.GetView("($Inbox)")

If(db.FolderReferencesEnabled) Then
Print "Okay - Folder references are already enabled"
Else
Print "Warning: Folder references are not enabled"
Print "Okay - Now enabling folder references"
db.FolderReferencesEnabled = True
End If

Set maildoc = New NotesDocument( db )
' set the new document's form so it'll be readable as a mail memo
maildoc.Form = "Memo"
' set the new document's subject
server = serverName.Abbreviated
If (server = "") Then
server = "Local"
End If
maildoc.Subject = thisAgent.Name & {, DB: } & db.title & { on Server: } & server & {, Time: } & Format(Now(),"dddd, dd. mmmm yyyy, hh:mm:ss")
' set the new document's body

Set rtitem = New NotesRichTextItem (maildoc, "Body" )
Call rtitem.AppendText ( "Here are the documents we've been working on in your Inbox:" )
Call rtitem.AddNewline(2)
'Disable autoupdate in the view!
If (view.AutoUpdate = True) Then
Print "Disabling the auto update feature of the inbox view..."
view.AutoUpdate = False
End If
Print {Started agent "} & thisAgent.Name & {". Please wait...}
'Set doc = view.GetFirstDocument

Set dc = db.UnprocessedDocuments
If dc.Count = 0 Then
Print "Please select some documents before calling this action."
Exit Sub
End If

For j=1 To dc.Count
Set doc = dc.GetNthDocument(j)
countdocs = countdocs + 1
i = 0
Call rtitem.AppendText ({Subject: "} & doc.Subject(0) & {" from "} & doc.From(0) & {", Note ID: } & doc.noteid)
Call rtitem.AddNewline(1)
'Cycle through all documents and put them in the folder - except for the folder ($Inbox)
Forall FolderReference In doc.FolderReferences
i = i+1
'if (FolderReference <> "($Inbox)") Then
Call rtitem.AppendText ({ - Folder (} & i & {): } & FolderReference & {, Note ID: } & doc.noteid)
Call rtitem.AddNewline(1)
If (FolderReference <> "($Inbox)") Then
Call rtitem.AppendText ({ - - Mail was removed from the Inbox: it was already filed in a folder: "} & FolderReference & {" before...})
Call rtitem.AddNewline(1)
' Because if it was filed before, just remove the doc from the Inbox folder
Call doc.RemoveFromFolder("($Inbox)")
End If
End Forall
Call rtitem.AddNewline(1)
Next
Call rtitem.AddNewline(2)
Call rtitem.AppendText ({Totally processed mail documents: } & countdocs )
Print {eMail was sent to: } & session.UserName
Call maildoc.Send( False, session.Username )
Print "Enabling the auto update feature of the inbox view..."
view.AutoUpdate = True
Print {Ended agent: "} & thisAgent.Name & {". Finished.}

Bei IBM Lotus habe ich bereits einen Call aufgemacht ( incident #1598148 )

mal sehen, was passiert

eknori

[Meff]

Hi eknori,

danke für den Workaround, vielleicht kannst Du das ganze nochmals im Tipps & Tricks Forum posten.

Lt. IBM ist das Problem derzeit bei QM und ist als Fix für Release 6.0.3 announced.

Meff