Auf automatisch generierte mails antworten

[crow]

moin,

folgendes problem: bei uns  werden mails mit zahlen aus as/400 tabellen automatisch generiert und über den server verschickt.

Wie kann ich es einrichten, das wenn der empfänger auf antworten drückt der zuständige sachbearbeiter als empfänger der antwort eingetragen wird ?

[tower]

Hallo, du musst das Mail mit einen geänderten Absender verschicken und das geht, in dem Du das Mail direkt in der Mail.box des Servers erstellst.

Für Lotusscrip hier eine Funktion:

Sub SendMail (subject As String, body As Variant, recipients As String, whofrom As String)      
   
 ' Subroutine to create email messages directly                                                  
 'in the mail.box for router to deliver                                                          
   
 'Setup sane logic                                                                              
   On Error Goto HandleError                                                                      
   
 'Allocate worker vars.                                                                          
   Dim session As NotesSession                                                                    
   Dim db As NotesDatabase                                                                        
   Dim Memobody As NotesRichTextItem                                                              
   Dim object As NotesEmbeddedObject                                                              
   
 'Create the document in MAIL.BOX on current server                                              
   Set session = New NotesSession                                                                  
   session.convertmime=False
   Set db = session.GetDatabase("","mail.box")                                                    
   Dim memo As New NotesDocument(db)                                                              
   
 'Convert recipients array into NAMES fields in Memo                                            
   Dim recip As New NotesItem(memo,"Recipients",recipients,NAMES)                                  
   Dim sendTo As New NotesItem(memo,"SendTo",recipients,NAMES)                                    
   Dim blindCopy As New NotesItem(memo,"BlindCopyTo","",NAMES)                                    
   
 ' Make recip and sendTo Summary Fields. Failure to do so                                        
 ' will prevent them appearing in view columns. If they                                          
 ' don't appear in a view column ROUTER task will reject them.                                  
 ' This is a very common mistake to forget about this.                                          
   recip.IsSummary = True                                                                          
   sendTo.IsSummary = True                                                                        
   
 'Put body into richtext field                                                                  
   Set MemoBody = memo.CreateRichTextItem( "Body" )                                                
'   Call MemoBody.AppendText(body)                                                                  
   If Typename(Body) = "NOTESRICHTEXTITEM" Then                                                    
      Call Memobody.AppendRTItem(body)                                                                
   Else                                                                                            
      Call Memobody.AppendText(body)                                                                  
   End If                                                                                          
   
 'Set Various memo control fields for Notes Friendliness                                        
   memo.Form = "Memo"                                                                              
   memo.From = whofrom                                                                            
   memo.Subject = subject                                                                          
   memo.MailFormat = "T"                                                                          
   memo.DeliveryPriority = "High"                                                                  
   memo.deliveryReport = "O"                                                                      
   
   Call memo.save(True,False)                                                                      
   
Done:                                                                                          
   On Error Goto Bail                                                                              
 'Misc post processing goes here                                                                
   Exit Sub                                                                                        
   
HandleError:                                                                                    
 'Aggh something fail put error on browser so it can be spotted                                  
   Dim status As String                                                                            
   status$ = "Error! " & Err() & " at line " & Erl() & ": " & Error()                              
   Messagebox(status$)                                                                            
   Resume Done                                                                                    
   
Bail:                                                                                          
   status$ = "Error " & Err() & " at line " & Erl() & ": " & Error()                              
   Messagebox(status$)                                                                            
   Resume BailOut                                                                                  
   
BailOut:                                                                                        
End Sub      

[crow]

Danke für den tipp