Bitte Erklärung: Excel in Notes nutzen.

[Darkface]

Hallo zusammen,
könnte mir mal jemand erklären, wie ich mit Lotus Notes auf Excel zugreifen kann und folgende Werte in die Tabelle schreiben kann.
Name
Vorname

Dies sind auch die Feldnamen im Dokument.

Über eine Antwort und eine Erklärung würde ich mich sehr freuen.

MFG
 Darkface

[Don Pasquale]

Hi,
hier ist ein Script mit dem ich ein Worddokument aufrufe.
Ich habe bisher halt nur auf Word zugegriffen,
in dem WordDokument waren Felder eingefügt (hier: IDENTNUMMER)
Vielleicht kannst Du das Script ja umstricken

Don Pasquale

Code

      
      Dim workspace As New NotesUIWorkspace 
      Dim uidoc As NotesUIDocument 
      Set uidoc = workspace.CurrentDocument       
      Dim object As NotesEmbeddedObject       
      Dim s As New notessession 
      Dim heute As New notesdatetime("heute") 
      Dim word As Variant 
      Dim wordoc As Variant 
      Dim Worddokumentname As String 
      Dim Identnummer As String
      'Predefined values: (replace with field values from uidoc) 
      Worddokumentname = uidoc.FieldGetText("subject") 
      
'Create the Word object: 
      Set word = CreateObject("Word.Application") 'Create Word object 
     'Create a new document based on the template "TESTVORLAGE01.DOT"       
      Call word.documents.add("C:\Vorlagen\Vorlage01.dot")       
      Set worddoc = word.activedocument 'Get a handle for the active document 
      
'Assign the field values: 
      
      worddoc.FormFields("IDENTNUMMER").result = uidoc.FieldGetText("Identnummer")
      
      worddoc.saveas(Worddokumentname) 'save the document with the filename of "user" 
      word.visible = True 'Comment this line if you don't want to show Word. 
'word.quit 'remove comment if you want to close rather than show Word. 
      

[Axel]

Hi,

ich hab vor einiger Zeit mal eine Klasse für den Zugriff auf Excel geschrieben. Ist mit Sicherheit noch nicht das Non-Plus-Ultra, aber sie funktioniert. Ich will sie irgendwann, wenn mal Zeit ist, neu machen.

Packe die Codezeilen in den Declaration - Teil einer Script-Bibliothek.

Class cExcel
     
     objExcel As Variant
     objSheet As Variant    
     
'  Konstruktor
     Sub New
           Set objExcel = Nothing
           Set objExcel = CreateObject("Excel.Application")          
     End Sub
     
'  Destruktor-Prozedur
     Sub Delete
           Set objExcel = Nothing        
     End Sub
     
' Bringt Excel als Vollbild in den Vordergrund
     Sub ActivateExcel
           objExcel.Visible = True  'Excel sichtbar machen
           objExcel.Windows(1).WindowState = -4137
           objExcel.Windows(1).Activate
     End Sub
     
'  Erstellt eine neue Arbeitsmappe    
     Sub NewWorkbook
           Call objExcel.Workbooks.Add
           Set objSheet = objExcel.Workbooks(1).Worksheets(1)
     End Sub
     
'  Schreibt einen Wert in die angegebene Zelle
     Sub SetCellValue(sZiel As Variant, sValue As Variant)
           objSheet.Range(sZiel).Value = sValue
     End Sub
     
' Formatiert einen Bereich als Text
     Sub FormatRangeText(sZiel As Variant)        
           objSheet.Columns(sZiel).Select
           objExcel.Selection.NumberFormat ="@"
           objSheet.Range("A1").Select
     End Sub
     
'Formatiert ein Arbeitsblatt mit den Attributen vertikale Textausrichtung oben und
'optimale Spaltenbreite
     Sub FormatRangeAlignment
           objSheet.Cells.Select  'Gesamtes Arbeitsblatt markieren
           objExcel.Selection.VerticalAlignment = -4160  'Vertikale Ausrichtung nach oben
           objExcel.Selection.Columns.AutoFit  'Optimale Spaltenformel
           objExcel.Selection.Rows.AutoFit  'Optimale Spaltenhöhe
           objSheet.Range("A1").Select          
     End Sub
     
     
End Class

Beispiel:


...

Dim oExcel As cExcel    

Set oExcel = New cExcel  'Erstellen eines OLE-Objects
Call oExcel.NewWorkbook 'Erstellt neue Arbeitsmappe
Call oExcel.SetCellValue("A1", doc.Feldname(0)) 'Feldinhalt in Zelle A1
Call oExcel.ActivateExcel  'Excel in den Vordergrund
Delete oExcel
...



Axel

[Axel]

Hi,

ich hab noch was gefunden. Schau mal hier, vielleicht kannst du damit was anfangen.

http://217.160.137.156/html/cgi-bin/yabb/YaBB.pl?board=Downloads;action=display;num=1014050197

Axel

[Don Pasquale]

Hi Axel,

