E-Mail Bearbeitungsvermerke mit Auswahlmöglichkeit

[Matthias 77]

Hallo zusammen,

ich würde gerne für meine E-Mail-Übersicht eine Auswahlroutine mit Bearbeitungsvermerken haben.
In der Betreffzeile soll der Status und der Bearbeiter direkt ersichtlich sein, ebenso in der eigentlichen Mail - hier farblich abgehoben...

Mit einzelnen Buttons funktioniert das schon, jetzt möchte ich einen Button haben, der eine Abfrage startet, was genau da stehen soll.
Bei der Formelüberprüfung sagt er mir, dass ein Semikolon fehlt!
Irgendwie habe ich hier einen Denkfehler und finde ihn nicht!




@Command([EditDocument]);
auswahl := @Prompt([OkCancelList]; "Wählen Sie einen Vermerk"; "Wählen Sie einen Vermerk.";
"Erledigt";
"zur Kenntnis":
"in Bearbeitung":
"mit der Bitte um":
);

@if(
auswahl = "Erledigt";
@Command( [EditGotoField] ; "Subject" );
@Command( [EditInsertText] ; "erl - Matthias - "  );
@Command( [EditGotoField] ; "Body" + @NewLine );
@Command( [TextBold] );
@Command( [TextSetFontFace] ; "Courier New" );
@Command( [TextSetFontSize]; "10" );
@Command( [TextSetFontColor] ; );
@Command( [EditInsertText] ; "erledigt - Matthias " + @Text( @Now ) + @NewLine + @NewLine );


auswahl = "zur Kenntnis";
@Command( [EditGotoField] ; "Subject" );
@Command( [EditInsertText] ; "zK - Matthias - "  );
@Command( [EditGotoField] ; "Body" + @NewLine );
@Command( [TextBold] );
@Command( [TextSetFontFace] ; "Courier New" );
@Command( [TextSetFontSize]; "10" );
@Command( [TextSetFontColor] ; );
@Command( [EditInsertText] ; "zur Kenntnis - Matthias " + @Text( @Now ) + @NewLine +@NewLine );
@Command( [EditGotoField] ; "Body" );

auswahl = "in Bearbeitung";
@Command( [EditGotoField] ; "Subject" );
@Command( [EditInsertText] ; "iB - Matthias - "  );
@Command( [EditGotoField] ; "Body" + @NewLine );
@Command( [TextBold] );
@Command( [TextSetFontFace] ; "Courier New" );
@Command( [TextSetFontSize]; "10" );
@Command( [TextSetFontColor] ; );
@Command( [EditInsertText] ; "in Bearbeitung - Matthias " + @Text( @Now ) + @NewLine + @NewLine );
@Command( [EditInsertText] ; "... "+ @NewLine + @NewLine);
@Command( [EditGotoField] ; "Body" );

);

[tfrenz]

Hallo,
bei @If müssen es immer ungerade Parameter sein, die mit ; Getrennt sind.
Dann würde ich alle Parameter, die zusammen ausgeführt werden sollen in Klammern setzen.
Und am ende "Es trifft nichts zu" immer ein "" einfügen.
Gruß Thomas

[Peter Klett]

Mehrere Kommandos als ein Element müssen m.W. mit @Do () zusammengefasst werden

@if(
auswahl = "Erledigt";
@Do (
   @Command( [EditGotoField] ; "Subject" );
   @Command( [EditInsertText] ; "erl - Matthias - "  );
   @Command( [EditGotoField] ; "Body" + @NewLine );
   @Command( [TextBold] );
   @Command( [TextSetFontFace] ; "Courier New" );
   @Command( [TextSetFontSize]; "10" );
   @Command( [TextSetFontColor] ; );
   @Command( [EditInsertText] ; "erledigt - Matthias " + @Text( @Now ) + @NewLine + @NewLine )
);

auswahl = "zur Kenntnis";



EDIT: Je länger ich mir die Formel anschaue, umso weniger gefällt sie mir, denn es ist ja alles doppelt und dreifach


_listelang := "Erledigt" : "zur Kenntnis": "in Bearbeitung" : "mit der Bitte um";
_listekurz := "Erl" : "zK": "iB" : "mdB";

_auswahl := @Prompt([OkCancelList]; "Wählen Sie einen Vermerk"; "Wählen Sie einen Vermerk."; _listelang);
@If (_auswahl = ""; @Return (""); "");
_auswahlkurz := @Replace (_auswahl; _listelang; _listekurz);

@Command([EditDocument]);
@Command( [EditGotoField] ; "Subject" );
@Command( [EditInsertText] ; _auswahlkurz + " - Matthias - "  );
@Command( [EditGotoField] ; "Body" + @NewLine );
@Command( [TextBold] );
@Command( [TextSetFontFace] ; "Courier New" );
@Command( [TextSetFontSize]; "10" );
@Command( [TextSetFontColor] ; );
@Command( [EditInsertText] ; _auswahl + " - Matthias " + @Text( @Now ) + @NewLine + @NewLine );

[Ralf_B]

Die ausgewählte Farbe würde ich eventuell nochmal überdenken. 

Und dann würde ich einzele IF's machen und auch @Do verwenden:

@if(auswahl = "Erledigt";
@Do(
@Command( [EditGotoField] ; "Subject" );
@Command( [EditInsertText] ; "erl - Matthias - "  );
@Command( [EditGotoField] ; "Body" + @NewLine );
@Command( [TextBold] );
@Command( [TextSetFontFace] ; "Courier New" );
@Command( [TextSetFontSize]; "10" );
@Command([TextSetFontColor]; [DarkCyan]);
@Command( [EditInsertText] ; "erledigt - Matthias " + @Text( @Now ) + @NewLine + @NewLine )
);
""
)

[Matthias 77]

Danke schonmal für die schnellen Antworten.

Ich werde die Formeln mal überdenken und meine dahingehend mal anpassen! Danke!

[Matthias 77]

Ich habe jetzt einen Button erstellt... die Vermerke werden auch so, wie ich es angebe eingearbeitet, allerdings nur, wenn ich selber eine neue Mail öffne… nicht aber, wenn ich eine empfangene Mail bearbeite... da fragt der im vorhinein, ob ich speichern möchte und schließt die Bearbeitung, bevor er die Kommentare setzen kann... dann bekomme ich - verständlicher Weise - die Nachricht, dass die Routine nicht ausgeführt werden kann... woran kann das liegen!? Habt ihr da eine Idee?

[Peter Klett]

@Command([EditDocument]) schaltet vom Lese in den Bearbeitenmodus oder umgekehrt. Wenn Du das Dokument also bearbeitest, schaltet er erst in den Lesemodus (dabei kommt die Frage, ob Du speichern möchtest), und das wars dann. Probier mal @Command([EditDocument]; 1) oder @Command([EditDocument]; "1") (Laut Hilfe sei der Parameter number, im Beispiel in der Hilfe wird er aber als Text übergeben)