Object variable not set bei DetDocumentByKey

[cococo69]

Hallo zusammen,

ich habe ein für mich nicht nachvollziehbares Problem mit der Funktion GetDocumentByKey...

- Ansicht wird gefunden
- Spalte ist  sortiert
- Es gibt eine Ansicht "Vorgabe beim ersten Öffnen..."

Alle Infos in der angehängten PDF.

Viele Grüße
Armin

[ascabg]

Hallo,

Und wo genau kommt jetzt die Fehlermeldung?


Andreas

[udo187]

Hallo !

Wo wird das docThis gesetzt ?

Gruss
Udo

[Peter Klett]

Probier mal @Text (@NotesID) in der Ansicht

[Peter Klett]

Hab mir das ganze nochmal genauer angesehen:

Was willst Du eigentlich erreichen? Du hast ein Dokument (docThis), von diesem Dokument holst Du Dir über Evaluate @Text (@NoteID), also die NoteID des Dokuments.

Dann gehst Du in eine nach @NoteID sortierte Ansicht und holst Dir das Dokument (docAnsicht) mit der soeben ermittelten NoteID.

Unter welchen Bedingungen sollten diese beiden Dokumente nicht gleich sein? Also wozu holst Du dasselbe Dokument noch einmal über die Ansicht? Einziger Sinn könnte darin bestehen, dass Du prüfen willst, ob das Dokument schon gespeichert wurde, aber wenn es nicht gespeichert wurde, ist es nicht in der Ansicht. Dann ist es korrekt, dass "Object variable not set" ausgegeben wird. Da müsstest Du auf "Is Nothing" prüfen.

EDIT: Falls das das Ziel ist, ließe sich das natürlich viel einfacher machen, indem z.B. beim Speichern ein Feld gesetzt wird, das Du überprüfen kannst.

[cococo69]

Hallo zusammen,

danke für die Antworten!

@Andreas
Die Fehlermeldung kommt in der Zeile, welche in der Debugger-Hardcopy markiert ist (If docThis....) da docAnsicht nicht existiert.

@Udo
Das docThis wird an die Funktion übergeben, sorry sieht man in der Hardcopy nicht

@Peter
@Text... habe ich schon probiert
Was ich mit der Funktion erreichen will: Das Dokument soll erneut zugeordnet werden um zu prüfen, ob es zwischenzeitlich von einem anderen Benutzer gespeichert worden ist...

Was es noch zu erwähnen gibt:
Genau die gleiche Funktionalität habe ich in mehreren anderen Anwendungen erfolgreichg im Einsatz. Alles nur kopiert , nur hier klappt dieser GetDocumentByKey nicht.......!!!?

Gruß Armin

[Peter Klett]

Ok, Anliegen verstanden ...

Schaust Du in die Ansicht auf dem gleichen Server, auf dem auch das Dokument geöffnet wurde? M.W. ist die NoteID im Gegensatz zur UniversalID von Replik zu Replik unterschiedlich.

Ansonsten würde ich die Ansicht einmal komplett löschen und völlig neu erstellen, vielleicht hat die einen Schlag weg.

[cococo69]

Hallo Peter,

ja, ich schaue auf dem gleichen Server.
Habe die Ansicht auch schon gelöscht und neu angelegt...
... Erfolg = 0

Andere Ideen?

Gruß Armin

[Driri]

Ich habe leider keine Idee dazu, sondern lediglich eine Anmerkung/Frage/Verbesserungsvorschlag :

Warum holst Du die NoteID mit Evaluate ? Wenn Du das Dokument hast, kannst Du doch auch direkt mit docThis.NoteID darauf zugreifen.

[thkn777]

@cococo69
Ja... die alte Schritt-für-Schritt-Methode:

if docThis is nothing then
  print "docThis nothing"
  exit function
end if

set view = db.GetView("irgendwas")
if view is nothing then
  print "kein Zugriff auf view"
  exit function
end if

call view.Refresh

id = ...
id_cstr = Cstr(id(0))
print "id_cstr=" & id_cstr

Usw. usf.

Versuch' erstmal rauszubekommen, was Notes da quer steht. Und zwar aus Sicht Deines Notes-Scripts. Die Praxis kann da manchmal überraschend sein Bsp: docThis wird übergeben... schön und gut. Weißt Du genau, daß in diesem Fall ein sinnvoller Wert drinsteht?

Wenn alles "gut" sein sollte:
- leere DB erstellen
- nur die benötigten Gestaltungselemente für den Test Deiner Funktion reinkopieren bzw. schlimmstenfalls NEU 1:1 erstellen
- Daten kopieren oder schlimmstenfalls neu erstellen
- testen
Erklärung: Manchmal (selten) sind Notes Gestalungselemente einfach kaputt.

