von einer DB zur anderen ?

[bwinger]

Hallo,
es dürfte recht einfach sein, nur bin ich leider recht neu in der Materie.
Wie bekomme ich von DB mail.nsf zugriff auf eine mitarbeiter.nsf .
Sinn des ganzen ist eine erstellung einer Signatur mittels button. in der Mitarbeiter nsf habe ich eine Ansicht mit Vorname und Nachname in der ersten spalte.
nun möchte ich diese als schluessel benutzen und die erte aus dieser Zeile für die signatur benutzen.
mit evaluate(|dblookup .... |) bin ich nicht zum ziel gekommen, nur leeres Feld.
Falls das nicht möglich ist, wie bekomme ich in der Mitarbeiter DB aus die Datenbank raus in eine Formatierte Text-Datei, möglichst einfach natürlich. Dabei muss aber jeder eintrag eine Datei sein im muster vorname_Nachname.sig

Da das ganze zu komplex ist, reicht mal so ein anstoss zum selber schreiben.

:Bernd

[mahonri]

Probiers mit einer Aktion die auf eine Ansicht in deiner MADB zugreift

_Title := "Signatur anhängen";
_ErrorINI := "Fehler in Datei \"Notes.ini\", bitte erneut versuchen.";
_ErrorSource := "keine Signatur gefunden";

REM "Reading Signature --------------------------";
_Server   := @Subset(@DbName; 1);
_SourceDB := "Mitarbeiter.nsf";
_View := "(Signaturen)";
_Name := @Name([Abbreviate]; @UserName);
_Row := 2;

_Value := @DbLookup("":"NoCache"; _Server:_SourceDB; _View; _Name; _Row);
@If(!@IsError(_Value);
 @Set("_Value"; @ReplaceSubstring(@Trim(@ReplaceSubstring(_Value; "  "; "##")); "##"; "  "));
 ""
);
DisplayText := @Implode(@If(@IsError(_Value); _ErrorSource; _Value); @NewLine);

@Command([EditInsertText]; @Left(DisplayText; 250));
@Command([EditInsertText]; @Middle(DisplayText; 250; 250));
@Command([EditInsertText]; @Middle(DisplayText; 500; 999));
""



Die Zweite Spalte in der Ansicht könnte dann folgende Formel haben:

_Tab := @Char(9);
_Signature := "Mit freundlichen Grüßen" + @NewLine;
_Name := @Implode(@Trim(PersTitle : @Subset(@Name([CN]; FullName); 1)); " ");
_Delimiter := ">>>----------------------------------";
_Address := @Implode(@Trim(Street : Location); ", ");
_JobTitle := JobTitle;
_Company := @Implode(@Trim(CompanyTitle : CompanyName); " ");
_Phone := @If(OfficePhoneNumber != ""; "Tel:" + _Tab + @Subset(OfficePhoneNumber; 1); "");
_Fax := @If(OfficeFaxPhoneNumber != ""; "Fax:" + _Tab + @Subset(OfficeFaxPhoneNumber; 1); "");
_Mobile := @If(Handy != ""; "Mobil:" + _Tab + @Subset(Handy; 1); "                               ");
_Internet := InternetAddress;
_EMailAt := @Left(@Subset(ShortName; 1) + "@"; "@") + "@" + ExtDomain;
_EMail := @If(
 @Trim(_Internet) != ""; "E-Mail:" + _Tab + _Internet;
 ShortName != ""; "E-Mail:" + _Tab + _EMailAt;
  ""
);
_Net := "Internet:" + _Tab + "http://www." + ExtDomain;
phone_mob  := phone   + @If(mobile  != ""; ", " + mobile;  "");

_Signature : _Name : _JobTitle : _Company : _Address : _Phone : _Fax : _Mobile : _EMail : _Net

Funktioniert ganz passabel, Die Aktion fügt an der gewählten Stelle die Signatur ein.