Memo per @Command füllen

[Keydins]

Moin zusammen,

ich versuche grade verzweifelt per Schalter aus einer seperaten Notesanwendung ein Memo mit Vorgabewerten zu füttern....

Code

it-mail := "ITSupport";
vl-mail := verantwortlich_leiter;
bez := Bezeichnung;

auswahl := @Prompt(
									[OkCancelList]:[NoSort];
									"Informationen senden";
									"Informationen zum Update versenden an:";
									"Verantwortlichen Leiter";
									"Verantwortlichen Leiter":"IT-Management");

@If(auswahl = "Verantwortlichen Leiter";
			@Do(
						@Command([MailComposeMemo]);
						@PostedCommand([EditGotoField];"EnterSendTo");
						@PostedCommand([EditInsertText]; vl-mail);
						@PostedCommand([EditGotoField];"Subject");
						@PostedCommand([EditInsertText]; "Info: Ein Update für '" + bez + "' liegt vor" );
						@PostedCommand([EditGotoField];"Body")
			);
		auswahl = "IT-Management";
			@Do(
						@Command([MailComposeMemo]);
						@PostedCommand([EditGotoField];"EnterSendTo");
						@PostedCommand([EditInsertText]; it-mail);
						@PostedCommand([EditGotoField];"Subject");
						@PostedCommand([EditInsertText]; "Info: Ein Update für '" + bez + "' liegt vor" );
						@PostedCommand([EditGotoField];"Body")
			);
		""
)

Ergebnis

Im Feld "EnterSendTo" wird nichts eingetragen
Im Feld "Subject" landet der beabsichtigte Text (inklusive dem Inhalt von 'bez')

Ersetze ich die Variablen "it-mail" und "vl-mail" in den [EditInsertText]-Zeilen durch "Bla Bla" so wird das sauber in das Memo übernommen....

Wie bekomme ich variable Empfänger in das "EnterSendTo" Feld?


Gruß
Dirk

[Glombi]

Das geht einfacher so:

_sendto := "Max Mustermann@abc.de":"HeinzSchenk@blauerbock";

@Command([MailComposeMemo]);
@UpdateFormulaContext;
FIELD Subject := "Betreff";
FIELD EnterSendTo := _sendto;
...

Da kannst Du auch variable Empfänger verwenden, insb. auch Mehrfachwerte.

Andreas

[Keydins]

Das ist nebenbei auch noch deutlich kürzer  

Funktioniert jetzt, aber das Problem lag scheinbar an meinen Variablen...

_sendto := Empfänger; => geht
it-mail := Empfänger; => geht nicht

Aber ich glaub darüber denk ich heute Abend nicht mehr nach.


Besten Dank und einen schönen Anbend noch

[it898ur]

Ich glaube ein Bindestrich in Variablennamen ist überhaupt nicht zulässig, da Notes hier versucht Variable mail von Variable it abzuziehen (Subtraktionszeichen).

Gruß

André

[Keydins]

Das klingt auf jeden Fall plausibel. War ein langer Tag gestern, da kommt man schonmal auf "komische" Variablennamen.