Das Notes Forum

Domino 9 und frühere Versionen => Administration & Userprobleme => Thema gestartet von: Pascal am 16.05.02 - 09:37:02

Titel: Migration R4.61 auf R5.10
Beitrag von: Pascal am 16.05.02 - 09:37:02

Hallo

ich stehe vor einem grossen Problem, ich soll R4.61 auf R5.10 migrieren, wobei bei den Mailfiles die Privat Folders übenommen werden müssen, die design Infomationen der Folder aber neu , dh, auf R5 gewechselt werden müssen.
Wie bringe ich das hin das ein Privat Folder von mir veränderd werden kann ?
Ich hab die Krise, ich glaube meine Chefs verlangen da unmögliches von mir oder sehe ich das falsch?

Gruss
Pascal

Titel: Re: Migration R4.61 auf R5.10
Beitrag von: eknori am 16.05.02 - 10:07:00

Nicht verzagen, Forum Fragen !!

Habe hier einen Agenten, der die Arbeit macht. Ich habe den Code noch nicht getestet, aber so bem ersten Betrachten scheint das genau das zu sein, was du brauchst

Sub Initialize
Dim Session As New NotesSession
Dim Currentdb As NotesDatabase
Dim newfolder As String
Dim tempfolder As NotesView
Dim doc As NotesDocument

Set Currentdb = Session.CurrentDatabase

'Create new folder for each existing folder and copy all mails from existing folders to
'new folder
Forall view In currentdb.views
If view.IsFolder And view.name <>"($Inbox)" And view.name <>"($Trash)" And _
view.name <> "$Alarms" And Right(view.name, 6) <> "(New!)" Then
newfolder = view.name & "(New!)"
Set doc = view.GetFirstDocument
Do While Not doc Is Nothing
Call doc.PutInFolder(newfolder)
Set doc = view.GetNextDocument(doc)
Loop
End If
End Forall

'Remove existing folder if there is a corresponding new 'folder
Forall view In currentdb.views
If view.IsFolder And Right(view.name, 6)= "(New!)" Then
Set tempfolder = currentdb.GetView(Left(view.name, Len(view.name)-6))
If Not tempfolder Is Nothing Then
Call tempfolder.remove
End If
End If
End Forall

Forall view In currentdb.views
If view.IsFolder And Right(view.name, 6)= "(New!)" Then
Set doc = view.GetFirstDocument
Do While Not doc Is Nothing
Call doc.PutInFolder(Left(view.name,Len(view.name)-6))
Set doc = view.GetNextDocument(doc)
Loop
Call view.remove
End If
End Forall
End Sub

Titel: Re: Migration R4.61 auf R5.10
Beitrag von: Pascal am 16.05.02 - 12:14:40

Hey Ulrich

you are the best

vielen dank, läuft voll gut

danke

Pascal

Titel: Re: Migration R4.61 auf R5.10
Beitrag von: eknori am 16.05.02 - 12:25:47

Schön, wenn man Krisen so einfach bewältigen kann. Ich hoffe, dein Chef gibt dir für DEINE   8) Lösung wenigstens einen Tag frei; ist ja das Mindeste, oder ?