Kalendereinträge erstellen

[Haschn]

Hallo zusammen,

hat jemand von euch schonmal einen Kalendereintrag (Termin Ganztägig - über mehrere Tage) programmiertechnisch erstellt?

Folgender Hintergrund:
Einen einfachen Kalendereintrag zu erstellen, ist leicht. Aber sobald das Feld "CalendarDateTime" zum tragen kommt, komme ich einfach nicht mehr weiter. In diesem Feld stehen alle Tage einzeln in einem DateTime - Array. Aber wie fülle ich so ein Array? mit item.appendtotextlist gehts ja wohl schlecht, weil dann wäre es ja text - funktioniert auch nicht.

21.02.2007 04:00:00 CET
22.02.2007 04:00:00 CET
23.02.2007 04:00:00 CET

Hat jemand eine Ahnung? Am liebesten wäre mir eine Routine, von jemandem der das schonmal gelöst hat.

Vielen Dank!!

Gruß Andy

[koehlerbv]

Ja hamma denn heut' schoa Weihnoachten? 

Code

Function GetDateArray (vStartDate As Variant, vEndDate As Variant) As Variant
     '==================================================================================================================
     ' Purpose:		Build from given start end and end date an array of date/time variants containing all days between start and end date
      '------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
     ' Arguments:
	'					vStartDate - First date of the period (included) - must be variant of type "Date/Time"
	'					vLastDate - Last date of the period (included) - must be variant of type "Date/Time"
      '------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
     ' Returns:		An array of variants containing all days between start and end date
      '------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
     ' Created by:  	Bernhard Koehler on 10.04.2004            Modified by: 
     '------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
	' Changes:
     '==================================================================================================================
	
	Dim vResult () As Variant
	Dim iLoop As Integer
	
	On Error Goto ErrorRoutine
	
	'Check for correct values:
	If (Datatype (vStartDate) <> V_DATE) Or (Datatype (vEndDate) <> V_DATE) Then
		Exit Function
	End If
	If vEndDate - vStartDate < 0 Then
		Exit Function
	End If
	
	iLoop = vEndDate - vStartDate
	Redim vResult (0 To iLoop)
	
	vResult (0) = vStartDate
	For iLoop = 1 To Ubound (vResult)
		vResult (iLoop) = vStartDate + iLoop
	Next
	
	GetDateArray = vResult
	
	Exit Function
	
ErrorRoutine:
	Call ErrorHandler ("GetDateTimeArray")     
	Exit Function	
End Function

HTH,
Bernhard

PS: ErrorHandler ist selbst zu schreiben!

[koehlerbv]

Noch ein Nachtrag: Andy, bisher hast Du nur Fragen gestellt und Dich nachher trotz teilweiser umfangreicher Hilfestellung nie wieder dazu gemeldet, geschweige denn bedankt. Ich hoffe, dass das ab jetzt nicht mehr passiert! 

Bernhard (Moderator)

[Haschn]

Ja - du hast schon recht, melden sollte man sich schon nochmal... Hab mir das gerade nochmal angesehen, normal ist das auch nicht mein Stil ;-)

Aber vielen Dank für die Funktion, hat funktioniert!

[koehlerbv]