Viel Erfolg.

P.S: Mal abgesehen davon... ich würde der Empfehlung von Driri folgen und den Code vereinfachen. Wenn Du die NoteID hast, warum dann kein db.GetDocumentByID?

[Peter Klett]

Ich hab das jetzt mal nachgebaut:

Bei mir funktioniert folgendes (in der Ansicht habe ich @Text (@NoteID) als erste sortierte Spalte):

Code

Sub Initialize
	Dim workspace As New NotesUIWorkspace
	Dim uidoc As NotesUIDocument
	Set uidoc = workspace.CurrentDocument
	Dim doc As NotesDocument
	Set doc = uidoc.Document
	doc.Feldx = "irgendwas"
	
	Dim db As NotesDatabase
	Set db = doc.ParentDatabase
	Dim view As NotesView
	Set view = db.GetView ("noteid")
	Dim iddoc As NotesDocument
	Dim id As String
	id = "NT" & Right ("00000000" & doc.NoteID, 8)
	Set iddoc = view.GetDocumentByKey (id)
	Msgbox iddoc.Feldx (0)
End Sub

Msgbox gibt korrekterweise nichts aus.

Dagegen

Code

Sub Initialize
	Dim workspace As New NotesUIWorkspace
	Dim uidoc As NotesUIDocument
	Set uidoc = workspace.CurrentDocument
	Dim doc As NotesDocument
	Set doc = uidoc.Document
	doc.Feldx = "irgendwas"
	
	Dim db As NotesDatabase
	Set db = doc.ParentDatabase
	Dim iddoc As NotesDocument
	Set iddoc = db.GetDocumentByID (doc.NoteID)
	msgbox iddoc.Feldx (0)
End Sub

geht es nicht mit db.GetDocumentByID, da dann das Dokument im Speicher verwendet wird (hatte mir das gedacht, musste ich aber erst überprüfen). Hier wird also "irgendwas" ausgegeben.

Beim Evaluate bekommst Du die NoteID so zurück, wie sie in der Ansicht steht. Bei doc.NoteID musst Du ein "NT" und den Rest 8-stellig mit führenden Nullen aufbauen. Da wäre mir das Evaluate lieber, falls sich da mal was ändert, ist aber sicher Geschmacksache.

db.GetDocumentByID bringt Dich aber auf keinen Fall weiter.

[thkn777]

@Peter Klett
Wenn man auf das NotesSession Objekt verzichtet und die db einfach über db.Open(Server, Pfad) öffnet, dann kann man auch GetDocumentById verwenden.

Code

Private Sub showEingabe(Byval db3name As String, Byval db3server As String, Byval NoteId3 As String)
	Dim session3 As New NotesSession
	Dim doc3 As NotesDocument
	Dim db3 As New NotesDatabase( "", "" )
	
	' Set db3 = session3.GetDatabase(db3server, db3name)
	Call db3.Open( db3server, db3name )
	
	Set doc3 = db3.GetDocumentByID(noteId3)
	If doc3 Is Nothing Then
		Print "doc3 is nothing"
	Else
		Print Str$(Now()) & " doc3.eingabe = " & doc3.eingabe(0)
	End If
End Sub

- Ich habe diese Sub in einer Maske eingebunden.
- ich gebe in das Feld "eingabe" etwas ein (z.B. "1") und speichere, danach rufe ich die Sub auf --> "1"
- das Dokument verbleibt weiter im Edit-Mode
- ich gebe in das Feld "eingabe" etwas anderes ein (z.B. "2") ohne zu speichern und rufe die Sub auf --> immer noch "1"

Benutze ich stattdessen "Set db3 = session3.GetDatabase(db3server, db3name)" (oben auskommentiert), dann tritt der von Dir beschriebene Effekt ein, daß über das im Client nur einmal verwendete NotesSession Objekt das in-memory Dokument verwendet wird. Folgerichtig wird dann der nicht gespeicherte Wert "2" angezeigt.

Ich bin immer noch der Meinung, daß es auch ohne Ansicht geht und direkt die DocumentId verwendet werden kann. Wie sich das ganze performancetechnisch verhält, müßte man noch gucken. Mir fehlt im Moment auch die Zeit auszutesten, wie weit man db3 in die Globals schieben kann. Wenn das geht, dann sollte die Sub sehr schnell sein.

Gruß,
Th.

P.S. @cococo69 Entschuldige, Deine Frage in dem Thread war eine andere und es geht Dir eigentlich um die GetDocumentByKey Fehler - vielleicht kommt aber trotz des "Hijacking" etwas Gutes für Dich bei dieser Diskussion heraus. 

[thkn777]

Mit einem Evaluate geht auch so etwas in der Maske (gleiches Scenario wie oben):

Code

