Das Notes Forum

Domino 9 und frühere Versionen => Entwicklung => Thema gestartet von: Centaury am 20.02.03 - 16:46:39

Titel: Aufgaben erstellen
Beitrag von: Centaury am 20.02.03 - 16:46:39

Hallo Leute!
Wir haben hier eine eigene Datenbank für Aufgaben. Dafür haben wir unsere eigene Maske. Was muss ich tun, damit diese Aufgaben in der persönlichen Aufgabenliste und im Kalender auftauchen?

Titel: Re:Aufgaben erstellen
Beitrag von: Performance am 20.02.03 - 17:57:07

einen Agent schreiben der eine Task in deiner Mail db erzeugt...
ich glaube das Thema wurde schon öfters hier behandelt.


cu

Titel: Re:Aufgaben erstellen
Beitrag von: Centaury am 21.02.03 - 08:06:33

Hmm..Ich hab die Suche benutzt, aber nichts gefunden, was mir weiterhilft.
Ich nehme an, dass die Aufgabe bestimmte Felder enthalten muss. Welche sind das?
Wie schicke ich das fertige Dokument in die Mail In Datenbank, oder wird das direkt in der Mail in DB erstellt?

Titel: Re:Aufgaben erstellen
Beitrag von: Performance am 21.02.03 - 09:55:30

ein Beispiel mit einem Action button - das minimalen Anforderungen entspricht.

Sub Click(Source As Button)
   Dim s As New NotesSession
   Dim db As NotesDatabase
   Dim ws As New NotesUIWorkspace
   Dim uidoc As NotesUIDocument
   Dim MailDB As New NotesDatabase( "", "" )
   Dim CalNote As NotesDocument
   
   Dim rtfBody As NotesRichTextItem
   Dim styleMsg As NotesRichTextStyle
   Dim NoteDate As New NotesDateTime(Now)
   
   Call MailDB.OpenMail
   If Maildb.isopen = False Then
      Messagebox "Your Calendar......." ,48,"Create Task"
      Exit Sub
   End If
   
   Set CalNote = New NotesDocument(maildb)
   
   CalNote.Form = "Task"
   CalNote.Subject = "Neuer Eintrag vom Chefe"
   Call CalNote.ReplaceItemValue("StartDate", Notedate)
   Call CalNote.ReplaceItemValue("StartDateTime", Notedate)
   Call CalNote.ReplaceItemValue("DueDate", Notedate)
   Call CalNote.ReplaceItemValue("DueDateTime", Notedate)
   Call CalNote.ReplaceItemValue("_ViewIcon", 168)
   Call CalNote.ReplaceItemValue("$CSVersion", "2")
   CalNote.Chair = s.UserName
   CalNote.WebDateTimeInit = "1"
   CalNote.tmpOwnerHW = "0"
   CalNote.Assignstate = 0
   CalNote.TaskType = "1"
   CalNote.dueState = 1
   CalNote.Importance = "2"
   
   Set rtfBody = CalNote.CreateRichTextItem( "Body" )
   Call rtfBody.AppendDocLink(ws.CurrentDocument.document, s.currentDatabase.title)
   Call rtfBody.AddNewLine(1)
   
   Set styleMsg = s.createRichTextStyle()
   styleMsg.bold = True
   styleMsg.fontsize = 16
   styleMsg.NotesColor = 10
   Call rtfBody.appendStyle(styleMsg)
   
   Call rtfBody.AppendText("... Termin beim Zahnarzt! ")
   
   Call CalNote.ComputeWithForm(True, True)
   Call CalNote.Save(True, False)
   Call CalNote.ReplaceItemValue("ApptUNID", CalNote.UniversalID)
   
   Call CalNote.Save(True, False)
''   Set uidoc= ws.EditDocument(True,CalNote)
   
End Sub


cu

Titel: Re:Aufgaben erstellen
Beitrag von: Centaury am 21.02.03 - 12:05:06

Danke! Ich glaube, das habe ich gesucht. Komme jetzt gerade nicht zum Testen. Ich poste, wenn's noch Probleme gibt.
Dankeschön!  :)