Call oExcel.SetCellValue("A1", doc.Feldname(0)) 'Feldinhalt in Zelle A1

hier bekomme ich eine "Variant does not contain Object"
Meldung - Wo habe ich etwas übersehen ??

pasquale

[Axel]

Hi,

hast du die Variable doc (Typ NotesDocument) initialisiert und einen gültigen Feldnamen benutzt ?


Axel

[Darkface]

Jetz sagt er bei mir:
Object variable not set

Gruß
Darkface

[Axel]

Hi,

hab ihr auch die Script-Bibliothek, in der die Klasse enthalten ist, eingebunden ?

Angenommen die Bibliothek heisst libExcel, dann muß die Bibliothek mit

  uses "libExcel"  (im Options - Teil)

eingebunden werden.

Axel

[Darkface]

Ich habe alles so wie es seien sollte.

Code

      Dim objExcel As CExcel      
      Dim doc As NotesDocument
      
      ' Erstellen eines OLE-Objects
      Set objExcel = New CExcel 
      ' Erstellt neue Arbeitsmappe 
      Call objExcel.NewWorkbook
      ' Ziel, Feldinhalt 
      Call objExcel.SetCellValue("A1", doc.Feldname(0))
      ' Excel in den Vordergrund      
      Call objExcel.ActivateExcel 
      Delete objExcel 

Das habe ich und deine Scriptbibliothek.

Gruß
 Darkface

[Axel]

Hi,

hier mal ein komplettes Beispiel für einen Aktionsbutton im Dokument:

(Options)
Use "libExcel"

Click
Sub Click(Source As Button)

 Dim ws As New NotesUIWorkspace
 Dim uidoc As NotesUIDocument
 Dim doc As NotesDocument
 Dim oExcel As cExcel      

 Set uidoc = ws.CurrentDocument
 Set doc = uidoc.Document

 Set oExcel = New cExcel  'Erstellen eines OLE-Objects
 Call oExcel.NewWorkbook 'Erstellt neue Arbeitsmappe
 Call oExcel.SetCellValue("A1", doc.Feldname(0)) 'Feldinhalt in Zelle A1
 Call oExcel.ActivateExcel  'Excel in den Vordergrund
 Delete oExcel

End Sub

Anmerkungen:
Die Script-Bibliothek mit der Klasse heißt libExcel.
Feldname muss durch den Namen, eines in der Maske vorhandenen Feldes, ersetzt werden.

Noch eine Anmerkung zur Script-Bibliothek: man muss darauf achten, dass im Options-Teil Option Public eingetragen ist. Sonst ist die Klasse ausserhalb der Bibliothek nicht sichtbar.

Axel

[Darkface]

Hi Axel,
wenn du mir jetz noch sagen kannst, wie man die Datei Automatisch speichern kann und das Die erste Zeile mit Fetter Schrift ist, dann bin ich dir mehr als dankbar.

Bin dir jetzt schon was schuldig.

Gruß
 Darkface

[Axel]

Hi,

hab ich in Excel noch nicht gemacht. Geb mir bitte ein bisschen Zeit, dann krieg ich es raus. In Word hab ich's mal hingekriegt.

Axel

[Darkface]

Das mit der Fetten Schrift geht so:

Code

m_oSheet.Range("A1 : H1").Font.Bold = True

Aber das Speichern, das macht Probleme.
Danke schon mal.


Gruß
Darkface

[Axel]

Hi,

hier eine Lösung zum Speichern.

Erweitere die Klasse um folgendene Methode:

Sub SaveWorkbook(strName As String)      
 Call objExcel.ActiveWorkbook.SaveAs(strName)
End Sub

Der Dateiname wird als Parameter übergeben.


Der Aufruf sieht dann so aus:

Call oExcel.SaveWorkbook("d:\temp\test.xls")


Axel

[Don Pasquale]

Hi Axel,

jetzt klappt es bei mir auch.

Allerdings produziert
Call oExcel.SetCellValue("A1", doc.Feldname(0))
immer einen Type Mismatch

So klappt´s :
Call oExcel.SetCellValue("A1",doc.Feldname)


Gruß

Don Pasquale

[Darkface]

Jetz noch ne größer Frage:
Gibt es auch bei diesem Script die Möglichkeit, wenn man 20 Dokumente hat alle in diese Excel Tabelle zu schreiben.
Mit einem Agenten im Backend?

Gruß
 André

[Axel]

Hi,

ich denke schon. Das ist dann ein getriggerter Agent (d.h. er läuft bei einem bestimmten Ereignis oder zu einer bestimmten Uhrzeit). Er darf dann keine Forntend-Klassen (NotesUIDocument usw.) enthalten.

Ganz wichtig ist dabei auch, wenn dieser Agent auf dem Server läuft, dass dort Excel installiert ist.

Vor einem solchen Problem stand ich noch nicht. Hier fehlt mir die Erfahrung.


Axel

[Darkface]

Hi Axel,
dank für deine Hilfe. Du bist schwer in Ordnung.

DANKE !!

Gruß
 Darkface