Meeting Form per Formula Language öffnen

[immanuel]

Hallo Zusammen

Ich möchte per Knopfdruck die Meeting Maske öffnen und einige Infos reinschreiben lassen.

Folgendes verwende ich schon:

Code

subject := "IT-Helpdesk: "+iq_Subject;
userName := @Name([Abbreviate]; CreatedFor );

@Command([EditMakeDocLink]);
@Command([MailOpen]);
@Command([Compose];@MailDbName;"Appointment");
@Command([EditGotoField];"Subject");
@Command([EditInsertText];subject);

@Command([EditGotoField];"Body");
@Command([EditInsertText];"Documentlink:");
@Command([EditPaste]) ;
@Command([EditGotoField];"Body")

Das Funktioniert gut, die Infos werden in die Form eingefügt. Ein Problem habe ich allerdings noch mit dem Typ Meeting. Wenn der Wert von AppointmentType per FL setzen lasse (Meeting | 3), dann erscheinen die spezifischen Meeting Felder nicht. Wie kann ich eine Auswahl bei AppointmentType mir @Command simulieren und nicht nur einfach den Wert reinsetzen?

Greez
Manuel

[Glombi]

Als letztes ein
@Command([RefreshHideFormulas])
und/oder
@Command([ViewRefreshFields])

Andreas

[immanuel]

Hallo Andreas

Klappt leider immer noch nich. Ich denke, dass der Haken bei folgender Passage liegt:

Code

@Command([EditGotoField];"AppointmentType");
@Command([EditInsertText];"3");

Das Kombinationsfeld wechselt zwar auf Meeting, komischerweise erscheint aber links vom Feld eine 3. Der Text links vom Feld wird dann aktualisiert, wenn ich den Wert des Feldes von Hand ändere. Vielleicht müsste das mal jemand nachvollziehen...

Greez
Manuel

[Glombi]

Es muss evtl.
@Command([EditInsertText];"Meeting")
bzw.
@Command([EditInsertText];"Besprechung")
je nach Sprache heissen.
Die "3" kennt er ja nicht, da es der Alias ist.

Andreas

[immanuel]

Hallo!

Ich habs auch schon mal mit "Meeting" versucht - kein Erfolg. Kannst du den Code mal bei dir 1:1 nachvollziehen?

Grüsse aus Zürich
Manuel

[Don Pasquale]

Kannst Du evtl. Deinen kompletten Code posten, dann hat auch jemand anders die Chance per Drag and Drop den Code zu testen.
Vielleicht ist es auch nur ein Tippfehler.

Ciao
Don Pasquale

[Glombi]

Hallo!

Ich habs auch schon mal mit "Meeting" versucht - kein Erfolg. Kannst du den Code mal bei dir 1:1 nachvollziehen?

Grüsse aus Zürich
Manuel

Du musst anstelle von
@Command([EditInsertText];...)
mit
@SetField arbeiten.

Das hier geht:

@Command([Compose];"Appointment");
@SetField("AppointmentType";"3");
@Command([ViewRefreshFields])

Andreas

[immanuel]

Hallo Zusammen!

Das mit @Setfield funktionierte nicht: Ungültiges Dokument, Dokument nicht gefunden...

Hier noch der gesamte Code:

Code

subject := "IT-Helpdesk: "+iq_Subject;
userName := @Name([Abbreviate]; CreatedFor );

@Command([EditMakeDocLink]);
@Command([MailOpen]);
@Command([Compose];@MailDbName;"Appointment");
@Command([EditGotoField];"Subject");
@Command([EditInsertText];subject);
@Command([EditGotoField];"AppointmentType");
@Command([EditInsertText];"Meeting");
@Command([EditGotoField];"Body");
@Command([EditInsertText];"Documentlink:");
@Command([EditPaste]);
@Command([EditGotoField];"Body");
@Command([RefreshHideFormulas]);
@Command([ViewRefreshFields])

Grüsse
Manuel

[Glombi]

Ich habe es nochmal getestet. Es geht:

subject := "IT-Helpdesk: "+iq_Subject;
userName := @Name([Abbreviate]; CreatedFor );

@Command([EditMakeDocLink]);
@Command([MailOpen]);
@Command([Compose];@MailDbName;"Appointment");
@SetField("AppointmentType";3);
@Command([EditGotoField];"Subject");
@Command([EditInsertText];subject);
@Command([EditInsertText];"Meeting");
@Command([EditGotoField];"Body");
@Command([EditInsertText];"Documentlink:");
@Command([EditPaste]);
@Command([EditGotoField];"Body");
@Command([RefreshHideFormulas]);
@Command([ViewRefreshFields])

Andreas

[immanuel]

Hallo Andreas

Hab's soeben ausprobiert. Es gibt zwar keine Fehlermeldung bei mir, jedoch wird "Meeting" einfach dem Subject angefügt, AppointmentType bleibt unberührt. Ich verwende Notes 5.0.10 und Domino 5.0.12...

Grüsse
Manuel

[Glombi]

Da war noch ein Fehler drin

subject := "IT-Helpdesk: "+iq_Subject;
userName := @Name([Abbreviate]; CreatedFor );

@Command([EditMakeDocLink]);
@Command([MailOpen]);
@Command([Compose];@MailDbName;"Appointment");
@SetField("AppointmentType";3);
@Command([EditGotoField];"Subject");
@Command([EditInsertText];subject);
@Command([EditGotoField];"Body");
@Command([EditInsertText];"Documentlink:");
@Command([EditPaste]);
@Command([EditGotoField];"Body");
@Command([RefreshHideFormulas]);
@Command([ViewRefreshFields])

Geht mit 5.0.6a.

Andreas

[koehlerbv]

Muss vor dem @SetField nicht noch ein
FIELD AppointmentType := AppointmentType
stehen ?

Bernhard

[Hütte]

Folgende Lösung hat bei mir funktioniert: Überschreiben der Notes.Ini-Variablen, die bestimmt, mit welchem Meeting-Typ der Default-Kalender-Eintrag geöffnet wird. Anschließend die Notes.Ini-Variable wieder zurücksetzen.


@If(@IsNewDoc | @IsDocBeingEdited; @If(@Command([FileSave]); @Success; @Return("")); @Success);
@Command([EditMakeDocLink]);

to := @Implode(@Trim(@Unique(@Name([Abbreviate]; Responsible))); ", ");
database := "Datenbank: " + @DbTitle;
text := "Link zum Task --> ";
link := @NewLine + @NewLine + database + @NewLine + text;

REM {Voreinstellung für Kalendereintrag auf Besprechung setzen};
envAppointment := @Environment("CSDocType");
@If(envAppointment != "3"; @Environment("CSDocType"; "3"); "");

@Command([Compose]; @MailDbName; "Appointment");
@Command([EditGotoField]; "Subject");
@Command([EditInsertText]; Subject);
@Command([EditGotoField]; "EnterSendTo");
@Command([EditInsertText]; to);
@Command([EditGotoField]; "Body");
@Command([EditInsertText]; link);
@Command([EditPaste]);

REM {Voreinstellung für Kalendereintrag zurücksetzen};
@If(@Environment("CSDocType") != envAppointment; @Environment("CSDocType"; envAppointment); "")