Inhalte von .pdf und .doc in rtf-feld anzeigen

[Smash]

Hallo @all,
ich benötige Hilfe oder eine Idee, wie ich den Inhalt von .pdf oder .doc-dateien in Notes importieren kann, so dass der Inhalt im neuen Notes-Dok direkt sichtbar wird. Also ich möchte keine Attachments oder Objects im Notes-Dok haben.
Hat irgendeiner Erfahrungen damit??
Danke in Voraus
Smash

[Semeaphoros]

Dot Doc kannst Du doch über File - Import importieren? Wo ist das Problem?

PDF ist nicht so einfach, weil Format für einen Import nicht vorgesehen ist.

[Smash]

Nun, vielleicht hätte ich erwähnen sollen, dass dieser Import im Zuge eines Background-Agenten geschehen soll, und da konnte ich bisher nur den File als EmbeddedObject einfügen. Ich möchte aber den Inhalt des Files direkt im RTF-Feld anzeigen lassen.

[Semeaphoros]

Wie wäre es damit:


Call notesUIDocument.Import( [ filter$ , filename$ ] )

[Smash]

Ja, habe ich auch schon dran gedacht, aber da ich mich Backend bewege und nicht im Frontend wird das wohl nicht gehen. Werde das aber nochmal austesten.

[koehlerbv]

Das funktioniert garantiert NICHT im Backend. Und PDF kann m.E. überhaupt nicht importiert werden, auch nicht im Frontend.

Bernhard

[animate]

wenn ich mich nicht irre, dann kannst du dir was aus der OfficeLibrary abschauen.

da sind z.b. Worddokumente auch als eingebette Objekte in NotesDokumenten gespeichert, werden aber beim Öffnen eines Notes Doks "aktiviert". also der Inhalt wird angezeigt

aber ich bin mir nicht wirklich sicher, ob das stimmt.

[TMC]

Eine Alternative wäre es, dass Du das PDF direkt im Notes-Client anzeigst (ohne eigenes Fenster).




Ich hab mal eine Beispiel-DB attached.....

Matthias


** Edit **
Beispiel-DB gelöscht, hier ist die aktuelle DB:
http://www.atnotes.de/index.php?board=9;action=display;threadid=15076

[koehlerbv]

Interessantes Phänomen: Wenn ich das Dokument in Deiner DB im Lesenmodus öffne, ist es leer. Öffne ich es im Bearbeiten-Modus, sehe ich ein PDF-Attachment darin.

Was läuft da schief ?

Bernhard

[TMC]

Hängt vielleicht der Acrobat (Reader) noch irgendwie im Taskmanager drin?

Versuche bitte mal folgendes:
- Notes-Client schließen
- Adobe (Acrobat) abschiessen im Taskmanager
- Notes-Client starten
- Nochmal versuchen (Dok doppelklicken)

Ich selbst habe das noch nicht produktiv eingesetzt, wusste nur dass es da was gibt :-)

Die PDF-Datei im Anhang wird btw im Windows-Temp-Verzeichnis gespeichert.......
Die PDF sollte im Lese-Modus angezeigt werden, im Bearbeiten-Modus nicht (sondern das Attachment).

Matthias

[TMC]

Bernhard, ich konnte gerade denselben Fehler feststellen (Fenster bleibt leer).

Wenn ich dann 3 Msgboxes hinzufüge im Postopen, dann geht es.

Code

Sub Postopen(Source As Notesuidocument)
   Dim doc As NotesDocument   
   Dim adobe As Variant
   Dim rtItem As Variant
   Dim strWinTemp As String
   Dim strStartPDF As String
   
   If Source.EditMode = True Then Exit Sub 'Exit wenn Dok in Bearbeitung
   
   Set doc= Source.Document
   Set adobe = Source.GetObject("Acrobat Control for ActiveX")
   Set rtItem = doc.GetFirstItem("PDF")
   
   strWinTemp = WinTemp 'see function.....
   Msgbox "strWinTemp"
   
   Forall obj In rtItem.EmbeddedObjects
      If (obj.Type=Embed_Attachment) Then
         Call obj.ExtractFile(strWinTemp & "\" & obj.Source)
         Msgbox "Extrahiert"         
         adobe.LoadFile(strWinTemp & "\" & obj.Name)
         Msgbox "Geladen"
      End If
   End Forall
   
End Sub

Wohl ein Timing-Problem? Vielleicht sollte man einen sleep einbauen..... ??

Matthias

[koehlerbv]

AFAICS: Sleep bringt nix. Die Massage-Kiste
Msgbox "Extrahiert"
ist der Punkt - diese alleine reicht, um das Ding zum Laufen zu bringen.
Mystisch, aber schon mal ein Ansatz ;-)

Bernhard

[animate]

nur ne Idee, ohne die Syntax zu kennen:

If obj.ExtractFile then
...
End if

[TMC]

Hmm, Problem ist ja, dass das File immer extrahiert wird. Das klappt also.

Nur eben ohne Msgbox geht es nicht immer.
Habe es gerade auch unter R6.5 getestet, da verhält es sich genau so.

Kann man denn eine geöffnete Msgbox per Befehl schliessen? Dies wäre dann zumindest ein Workaround.....

Matthias

[Axel_Janssen]

was ist hiermit?

[TMC]

Axel, genau habe ich in meiner Beispiel-DB verwendet  

Matthias

[Axel_Janssen]

:outsch:  
vielleicht ist das Internet Explorer plug-in irgendwie stabiler.

[koehlerbv]

Ich kriege einen Klaps - das ActiveX-Control will wirklich, dass vorher irgendwas im FrontEnd passiert !
Mit folgendem Code im PostOpen geht es sich - dazu muss man sich noch eine Maske "(DummyForm") basteln, und die Adobe-Maske sollte die Vorgabemaske sein.

