Autor Thema: Inbox bereinigen  (Gelesen 9296 mal)

Offline HarryB

  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 521
  • Geschlecht: Männlich
Inbox bereinigen
« am: 19.08.08 - 11:04:45 »
Hallo zusammen,

ich schreibe gerade einen Agenten, der einmal die Woche über die Mailbox laufen soll und alle Mails, die älter sind als 30 Tage, in einen anderen Ordner verschieben. Zusätzlich soll das ganze nur laufen, wenn mehr als 200 Dokumente in der Mailbox sind.

Nun ist es so, dass mein Code nicht alle Mails verschiebt, die den Kriterien entsprechen. Lasse ich den Agenten noch mal laufen, verschiebt er wieder ein paar Mails, aber wieder nicht alle. Die Frage ist: wo liegt mein Denkfehler?

Anbei mein Code.

Code
Sub Initialize
	
	'Inbox Maintenance
	'Periodisches Aufräumen des Meileingangs zur Performanceverbesserung
	
	Const archiveFolder = "Maileingang - Archiv"
	Const inboxLimit = 200 'Anzahl Dokumente
	Const maxAge = 30 'in Tagen
	
	Dim ses As New NotesSession
	Dim currentDb As NotesDatabase
	Dim inbox As NotesView
	Dim mailDoc As NotesDocument
	Dim moveDoc As NotesDocument
	Dim movedDocs As Integer
	Dim mailCreated As NotesDateTime
	Dim cutoffDate As NotesDateTime
	
	Set currentDb = ses.CurrentDatabase
	
	'Eingangsordner heranziehen
	Set inbox = currentDb.GetView("($Inbox)")
	
	'Prüfen, wie viele Dokumente im Eingang liegen; wenn Limit überschritten, aktiv werden
	If (inbox.EntryCount > inboxLimit) Then
		
		'Wenn Schwellwert überschritten, alls Mails die älter sind als x Tage in Archiv verschieben
		Set cutoffDate = New NotesDateTime(Cstr(Today))
		Call cutoffDate.AdjustDay(-1 * maxAge)
		Set mailCreated = New NotesDateTime("")
		
		Set mailDoc = inbox.GetFirstDocument
		
		While Not (mailDoc Is Nothing)
			
			mailCreated.LSLocalTime = mailDoc.Created
			
			If (cutoffDate.TimeDifference(mailCreated) > 0) Then
				
				Set moveDoc = mailDoc
				
			End If '(cutoffDate.TimeDifference(mailCreated) > 0)
			
			Set mailDoc = inbox.GetNextDocument(mailDoc)
			
			If Not (moveDoc Is Nothing) Then
				
				movedDocs = movedDocs + 1
				
				Call moveDoc.PutInFolder(archiveFolder, True)
				Call moveDoc.RemoveFromFolder("($Inbox)")
				
				Set moveDoc = Nothing
				
			End If 'Not (moveDoc Is Nothing)
			
		Wend 'Not (mailDoc Is Nothing)
		
	End If '(inbox.EntryCount > inboxLimit)
	
	Print Cstr(movedDocs) + " Dokumente verschoben"
	
End Sub

Vielen Dank
Harry
« Letzte Änderung: 19.08.08 - 14:02:16 von HarryB »
Harald "HarryB" Börger

2 x 7.0.2FP1 auf AIX (Cluster)
1 x 7.0.2FP2 auf AIX
1 x 6.5.5 auf AIX
4 x 7.02.FP2 auf WIN

Clients: 7.0.2

Offline m3

  • Freund des Hauses!
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 8.102
  • Geschlecht: Männlich
  • Non ex transverso sed deorsum!
    • leyrers online pamphlet
Re: Inbox bereinigen
« Antwort #1 am: 19.08.08 - 11:19:46 »
1) "ich schreibe gerade einen Agenten, der einmal die Woche über die Mailbox Inbox laufen soll und alle Mails, die älter sind als 30 Tage, in einen anderen Ordner verschieben. Zusätzlich soll das ganze nur laufen, wenn mehr als 200 Dokumente in der Mailbox Inbox sind." - dann versteht man auch, was Du meinst.

2) Ich würde eher über NotesView.AllEntries iterieren. Mit Löschen/Verschieben und GetNextDocument bin ich schon mal eingefahren.

3) Oder gleich mit NotesView.FTSearch nur die Dokumente bearbeiten, die den Kriterien entsprechen.

HTH
m³ aka. Martin -- leyrers online pamphlet | LEYON - All things Lotus (IBM Collaborations Solutions)

All programs evolve until they can send email.
Except Microsoft Exchange.
    - Memorable Quotes from Alt.Sysadmin.Recovery

