Empfangenes Mail leider immer im Editmode

[robertpp]

Hallo,
Das Ziel welches ich verfolge ist, ein mail zu versenden wo ein Link drinnen ist aber nicht als einfachen url sondern mit <a href=......  >click me</a>

Das mach ich so:

Code

Sub MimeMailer(SendTo As Variant, Subject As String, url As String, doc As NotesDocument)
	Dim s As New NotesSession
	Dim db As NotesDatabase
	Dim body As NotesMIMEEntity
	Dim stream As NotesStream
	Dim tmpURL As String
	Dim message As NotesDocument	
	Dim mailbox As New NotesDatabase("","")
	Set db = s.CurrentDatabase
	
	tmpURL = |<font face="Arial" size="2"><a href='| + URL + |'>Click Here to activate user</a></font><br>|
	
	s.ConvertMIME = False
	Set stream = s.CreateStream
	
	Call mailbox.Open("SERVER","mail.box")
	If mailbox.IsOpen Then
		Dim sender As String
		
		Set message = mailbox.CreateDocument
		message.Form="memo"
		sender = "Admin"
		Set body = message.CreateMIMEEntity
		Dim mimeHeader As NotesMIMEHeader		
		Set mimeHeader = body.CreateHeader( "SMTPOriginator" )
		Call mimeHeader.SetHeaderVal( sender )
		Set mimeHeader = body.CreateHeader( "Sender" )
		Call mimeHeader.SetHeaderVal( sender )
		Set mimeHeader = body.CreateHeader( "INetFrom" )
		Call mimeHeader.SetHeaderVal( sender )
		Set mimeHeader = body.CreateHeader( "ReplyTo" )
		Call mimeHeader.SetHeaderVal( sender )
		Set mimeHeader = body.CreateHeader( "Principal" )
		Call mimeHeader.SetHeaderVal( sender )
		Set mimeHeader = body.CreateHeader( "From" )
		Call mimeHeader.SetHeaderVal( sender )
		
		message.Subject = Subject
		message.SendTo = SendTo
		message.Recipients = SendTo
		
		Dim htmlbeforeurl As String, htmlafterurl As String
		htmlbeforeurl = |<font face="Arial" size="2">Hi,<br><br>
		
		There is a new user to activate:<br><br>
		Username is: | +doc.Username(0) + |<br>
		Email is: | +doc.email(0) + |<br>
		<br></font>
		|
		
		Call stream.WriteText(htmlbeforeurl)
		Call stream.WriteText(tmpURL)
		
		htmlafterurl = |<font face="Arial" size="2"><br>
		Best Regards<br>
		Admin Team
		</font>|
		
		Call stream.WriteText(htmlafterurl)
		
		Call body.SetContentFromText (stream, "text/html;charset=iso-8859-1", ENC_NONE) 	

		Call message.Save( True, False )
	End If
	
	s.ConvertMIME = True ' Restore conversion
End Sub

Das Mail wird auch sehr schön versendet ABER:
Es ist dann immer beim öffnen in der Datenbank im Edit mode!!!
Wie bekomme ich es hin, dass das nicht so ist! Das Problem ist nämlich der link funktioniert dann klarerweise nicht!

Wenn ich diese Zeilen weg lasse:


      Dim mimeHeader As NotesMIMEHeader      
      Set mimeHeader = body.CreateHeader( "SMTPOriginator" )
      Call mimeHeader.SetHeaderVal( sender )
      Set mimeHeader = body.CreateHeader( "Sender" )
      Call mimeHeader.SetHeaderVal( sender )
      Set mimeHeader = body.CreateHeader( "INetFrom" )
      Call mimeHeader.SetHeaderVal( sender )
      Set mimeHeader = body.CreateHeader( "ReplyTo" )
      Call mimeHeader.SetHeaderVal( sender )
      Set mimeHeader = body.CreateHeader( "Principal" )
      Call mimeHeader.SetHeaderVal( sender )
      Set mimeHeader = body.CreateHeader( "From" )
      Call mimeHeader.SetHeaderVal( sender )
   
   
 dann ist das mail richtig und ich kann den link sofort anklicken ich hab aber keinen Sender drinnen stehen das will ich auch nicht haben:

Gibt es da eine Lösung für mein Problem?

danke Robert

[koehlerbv]

Setz da mal noch das PostedDate, sonst meint der Code in der empfangenden Mail-DB, dies sei ein Entwurf - und der wird im EditMode geöffnet (was ja auch Sinn macht).

Bernhard

[robertpp]

hallo Bernhard,

Echt dumm, das es daran gelegen hat!
Greift da notes wirklich einfach nur auf das Datum zum?

danke Robert

[robertpp]

Hallo,

Jetzt hab ich noch eine Frage dazu!

Kann ich den link auch so erstellen, dass es am Blackberry auch noch ein link ist?
Derzeit sehe ich am Blackberry nur den Text es ist aber kein link mehr?

danke Robert

[robertpp]

Hallo,

So jetzt hab ich auch das Problem, dass mein Link auch im Outlook funktionieren soll nur ist es dort auch nur ein reiner Text!

Kann mir da jemand einen tipp geben wie ich das hinbekomme, dass es im Exchange auch noch ein Link ist?

danke Robert

[m3]

So jetzt hab ich auch das Problem, dass mein Link auch im Outlook funktionieren soll nur ist es dort auch nur ein reiner Text!

Hmmmm.
Ich würd mal mit NotesMIMEEntity.ContentType auch einen korrekten Content-Type (text/html) setzten.

