Das Notes Forum

Domino 9 und frühere Versionen => ND7: Entwicklung => Thema gestartet von: oksenator am 29.10.07 - 11:51:23

Titel: Mail wird ohne "Form" geschickt
Beitrag von: oksenator am 29.10.07 - 11:51:23

Hallo,
bei folgendem Script kommt die Mail ohne das Feld "Form" an und deshalb können die Leute mit deutschem Client sie nicht öffnen. Im Debugger wird das Item ordentlich gefüllt. Irgend eine Idee woran das liegen könnte ?
Danke
Oliver

Sub Click(Source As Button)
   Dim session As New NotesSession
   Dim wrks As New NotesUIWorkspace
   Dim uidoc As NotesUIDocument
   Dim db As NotesDatabase
   Dim thisdoc As notesdocument
   Dim rtitem As notesrichtextitem
   
   Set uidoc = wrks.currentdocument
   Set thisdoc=uidoc.document
   
   SendTo= uidoc.FieldGetText("SendTo")
   CopyTo= uidoc.FieldGetText("CopyTo")
   'geht nicht weil Zugriffsrechte für den Abschnitt fehlen
   'Call uidoc.FieldSetText("cc", uidoc.FieldGetText("CopyTo"))
   Message = "Anbei Investitionsantrag mit der Bitte um Genehmigung."
   Message2 = "Beschreibung der Investition: " + Cstr(uidoc.FieldGetText("Investitionsbeschreibung"))
   About = "Investitionsantrag"
   InfoMessage = "Dieser Investitionsantrag wurde an " + Strleft(Cstr(SendTo), "/") + " zur Genehmigung gesandt."
   InfoAbout = "Info über einen neuen Investitionsantrag"
   
   
   Set db = session.CurrentDatabase
   Set maildoc = New notesdocument(db)
   maildoc.Form = "Memo"
   maildoc.Subject = Cstr(About)
   Set rtitem = New NotesRichTextItem( maildoc, "Body" )
   Call rtitem.AppendText( Cstr(Message) )
   Call rtitem.AddNewLine( 2 )
   Call rtitem.AppendText( Cstr(Message2) + " --> " )
   Call rtitem.AppendDocLink( thisdoc, "Investitionsantrag")   
   Call maildoc.send(True, SendTo)
   
   If CopyTo <> "" Then
      Set ccmaildoc = New notesdocument(db)
      ccmaildoc.Form = "Memo"
      ccmaildoc.Subject = Cstr(InfoAbout)      
      Set ccrtitem = New NotesRichTextItem( ccmaildoc, "Body" )
      Call ccrtitem.AppendText( Cstr(InfoMessage)  )
      Call ccrtitem.AddNewLine( 2 )
      Call ccrtitem.AppendText( Cstr(Message2) + " --> " )
      Call ccrtitem.AppendDocLink( thisdoc, "Investitionsantrag")
      
      Call ccmaildoc.send(True, CopyTo)
   End If
   
   Call uidoc.save
   Call uidoc.close
End Sub

Titel: Re: Mail wird ohne "Form" geschickt
Beitrag von: koehlerbv am 29.10.07 - 11:56:04

Unterlasse mal das Mitsenden der Maske, also
NotesDocument.Send (False, CopyTo)

Bernhard

Titel: Re: Mail wird ohne "Form" geschickt
Beitrag von: oksenator am 29.10.07 - 17:50:48

Danke,
das wars.

Oliver