"Lotus Notes ist wie ein Badezimmer, geht ohne Kacheln, aber nicht so gut." -- Peter Klett

"If there isn't at least a handful of solutions for any given problem, it isn't IBM"™ - @notessensai

Driri

  • Gast
Re: Inbox bereinigen
« Antwort #2 am: 19.08.08 - 11:25:18 »
Ist sichergestellt, daß der Archivordner existiert ? Sonst müßtest Du das auf jeden Fall noch abfangen.

So auf den ersten Blick fällt mir sonst nichts ins Auge. Alternativ zur Verwendung von 2 NotesDocuments (maildoc, movedoc) könntest Du auch für die Inbox das AutoUpdate deaktivieren und nach der Verarbeitung wieder aktivieren. Damit sparst Du dir das temporäre Zuweisen des zu verarbeitenden Dokumentes in ein zweites NotesDocument.

Offline m3

  • Freund des Hauses!
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 8.102
  • Geschlecht: Männlich
  • Non ex transverso sed deorsum!
    • leyrers online pamphlet
Re: Inbox bereinigen
« Antwort #3 am: 19.08.08 - 11:32:04 »
Nun ist es so, dass mein Code nicht alle Mails verschiebt, die den Kriterien entsprechen. Lasse ich den Agenten noch mal laufen, verschiebt er wieder ein paar Mails, aber wieder nicht alle. Die Frage ist: wo liegt mein Denkfehler?
In solchen Fällen schreibe ich bei jeder if-Abfrage einen Log-Eintrag. Damit sollte sich herausstellen, warum manche Dokumente nicht gleich genommen werden.
HTH
m³ aka. Martin -- leyrers online pamphlet | LEYON - All things Lotus (IBM Collaborations Solutions)

All programs evolve until they can send email.
Except Microsoft Exchange.
    - Memorable Quotes from Alt.Sysadmin.Recovery

"Lotus Notes ist wie ein Badezimmer, geht ohne Kacheln, aber nicht so gut." -- Peter Klett

"If there isn't at least a handful of solutions for any given problem, it isn't IBM"™ - @notessensai

Offline HarryB

  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 521
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #4 am: 19.08.08 - 11:41:45 »
Ist sichergestellt, daß der Archivordner existiert ? Sonst müßtest Du das auf jeden Fall noch abfangen.
Ja, das ist mit 'Call moveDoc.PutInFolder(archiveFolder, True)' bereits sichergestellt (das 'True' bezieht sich auf 'CreateOnFail'). Der Ordner wurd auch im ersten Durchlauf korrekt erstellt.
Harald "HarryB" Börger

2 x 7.0.2FP1 auf AIX (Cluster)
1 x 7.0.2FP2 auf AIX
1 x 6.5.5 auf AIX
4 x 7.02.FP2 auf WIN

Clients: 7.0.2

Offline HarryB

  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 521
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #5 am: 19.08.08 - 11:43:39 »
1) "ich schreibe gerade einen Agenten, der einmal die Woche über die Mailbox Inbox laufen soll und alle Mails, die älter sind als 30 Tage, in einen anderen Ordner verschieben. Zusätzlich soll das ganze nur laufen, wenn mehr als 200 Dokumente in der Mailbox Inbox sind." - dann versteht man auch, was Du meinst.
Wir korrigiert.  :-[

2) Ich würde eher über NotesView.AllEntries iterieren. Mit Löschen/Verschieben und GetNextDocument bin ich schon mal eingefahren.
Über AllEntries bin ich auch gestolpert. Ich probiere das mal.

3) Oder gleich mit NotesView.FTSearch nur die Dokumente bearbeiten, die den Kriterien entsprechen.
Es sind nicht alle Datenbanken volltextindiziert. Das ist dann auch kein Spaß.

Viele Grüße
Harry
Harald "HarryB" Börger

2 x 7.0.2FP1 auf AIX (Cluster)
1 x 7.0.2FP2 auf AIX
1 x 6.5.5 auf AIX
4 x 7.02.FP2 auf WIN

Clients: 7.0.2

Offline HarryB

  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 521
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #6 am: 19.08.08 - 13:26:48 »
2) Ich würde eher über NotesView.AllEntries iterieren. Mit Löschen/Verschieben und GetNextDocument bin ich schon mal eingefahren.
Damit klappt es. :D

Anbei das funktionierende Script.