Code

Sub Postopen(Source As Notesuidocument)
   Dim ws As New NotesUIWorkspace   
   Dim session As New NotesSession
   Dim dbCurrent As NotesDatabase
   Dim docTemp As NotesDocument
   Dim uidocTemp As NotesUIDocument
   
   Dim doc As NotesDocument   
   Dim adobe As Variant
   Dim rtItem As NotesRichTextItem
   Dim strWinTemp As String
   Dim strStartPDF As String
   
   On Error Goto ErrorRoutine
   
   If Source.EditMode = True Then Exit Sub 'Exit wenn Dok in Bearbeitung
   
   Set doc= Source.Document
   Set adobe = Source.GetObject("Acrobat Control for ActiveX")
   Set rtItem = doc.GetFirstItem ("PDF")
   
   strWinTemp = WinTemp 'see function.....
   'Msgbox "strWinTemp"
   
   Forall obj In rtItem.EmbeddedObjects
      If (obj.Type=Embed_Attachment) Then
         Call obj.ExtractFile(strWinTemp & "\" & obj.Source)
         'Sleep (5)
         'Msgbox "Extrahiert" 
         Set dbCurrent = session.CurrentDatabase
         Set docTemp = dbCurrent.CreateDocument
         docTemp.Form = "(DummyForm)"
         Set uidocTemp = ws.EditDocument (False, docTemp, True)
         Call uidocTemp.Close
         
         adobe.LoadFile(strWinTemp & "\" & obj.Name)
         'Msgbox "Geladen"
      End If
   End Forall
   
   Exit Sub
   
ErrorRoutine:
   Msgbox "An error occured: " & Error$ & " (in line " & Cstr (Erl) & ")"
   Exit Sub
   
End Sub

Mal sehen, ob dafür einer eine logische Begründung findet ...

By the way: Hilft das eigentlich bei der ursprünglichen Frage dieses Threads ? Unschön ist auch die Bedienung, um aus dem PDF wieder back to Notes zu kommen - die meisten Anwender werden da wohl aus Versehen Notes schliessen anstatt Adobe Acrobat Reader (mit Babelfish: "Lehmziegel Turner Leser" ;-) zu schliessen. Aber die Idee an sich hat was.

Ciao,
Bernhard

[koehlerbv]

Nachtrag:
An sich wäre es ja nett, wenn man die sowieso vorhandene Form "Adobe" für NotesUIWorkspace.EditDocument gleich verwenden könnte. Aber hier gilt:
"Wer ander'n eine Gräbe grubt,
sich selber in die Nase pupt !"
Damit wird ja gleich wieder das PostOpen der zu öffnenden Maske ausgeführt ... Würde Notes da nicht nach einer Weile selber streiken, wäre dies: "'In Ewigkeit - Amen !', sprach die Endlosschleife ..."

Wegen letzterem: Jeeeeeeeeens !

Ciao,
Bernhard

[TMC]

An sich wäre es ja nett, wenn man die sowieso vorhandene Form "Adobe" für NotesUIWorkspace.EditDocument gleich verwenden könnte. Aber hier gilt:
"Wer ander'n eine Gräbe grubt,
sich selber in die Nase pupt !"
Damit wird ja gleich wieder das PostOpen der zu öffnenden Maske ausgeführt ...

Geht schon:

Code

Sub Postopen(Source As Notesuidocument)
   On Error Goto errHandler
   
   Dim ws As New NotesUIWorkspace
   Dim session As New NotesSession
   Dim dbCurrent As NotesDatabase
   Dim docTemp As NotesDocument
   Dim uidocTemp As NotesUIDocument
   Dim doc As NotesDocument
   Dim adobe As Variant
   Dim rti As NotesRichTextItem
   Dim strWinTemp As String
   Dim strStartPDF As String
   Dim oFirst As NotesEmbeddedObject
   
   If Source.EditMode = True Then Exit Sub 'Exit wenn Dok in Bearbeitung
   
   
   Set doc= Source.Document
   
   If source.FieldGetText("TempFlag")  = "1"   Then Exit Sub
   
   Set adobe = Source.GetObject("Acrobat Control for ActiveX")
   Set rti = doc.GetFirstItem("PDF")
   
   Set oFirst = rti.EmbeddedObjects(0)
   
   If oFirst Is Nothing Then
      Msgbox "No embedded object in document"
      Exit Sub
   End If
   
   strWinTemp = WinTemp 'see function.....
   
   Call oFirst.ExtractFile(strWinTemp & "\" & oFirst.Source)
   
   Set dbCurrent = session.CurrentDatabase
   Set docTemp = dbCurrent.CreateDocument
   docTemp.Form = "Adobe"
   docTemp.TempFlag = "1"
   Set uidocTemp = ws.EditDocument (False, docTemp, True)
   Call uidocTemp.Close
   adobe.LoadFile(strWinTemp & "\" & oFirst.Name)
   
exitScript:
   Exit Sub
   
errHandler:
   Msgbox "An error occured." & Chr(10)  & Chr(10) _
   & "Error text: " & Error$ & Chr(10) _
   & "Error number: " & Err & Chr(10) _
   & "Line: " & Erl & Chr(10) _
   ,64,"Error"
   Resume exitScript
   
End Sub

Bitte nicht erschrecken, ist mein Baustellen-Code zum testen :-)

Ich habe in der Maske ein Hidden-Field "TempFlag".

So klappt es jetzt lt. den ersten Tests

Matthias