Seite drucken - Mail Reply mit neuem Text davor

Domino 9 und frühere Versionen => ND8: Entwicklung => Thema gestartet von: ThomasM am 16.07.14 - 14:47:03

Titel: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: ThomasM am 16.07.14 - 14:47:03

Hallo zusammen,

ich muss folgendes realisieren:
Mail kommt von extern mit diversen Angaben. Diese Angaben stehen im Betreff und im Body.
Das Mail soll nun an extern weitergeleitet werden mit dem Body aus der externen Mail UND davor noch
ein neuer Text.

Die erste Zeile des Textes kommt auch in der Mail, aber der restliche Text leider nicht.

Was mache ich falsch?

Vielen Dank im voraus

Gruss
Thomas

Script ist im Anhang

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: umi am 16.07.14 - 22:41:12

Moin

Schon mal das NotesRichtextitem.AppendRTItem probiert?
ungefähr so:

Code

dim origBody as notesRichtextitem

set body=docMemo.replaceitemvalue("Body","")
call body.appendText("....")
call body.addnewline(2)
set origBody = doc.getfirstitem("Body")
if not OrigBody is nothing then
 call body.appendRtitem(OrigBody)
end if

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: ThomasM am 17.07.14 - 15:56:54

Hallo Urs,

vielen Dank für die Antwort.
Deine Lösung hat nicht ganz funktioniert aber sie hat mich auf den richtigen Weg gebracht.
Jetzt hab ich eine Lösung.

Danke

Gruss
Thomas

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: Peter Klett am 17.07.14 - 16:03:31

Dann wäre es nett, wenn Du zumindest den Ansatz für spätere Leser hier einstellst.

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: ThomasM am 17.07.14 - 16:25:54

mach ich doch glatt

ist jetzt nicht ganz die "schöne" Lösung aber für das was realisiert werden soll reichts.

Gruss
Thomas

Ich hoffe das ist jetzt so OK :D

Sub Initialize
   Dim session As New NotesSession
   Dim ndb As NotesDatabase
   Dim view As NotesView
   Dim doc As NotesDocument
   Dim docMemo As NotesDocument
   Dim origbody As NotesRichTextItem
   Dim item As NotesItem

   Set ndb = session.CurrentDatabase
   Set view = ndb.GetView( "(AnfageUnBeantwortet)" )
   Set doc = view.GetFirstDocument

   view.AutoUpdate = False

   'Verarbeitung Busunternehmen
   While Not(doc Is Nothing)
      If Not doc.beantwortet(0)= "ja" Then

         'Betreff von Originalmail aufteilen
         SubjectMail = StrRightBack(doc.subject(0), "r - " )
         sendto = StrrightBack(SubjectMail, " - " )
         Bearbeitungsnummer = StrLeftBack(SubjectMail, "- " )

         'erstellen neue nachricht + füllen felder
         Set docmemo = doc.CreateReplyMessage( False )
         docMemo.Form = "Memo"
         docMemo.sendto = sendto
         docMemo.From = "xxxs@xxx.de"
         docMemo.ReplyTo = "xxx@xxx.de"
         docMemo.Subject = "Neues Feedback Qualitätsmamagement - " + Bearbeitungsnummer

         Set nrit = New NotesRichTextItem( docMemo, "Body" )
         Call nrit.AppendText( "Sehr geehrter,")
         Call nrit.AddNewLine( 2 )
         Call nrit.AppendText( "es ist ein neues Feedback über das Qualitätsmanagement eingegangen." )
         Call nrit.AddNewLine( 4 )
         Call nrit.AppendText( "************** Feedback über QMS ****************" )
         Call nrit.AddNewLine( 2 )

         'Feedback aus originalmail in neue mail einfügen
         Set origBody = doc.getfirstitem("Body")
         If Not OrigBody Is Nothing Then
            Call nrit.appendRtitem(OrigBody)
         End If

         'senden an Bus + verschieben in ordner + setzten verarbeitet flag
         Call docMemo.Send(False)
         Call docMemo.Save( True , False, True )
         Call docMemo.MarkRead()
         Call docMemo.PutInFolder("Mail an xxxx")

         doc.beantwortet = "ja"
         Call doc.Save( False, False, True )
         Call doc.PutInFolder( "Mail an xxxx" )
         Call doc.RemoveFromFolder( "$Inbox")

      End If
      Set doc = view.GetNextDocument(doc)

      Wend
End Sub

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: Tode am 17.07.14 - 16:34:23

BITTE: nicht jeder hat Bock, sich ein Attachment mit zweifelhaftem Inhalt runterzuladen... Dafür gibt es doch die Code- Tags... Poste den Code direkt, dann haben viel mehr Leute was davon...

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: Peter Klett am 18.07.14 - 11:22:40

Vielen Dank!

Titel: Re: Mail Reply mit neuem Text davor - BeginInsert?
Beitrag von: Tode am 18.07.14 - 11:41:19

nun ja... Code- Tags würden das ganze schon nochmal besser lesbar machen... Aber trotzdem: Danke...

Das Notes Forum

Domino 9 und frühere Versionen => ND8: Entwicklung => Thema gestartet von: ThomasM am 16.07.14 - 14:47:03