Sub Click(Source As Button)
	Dim ws As New NotesUIWorkspace
	Dim uidoc As NotesUIDocument
	Dim unid As String
	Dim res As Variant
	
	Set uidoc = ws.CurrentDocument
	unid = uidoc.Document.UniversalID
	
	res = Evaluate (|@GetDocField("| & unid & |"; "eingabe")|)
	Print Str$(Now()) & " eingabe = " & res(0)
End Sub

D.h. mit @GetDocField kann man sich - sofern man in der gleichen DB arbeitet - das DB.Open sparen. Es wird auch hier der Inhalt des NotesItems aus dem Backend angezeigt.

Schönen Feierabend wünsch' ich.

[pram]

Eine (evtl übertriebene) Anmerkung meinerseits:

Bei Codestücken wie diesen läuten bei mir immer die Alarmglocken:

Code

res = Evaluate (|@GetDocField("| & unid & |"; "eingabe")|)

Durch sowas baut man sich nämlich sehr oft (hier zwar nicht) eine Sicherheitslücke.
Wenn UNID aus einem Feld kommen würde, kann Code injiziert werden.
Deshalb sollte man, wenn möglich, immer eine konstante Formel verwenden und für die Parameterübergabe ein Dokument verwenden.

Besser wäre:

Code

res = Evaluate (|@GetDocField(@DocumentUniqueID; "eingabe")|, uidoc.document)

(evtl muss um @DocumentUniqueID noch ein @Text() rum)

Hat weiterhin den Vorteil, dass die Formel schon bei der Compilezeit überprüft wird.

Gruß
Roland

[Peter Klett]

@Peter Klett
Wenn man auf das NotesSession Objekt verzichtet und die db einfach über db.Open(Server, Pfad) öffnet, dann kann man auch GetDocumentById verwenden.
...

Cool, dann würde ich das an Armins Stelle genau so machen und auf die Ansicht verzichten. Da die Ansicht jedesmal refresht wird, kann GetDocumentByID nur schneller sein.

[thkn777]

Update:
Das Öffnen der DB darf nicht im Initialize erfolgen.

Maximal geht's bis:

Code

Public db_global As NotesDatabase
Public isOpen_db_global As Integer
Public session_global As NotesSession
Public doc_global As NotesDocument
Sub Initialize
	Set session_global = New NotesSession
	Set db_global = New NotesDatabase( "", "" )
	isOpen_db_global = False
	' *** hier NICHT!!!!! Call openDb_global (session_global.CurrentDatabase.Server, session_global.CurrentDatabase.FilePath)
End Sub

mit

Code

Private Sub openDb_global (Byval server As String, Byval filepath As String)
	If Not isOpen_db_global Then
		isOpen_db_global = db_global.Open( server, filePath )
	End If
End Sub

und

Code

Private Sub showEingabe_global(Byval myNoteId As String)
	Set doc_global = db_global.GetDocumentByID(myNoteId)
	If doc_global Is Nothing Then
		Print "doc_global is nothing"
	Else
		Print Str$(Now()) & " doc_global.eingabe = " & doc_global.eingabe(0)
	End If
End Sub

Der Aufruf erfolgt dann jeweils über:

Code

Call openDb_global (session_global.CurrentDatabase.Server, session_global.CurrentDatabase.FilePath)
Call showEingabe_global(NoteId)

Wenn Performance keine Rolle spielt, braucht man diese Handstände nicht zu machen.
Wenn doch: das eine "If Not isOpen_db_global" wird zu verschmerzen sein bzw. muß man wohl in Kauf nehmen.

Schönen (rutschfreien) Dienstag wünsch' ich.

[cococo69]

Hallo zusammen,

zuerst möchte ich euch allen herzlich danken für die unglaubliche Mühe, die ihr euch in diesem Thread gegeben habt!!

Ich bin nun tatsächlich den Weg von "thkn777" über db.Open(Server, Pfad)  gegeangen und es funktioniert einwandfrei!! Guter Ansatz - DANKE!

Viele herzliche Grüße
Armin

[thkn777]

@pram
Naja, ich war mehr darauf aus, daß man sich eine LS function bauen könnte

Code

Function getDocField(Byval unid As String, Byval itemname As String) As Variant
	getDocField = Evaluate (|@GetDocField("| & unid & |"; "| & itemname & |")|)
End Function

und diese benutzt, um den "Backend"-Wert eines Items zu ermitteln aus einem beliebigen Dokument der aktuellen DB, von dem man die UNID kennt. Diese liefert jedoch nicht ein NotesDocument Objekt zurück wie GetDocumentById oder GetDocumentByUnid. Vielleicht trotzdem ganz nützlich.


@cococo69
Freut mich, daß wir Dir beim Lösen Deines Problems helfen konnten.

Th.