Code
Sub Initialize
	
	'Inbox Maintenance
	'Periodisches Aufräumen des Meileingangs zur Performanceverbesserung
	
	Const archiveFolder = "Maileingang - Archiv" 'Name des anzulegenden Ordners
	Const inboxLimit = 200 'Anzahl Dokumente
	Const maxAge = 30 'in Tagen
	
	Dim ses As New NotesSession
	Dim currentDb As NotesDatabase
	Dim inbox As NotesView
	Dim allEntries As NotesViewEntryCollection
	Dim mailEntry As NotesViewEntry
	Dim mailDoc As NotesDocument
	Dim moveDoc As NotesDocument
	Dim movedDocs As Integer
	Dim mailCreated As NotesDateTime
	Dim cutoffDate As NotesDateTime
	
	Set currentDb = ses.CurrentDatabase
	
	'Eingangsordner heranziehen
	Set inbox = currentDb.GetView("($Inbox)")
	
	'Prüfen, wie viele Dokumente im Eingang liegen; wenn Limit überschritten, aktiv werden
	If (inbox.EntryCount > inboxLimit) Then
		
		'Wenn Schwellwert überschritten, alls Mails die älter sind als x Tage in Archiv verschieben
		Set cutoffDate = New NotesDateTime(Cstr(Today))
		Call cutoffDate.AdjustDay(-1 * maxAge)
		Set mailCreated = New NotesDateTime("")
		
		Set allEntries = inbox.AllEntries
		Set mailEntry = allEntries.GetFirstEntry
		
		While Not (mailEntry Is Nothing)
			
			Set mailDoc = mailEntry.Document
			mailCreated.LSLocalTime = mailDoc.Created
			
			If (cutoffDate.TimeDifference(mailCreated) > 0) Then
				
				Set moveDoc = mailDoc
				
			End If '(cutoffDate.TimeDifference(mailCreated) > 0)
			
			Set mailEntry = allEntries.GetNextEntry(mailEntry)
			
			If Not (moveDoc Is Nothing) Then
				
				movedDocs = movedDocs + 1
				
				Call moveDoc.PutInFolder(archiveFolder, True)
				Call moveDoc.RemoveFromFolder("($Inbox)")
				
				Set moveDoc = Nothing
				
			End If 'Not (moveDoc Is Nothing)
			
		Wend 'Not (mailDoc Is Nothing)
		
	End If '(inbox.EntryCount > inboxLimit)
	
End Sub
Harald "HarryB" Börger

2 x 7.0.2FP1 auf AIX (Cluster)
1 x 7.0.2FP2 auf AIX
1 x 6.5.5 auf AIX
4 x 7.02.FP2 auf WIN

Clients: 7.0.2

Offline Hirnbeisz

  • Frischling
  • *
  • Beiträge: 26
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #7 am: 19.08.08 - 19:23:18 »
Im Ausgangsscript hätte aus meiner Sicht auch ein
         
If Not (moveDoc Is Nothing) Then
    Set mailDoc = inbox.GetfirstDocument
else
   Set mailDoc = inbox.GetNextDocument(mailDoc)

gereicht!



Gruß Aloisius! ;)
« Letzte Änderung: 19.08.08 - 21:52:46 von Hirnbeisz »
Gruß Aloisius

Offline koehlerbv

  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 20.460
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #8 am: 19.08.08 - 20:28:04 »
Das ist richtig.

Probleme treten sonst allein schon bei ResponseDocs auf, da mit RemoveFromFolder diese automatisch mitgenommen werden. An sich ist das lieb und nett von Notes, aber mit solchen Konstrukten fällt man dann eben auf die Nase.

Bernhard

@"Hirnbeisz": Hast Du auch einen richtigen Namen? Das wird hier sehr gern gesehen.
Auf jeden Fall aber Danke einen Deinen helfenden Einstieg hier.

Offline HarryB

  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 521
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #9 am: 26.08.08 - 09:43:24 »
Probleme treten sonst allein schon bei ResponseDocs auf, da mit RemoveFromFolder diese automatisch mitgenommen werden. An sich ist das lieb und nett von Notes, aber mit solchen Konstrukten fällt man dann eben auf die Nase.
Ist das auch bei Ansichten/Ordnern so, in denen die Antworten nicht hierarchisch angezeigt werden?

Viele Grüße
Harry
Harald "HarryB" Börger

2 x 7.0.2FP1 auf AIX (Cluster)
1 x 7.0.2FP2 auf AIX
1 x 6.5.5 auf AIX
4 x 7.02.FP2 auf WIN

Clients: 7.0.2

Offline koehlerbv

  • Moderator
  • Gold Platin u.s.w. member:)
  • *****
  • Beiträge: 20.460
  • Geschlecht: Männlich
Re: Inbox bereinigen
« Antwort #10 am: 27.08.08 - 23:17:29 »
Da dort ebenso mit der Responses-Property gearbeitet wird: Ja.

Bernhard

 

Impressum Atnotes.de  -  Powered by Syslords Solutions  -  Datenschutz