Ansonsten zeig mal die Mail her, wie sie im Outlool ankommt.

[robertpp]

Ich hab das Script jetzt schon so angepasst dass es jetzt so aussieht:

Code

	Dim s As New NotesSession
	Dim db As NotesDatabase
	Dim GroupDoc As NotesDocument
	Dim view As NotesView
	Dim body As NotesMIMEEntity
	Dim stream As NotesStream
	Dim tmpURL As String
	Dim item As NotesItem
	Dim memo As NotesDocument	
	Dim htmlbeforeurl As String, htmlafterurl As String	
	Dim mailbox As New NotesDatabase("","")
	Dim URL As String
	Dim SendTo As Variant
	Dim CopyTo As Variant
	Dim sendas As String
	Set db = s.CurrentDatabase	
	Set view = db.GetView ( "($Group)" )
	Set GroupDoc = view.GetDocumentByKey ( doc.Sendto(0) )	'field sendto = Groupfield
	SendTo = GroupDoc.Manager
	CopyTo = doc.Copyto(0)
	sendas = optiondoc.GetItemValue("SendFrom")(0)
	URL = "Server/(ActivateUser)?OpenAgent&UserID=" + doc.UserID(0)
	
	s.ConvertMIME = False
	Set stream = s.CreateStream
	
	Call mailbox.Open("Server","mail.box")
	If mailbox.IsOpen Then
		Set memo = mailbox.CreateDocument
		With memo
			.From = sendas
			.SendFrom = sendas
			.Form="memo"
			.Subject = "Activate User"
			.SendTo = SendTo
			.CopyTo = CopyTo
			.RecNoOutOfOffice = "1" 'Set it so out of office agents don't reply to the message
			Set body = .CreateMIMEEntity
			Set item =  .ReplaceItemValue("Recipients", SendTo)
			Call item.AppendToTextList(.CopyTo(0))
			
			htmlbeforeurl = 	_
			|<font face="Arial" size="2">Hi,<br><br>	
				There is a new user to activate:<br><br>
				Username is: | +doc.Username(0) + |<br>
				Email is: | +doc.email(0) + |<br>
				<br></font>
			|
			
			Call stream.WriteText(htmlbeforeurl)
			tmpURL = |<font face="Arial" size="2"><a href='| + URL + |'>Click Here to activate user</a></font><br>|		
			Call stream.WriteText(tmpURL)
			
			htmlafterurl = _
			|<font face="Arial" size="2"><br>
				Best Regards<br>
				Team
				</font>
			|
			
			Call stream.WriteText(htmlafterurl)
			
' 			Ensure the MIME content will be recognized as HTML (Must be after the stream is written)
			Call body.SetContentFromText(stream, "text/html",ENC_NONE)		
'			Call stream.Truncate
			
			.PostedDate = Now()
			.ComposedDate = Now()
			.DeliveredDate = Now()
			.EncryptOnSend = False
			Call .Save( True, False )
		End With
	End If
	
	s.ConvertMIME = True ' Restore conversion

Somit sollte der Content-Type auch passen!

Der link ist einfach nur noch Text!

[m3]

Mach mal aus

Code

URL = "Server/(ActivateUser)?OpenAgent&UserID=" + doc.UserID(0)

eine richtige URL

Code

URL = "http://Server/(ActivateUser)?OpenAgent&UserID=" + doc.UserID(0)

[robertpp]

Martin,

sorry ist nur beim Anonymisieren von mir so gelöscht worden:

Link sieht im Script eh so aus:

   

Code

URL = "http://Server/bla.nsf/(ActivateUser)?OpenAgent&UserID=" + doc.UserID(0)

Sonst noch einen Tipp?

Sollte das grundsätzlich so funkionieren oder ist da beim Routing oder Servereinstellung irgendetwas zu beachten?

danke Robert

[m3]

Wie gesagt, post mal, wie das im Outlool aussieht, so tu ich mir schwer, was zu sagen.

[robertpp]

So sieht das mail aus:


Es sieht so aus wie ein Link ist aber keiner mehr!

[m3]

DEN SOURCE !

[robertpp]

Wie soll ich dir den schicken?
Gibt es da im Outlook irgendetwas mit Sourcecode oder Quelltext?
Outlook ist fremdwort für mich! ;-)
danke robert

[robertpp]

Hallo,

Kann es sein das der Notes Connector kein HTML unterstützt und deshalb der link weg ist?

Ich hab das jetzt mit dem Notesconnector getestet da geht es bei einem schon bei einem anderen nicht und wenn es über smtp gesendet wird funktionert es!

robert

[m3]

BITTE gib so relevante Dinge wie "Outlool-Notes Connector" gleich von Anfang an an. Gruml.

Ad Outlook:
http://email.about.com/od/outlooktips/qt/et010905.htm

[robertpp]

Ich kann da leider nichts machen! Das Ding wird leider!!! eingesetzt! und jetzt hab ich den Ärger damit!!!!

robert

[m3]

Das ist schon klar. Aber DASS ist das Teil einsetzt solltest uns schon mitteilen, da es ev. Auswirkungen auf die Antwort hat.

[robertpp]

Da bin ich jetzt selber erst darauf gekommen, dass das blöde ding mir auf der einen Seite "eine Strich durch die Rechnung macht". Wobei bei dem anderen Notes Connector (ich glaub der ist etwas neuer) hat das super funktioniert.

Gibt es da jetzt ein Würgaround?