Das Notes Forum

Domino 9 und frühere Versionen => ND8: Entwicklung => Thema gestartet von: Scotty67 am 27.12.11 - 09:46:05

Titel: Dokument Reload und ein Edit mit Dialogbox für Attachment
Beitrag von: Scotty67 am 27.12.11 - 09:46:05

Möchte gerne in einem Dokument einen "Attachment einfügen" Dialog anzeigen mit dem der Benutzer ein Attachment
einfügen kann.

Hier ein Script der das aktuelle Dokument kurzzeitig in den Editmode versetzt, einen Wert ändert und ein Reload
des Dokuments durchführt.





Dim db As NotesDatabase
Dim doc As NotesDocument
Dim workspace As New NotesUIWorkspace
Dim session As New NotesSession
Dim uidoc As NotesUIDocument
Dim user As String
Dim itemA As NotesItem
   
user = session.UserName

Dim boxType As Long
Dim answer As Integer
   
Set uidoc = workspace.CurrentDocument
Set doc=uidoc.Document


boxType& = 4 + 32
answer% = Messagebox("Möchten Sie den Projektabschlussbericht jetzt starten?", boxType&,   "Abschlussbericht eröffnen ?")
   
   
If answer%=7 Then
   Exit Sub
Else
   uidoc.EditMode=True
   Call uidoc.FieldSetText ("DocPjAbschluss","1")
      
End If
   
   
uidoc.AutoReload = True
Call uidoc.Save
Call workspace.ReloadWindow( )
uidoc.EditMode=False
uidoc.AutoReload = True


Ich wollte gleich am Ende von dem uidoc.Autoreload
das hier (nächsten 2 Codezeilen) exekutieren damit schmiert mir aber LN ab.



Set uidoc = workspace.EditDocument( True )
Call uidoc.GotoField( "ProjectClosingReportPM" )


Und wie bereits Eingangs erwähnt eine Dialogfenster für einen Attachment-Upload fehlt mir noch.
Wie gehts das ?


LG/Hannes

Titel: Re: Dokument Reload und ein Edit mit Dialogbox für Attachment
Beitrag von: Schnubbel am 27.12.11 - 10:30:34

Du möchtest dir OpenFileDialog method in der Hilfe durchlesen ;)

Gruß
Thorsten

Titel: Re: Dokument Reload und ein Edit mit Dialogbox für Attachment
Beitrag von: Scotty67 am 27.12.11 - 12:39:36

Thorsten, hab ich schon !

Dim uiw As New NotesUIWorkspace
Dim uidoc2 As NotesUIDocument
Dim getfile As Variant
Set uidoc2 = uiw.CurrentDocument
getfile=uiw.openfiledialog( False,"Please select the file", "Excel Spreadsheets|*.xls" ,"c:\Tempdir", "")

Bis zum getfile isses ja noch OK, ab dem EditDocument schmiert LN ab

Set uidoc2 = uiw.EditDocument( True )
Call uidoc2.GoToField("ProjectClosingReportPM")
Set handle = uidoc2.CreateObject("Sheet Name","",getfile(0))

Titel: Re: Dokument Reload und ein Edit mit Dialogbox für Attachment
Beitrag von: Schnubbel am 27.12.11 - 14:00:16

Ich hab hier son Code - Snipsel. Kurze Erklärung: DateiDialog erscheint, Datei(en) wird in RTF (Attachment) geschoben, Dokument wird gespeichert.

Dim ws as New Notesuiworkspace
Dim uidoc as Notesuidocument
Dim RDoc as Notesdocument

set uidoc = ws.currentdocument
set RDoc = uidoc.document


Dim filenames As Variant
Dim object As NotesEmbeddedObject
Dim rtitem As NotesRichTextItem


filenames = ws.OpenFileDialog(True,"Dateien anhängen")
      
   Forall filename In filenames
      Set rtitem = RDoc.GetFirstItem( "Attachment" )
      If (rtitem Is Nothing) Then
         Set rtitem = New NotesRichTextItem( RDoc, "Attachment")
      End If   
      Set object = rtitem.EmbedObject ( EMBED_ATTACHMENT, "", filename )
      Call RDoc.Save(1,1)
   End Forall

Hoffentlich hilft dir das weiter.

Thorsten

Titel: Re: Dokument Reload und ein Edit mit Dialogbox für Attachment
Beitrag von: Scotty67 am 27.12.11 - 14:23:32

maaaaa  :))))  magst mich heiraten ?  *ggg*  - DANKE - es funktioniert !!!!