Mail Reply mit neuem Text davor - BeginInsert?

[ThomasM]

Hallo zusammen,

ich muss folgendes realisieren:
Mail kommt von extern mit diversen Angaben. Diese Angaben stehen im Betreff und im Body.
Das Mail soll nun an extern weitergeleitet werden mit dem Body aus der externen Mail UND davor noch
ein neuer Text.

Die erste Zeile des Textes kommt auch in der Mail, aber der restliche Text leider nicht.

Was mache ich falsch?

Vielen Dank im voraus

Gruss
Thomas

Script ist im Anhang

[umi]

Moin

Schon mal das NotesRichtextitem.AppendRTItem probiert?
ungefähr so:

Code

dim origBody as notesRichtextitem

set body=docMemo.replaceitemvalue("Body","")
call body.appendText("....")
call body.addnewline(2)
set origBody = doc.getfirstitem("Body")
if not OrigBody is nothing then
 call body.appendRtitem(OrigBody)
end if

[ThomasM]

Hallo Urs,

vielen Dank für die Antwort.
Deine Lösung hat nicht ganz funktioniert aber sie hat mich auf den richtigen Weg gebracht.
Jetzt hab ich eine Lösung.

Danke

Gruss
Thomas

[Peter Klett]

Dann wäre es nett, wenn Du zumindest den Ansatz für spätere Leser hier einstellst.

[ThomasM]

mach ich doch glatt

ist jetzt nicht ganz die "schöne" Lösung aber für das was realisiert werden soll reichts.

Gruss
Thomas

Ich hoffe das ist jetzt so OK 

Sub Initialize
   Dim session As New NotesSession
   Dim ndb As NotesDatabase
   Dim view As NotesView
   Dim doc As NotesDocument
   Dim docMemo As NotesDocument
   Dim origbody As NotesRichTextItem
   Dim item As NotesItem
   
   Set ndb = session.CurrentDatabase
   Set view = ndb.GetView( "(AnfageUnBeantwortet)" )
   Set doc = view.GetFirstDocument
         
   view.AutoUpdate = False
   
   'Verarbeitung Busunternehmen   
   While Not(doc Is Nothing)
      If Not doc.beantwortet(0)= "ja" Then   
         
         'Betreff von Originalmail aufteilen
         SubjectMail = StrRightBack(doc.subject(0), "r - " )
         sendto = StrrightBack(SubjectMail, " - " )
         Bearbeitungsnummer = StrLeftBack(SubjectMail, "- " )
         
         'erstellen neue nachricht + füllen felder
         Set docmemo = doc.CreateReplyMessage( False )
         docMemo.Form = "Memo"
         docMemo.sendto = sendto
         docMemo.From = "xxxs@xxx.de"
         docMemo.ReplyTo = "xxx@xxx.de"
         docMemo.Subject = "Neues Feedback Qualitätsmamagement - " + Bearbeitungsnummer
            
         Set nrit = New NotesRichTextItem( docMemo, "Body" )                                 
         Call nrit.AppendText( "Sehr geehrter,")
         Call nrit.AddNewLine( 2 )
         Call nrit.AppendText( "es ist ein neues Feedback über das Qualitätsmanagement eingegangen." )
         Call nrit.AddNewLine( 4 )
         Call nrit.AppendText( "************** Feedback über QMS ****************" )
         Call nrit.AddNewLine( 2 )
         
         'Feedback aus originalmail in neue mail einfügen
         Set origBody = doc.getfirstitem("Body")
         If Not OrigBody Is Nothing Then
            Call nrit.appendRtitem(OrigBody)
         End If
         
         'senden an Bus + verschieben in ordner + setzten verarbeitet flag                                          
         Call docMemo.Send(False)
         Call docMemo.Save( True , False, True )   
         Call docMemo.MarkRead()
         Call docMemo.PutInFolder("Mail an xxxx")
         
         doc.beantwortet = "ja"
         Call doc.Save( False, False, True )
         Call doc.PutInFolder( "Mail an xxxx" )
         Call doc.RemoveFromFolder( "$Inbox")
         
      End If
      Set doc = view.GetNextDocument(doc)
            
      Wend
End Sub

[Tode]

BITTE: nicht jeder hat Bock, sich ein Attachment mit zweifelhaftem Inhalt runterzuladen... Dafür gibt es doch die Code- Tags... Poste den Code direkt, dann haben viel mehr Leute was davon...

[Peter Klett]

Vielen Dank!

[Tode]

nun ja... Code- Tags würden das ganze schon nochmal besser lesbar machen... Aber trotzdem: Danke...