Das Notes Forum

Domino 9 und frühere Versionen => Entwicklung => Thema gestartet von: birdy am 13.02.03 - 08:41:01

Titel: Picklistcollection
Beitrag von: birdy am 13.02.03 - 08:41:01

Hallo zusammen,

habe folgendes Problem:

Rufe aus meinem Dokument über einen Button eine Picklist auf und möchte mehrere Dokumente markieren. Aus diesen Dokumenten dann mehrere Werte kopieren und in meinem aktuellen Dokument speichern. Dabei sollen alle Werte in ein Feld geschrieben werden, getrennt z.B. durch Zeilenumbruch.

Bin bis jetzt so weit:

Sub Click(Source As Button)
       Dim session As New NotesSession
       Dim ws As New NotesUIWorkspace
       Dim uidoc As NotesUIDocument
       Dim doc As NotesDocument
       Dim col As NotesDocumentCollection
   
       Set uidoc = ws.CurrentDocument
       Set col = ws.PickListCollection(1, True, "Server", "DBName",_
       "Checkliste", "Checkliste erstellen", "Bitte auswählen:")
   
       Set doc = col.GetFirstDocument
       While Not (doc Is Nothing)
            Call uidoc.FieldSetText("Frage_Check", doc.Thema_Check(0))
            Call uidoc.FieldSetText("Kat_Check", doc.Kategorie(0))
            Set doc = col.GetNextDocument (doc)
       Wend
   
End Sub

Es funzt soweit, dass Werte an mein uidoc übergeben werden, allerdings immer nur die Werte des zuletzt durchlaufenen Docs.

Bin neu in der LS-Welt und habe mir den Code so zusammenkopiert, versteh manches gar nicht  ???

Bin für jeden Tipp dankbar.

Titel: Re:Picklistcollection
Beitrag von: Axel am 13.02.03 - 09:11:51

Hi,

versuch's mal damit:

Sub Click(Source As Button)
      Dim session As New NotesSession
      Dim ws As New NotesUIWorkspace
      Dim uidoc As NotesUIDocument
      Dim currdoc As NotesDocument
      Dim doc As NotesDocument
      Dim col As NotesDocumentCollection
      Dim item1 As NotesItem
      Dim item2 As NotesItem

   
      Set uidoc = ws.CurrentDocument
      Set currdoc = uidoc.Document
      Set item1 = currdoc.GetFirstItem("Frage_Check")
      Set item2 = currdoc.GetFirstItem("Kat_Check")

      Set col = ws.PickListCollection(1, True, "Server", "DBName",_
      "Checkliste", "Checkliste erstellen", "Bitte auswählen:")
   
      Set doc = col.GetFirstDocument
      While Not (doc Is Nothing)
            Call item1.AppendToTextList(doc.Thema_Check(0))
            Call item2.AppendToTextList(doc.Kategorie(0))
            Set doc = col.GetNextDocument (doc)
      Wend
   
End Sub

Die beiden Felder müssen natürlich Mehrfachfelder sein und die Werte läßt du beim Anzeigen durch einen Zeilnumbruch trennen.

Axel

Titel: Re:Picklistcollection
Beitrag von: birdy am 13.02.03 - 09:38:07

 ;D ;D ;D

Hallo Axel,

vielen vielen Dank!!!
Hat bestens funktioniert!

Gruß, Birdy