Das Notes Forum
Domino 9 und frühere Versionen => Administration & Userprobleme => Thema gestartet von: immanuel am 08.09.03 - 15:58:10
-
Hallo Zusammen
Wie kann ich den Inhalt einer Maildatenbank in eine andere MailDB (gleiches Template) kopieren, so dass die gesammte Ordnerstruktur der QuellDB übernommen wird? Gibts dazu Tools?
Grüsse
Manuel
-
Auf die persönlichen Ordner hat meiner Meinung nur der Eigner zugriff, also müsste jeder user seine Ordner selbst kopieren.
-
Hallo Zusammen!
Die User tun mir machmal richtig leid, wenn ich ihnen sagen muss, dass die alles von Hand in ihre Mailbox kopieren müssen. Wir haben gerade einen User, der ein paar duzend / hundert Ordner von seinem Vorgänger übernehmen darf. Als ex Outlook User, hatte er nicht gerade Freude dabei, weil dies in Outlook innert Sekunden erledigt ist.
Gibt es wirklich keine Tools oder Agenden, die dies erledigen? Alle Mails sind ja schnelle über die All Ansicht kopiert, aber die Folder gehen so futsch...
Wie löst ihr solche Fälle?
PS: Wie siehts in ND6 aus, da sollte es gehen, oder?
Grüsse aus Zürich
Manuel
-
Hundert Ordner? Das ist brutal.
Werden die Info permanent gebraucht, oder nur als Archiv?
Dann alles so lassen wie es ist und den neuen User nur passende Rechte geben.
Falls doch ein Umzug der Daten angesagt ist, warum ziehst Du das Mailfile nicht andersherum um?
Das vom Vorgänger zum aktuellen für den User machen.
Aber nicht vergessen ACL anzupassen, Agenten zu signieren und Eigentümerprofil korregieren. ;)
-
Da fällt mir spontan "FolderReferences" ein, guckst Du Best Practices:
http://www.atnotes.de/index.php?board=26;action=display;threadid=13503
-
Schlagt mich tot, ich hab keine Ahnung, wo ich das Script jetzt gefunden habe (zuviele offene Fenster), aber... ich habs eben zumindest getestet und es funktioniert wunderbar :-) Allerdings sollte man den Nutzer hierbei unterstützen und nicht einfach sagen: Da isses!
Es erfordert ein paar händische Angaben (von wo nach wo soll kopiert werden)...
Dim s As New NotesSession
Dim w As New NotesUIWorkspace
Dim destDb As New NotesDatabase("","")
Dim sourceDb As New NotesDatabase("","")
Dim AllDocs As NotesDocumentCollection
Dim AllDocsView As NotesView
Dim sourceDoc As NotesDocument
Dim destDoc As NotesDocument
Dim tempDoc As NotesDocument
Dim docCount As Variant
Dim current As Variant
Dim choices (0 To 2) As Variant
choices(0) = "Current Database"
choices(1) = "Local Database"
choices(2) = "Database on Server"
' get source database
sourceDbType = w.Prompt(PROMPT_OKCANCELLIST, "Select Database Location", _
"Select the location of the database you would like to copy from:", _
choices(0), choices)
If sourceDbType = "" Then
Messagebox "Operation cancelled"
Exit Sub
End If
If sourceDbType = choices(0) Then
Set sourceDb = s.CurrentDatabase
Else
If sourceDbType = choices(1) Then
sourceDbServer = ""
sourceDbNameReturn = w.OpenFileDialog(False, _
"Select the database you would like to copy from", "*.nsf", _
s.GetEnvironmentString("Directory", True))
If Isempty(sourceDbNameReturn) Then 'Means they hit Cancel
Msgbox("Operation cancelled: Unable to continue without a filename.")
Exit Sub
End If
sourceDbName=SourceDbNameReturn(0)
Else
sourceDbServer = Inputbox("Enter the name of the Domino server")
sourceDbName = Inputbox("Enter the filename of the database relative to the server data directory")
If sourceDbName = "" Then
Msgbox("Operation cancelled: Unable to continue without a filename.")
Exit Sub
End If
End If
If Not (sourceDb.Open(sourceDbServer, sourceDbName)) Then
Msgbox("Unable to find/open file: " + sourceDbName)
Exit Sub
End If
End If
' get destination database
destDbType = w.Prompt(PROMPT_OKCANCELLIST, "Destination Database", _
"Select the location of the database you would like to copy documents/folders to", _
choices(1), choices)
If destDbType = "" Then
Messagebox "Operation cancelled"
Exit Sub
End If
If destDbType = choices(0) Then
Set destDb = s.CurrentDatabase
Else
If destDbType = choices(1) Then
destDbServer = ""
destDbNameReturn = w.OpenFileDialog(False, _
"Please select the database you would like to copy from", "*.nsf", _
s.GetEnvironmentString("Directory", True))
If Isempty(destDbNameReturn) Then 'Means they hit Cancel
Msgbox("Operation cancelled: Unable to continue without a filename.")
Exit Sub
End If
destDbName=destDbNameReturn(0)
Else
destDbServer = Inputbox("Enter the name of the Domino server")
destDbName = Inputbox("Enter the filename of the database relative to the server data directory")
If destDbName = "" Then
Msgbox("Operation cancelled: Unable to continue without a filename.")
Exit Sub
End If
End If
If Not (destDb.Open(destDbServer,destDbName)) Then
Msgbox("Unable to find/open file: " + destDbName)
Exit Sub
End If
End If
If destdb.server=sourcedb.server And destdb.filename=sourcedb.filename And destdb.filepath=sourcedb.filepath Then
Msgbox("Source and Destination database should not be the same database")
Exit Sub
End If
' Build collection of all documents in source database using selection
' formula similar to that used in the Mail templates All Documents view
AllDocsSelect = "@IsNotMember(""A""; ExcludeFromView) & IsMailStationery != 1" + _
"& Form != ""Group"" & Form != ""Person"""
Set AllDocs = sourceDb.Search(AllDocsSelect, Nothing, 0)
' display progress
docCount = AllDocs.Count
current = 0
Print Cstr(Round(current / docCount * 100, 0)) + "% copied"
' step through each folder in source database except system folders other than Inbox
Forall folder In sourceDb.Views
If folder.IsFolder And (Instr(1, folder.Name, "(", 0)<>1 Or folder.Name="($Inbox)") Then
' The following code ensures that folders with no docs in them still get copied
' so that any folder design customizations are kept
Set destFolder = destDb.GetView(folder.Name)
If destFolder Is Nothing Then
Set sourceFolder = sourceDb.GetDocumentByUNID(folder.UniversalID)
Call sourceFolder.CopyToDatabase(destDb)
Set destFolder = destDb.GetView(folder.Name)
If destFolder Is Nothing Then
Msgbox("Unable to create folder in new database.")
Exit Sub
End If
End If
' cycle through each doc in the current folder
Set sourceDoc = folder.GetFirstDocument
While Not (sourceDoc Is Nothing)
Set destDoc = sourceDoc.CopyToDatabase(destDb)
' copy each document to the same folder in the destination database
Call destDoc.PutInFolder(folder.Name, True)
' remove document from the collection of docs built from source db all docs view
Set tempDoc = AllDocs.GetDocument(sourceDoc)
Set sourceDoc = folder.GetNextDocument(tempDoc)
Call AllDocs.DeleteDocument(tempDoc) 'remove from collection
' display progress
current = current + 1
Print Cstr(Round(current / docCount * 100, 0)) + "% copied"
Wend
End If
End Forall
' docs remaining in collection are not in any folder - copy these to dest. db
Set sourceDoc = AllDocs.GetFirstDocument
While Not (sourceDoc Is Nothing)
Call sourceDoc.
CopyToDatabase(destDb)
' display progress
current = current + 1
Print Cstr(Round(current / docCount * 100, 0)) + "% copied"
Set sourceDoc = AllDocs.GetNextDocument(sourceDoc)
Wend
'done
Msgbox("Documents have been copied. Close and reopen the destination file (if it is open) so that it can be refreshed.")
Edit:
Was´n Zufall :-) Nun hab ich die Quelle wieder gefunden. Natürlich wie so oft Ulrich K. aus M.. der die KnowledgeBase von oben bis unten durchzuwühlen scheint :-)
-
Hallo Zusammen!
Danke für alle Beiträge!
@Rygel XVI:
Hundert Ordner? Das ist brutal.
Werden die Info permanent gebraucht, oder nur als Archiv?
Dann alles so lassen wie es ist und den neuen User nur passende Rechte geben.
Falls doch ein Umzug der Daten angesagt ist, warum ziehst Du das Mailfile nicht andersherum um?
Das vom Vorgänger zum aktuellen für den User machen.
Aber nicht vergessen ACL anzupassen, Agenten zu signieren und Eigentümerprofil korregieren. ;)
Bei uns werden die neuen user in einer Übergangszeit von den alten MA eingeführt. Während dieser Zeit benötigt jeder User eine eigene Mailbox. Viele Folder gibt es schnell, wenn Daten über Jahre gepflegt und abgelegt werden.
Grüessli
Manuel
-
Hallo Zusammen
Ich habe den Agenten von Eknori getestet - funktioniert super!
Siehe seine Webpage: http://www.eknori.de/tipps/
Danke schön!
Grüessli
Manuel
-
Hallo zusammen,
ich stehe im Moment vor dem gleichen Problem. Und ich habe das oben gepostete Script mal in einen Agenten eingefügt aber bei mir läßt sich das Script nicht abspeichern. Meckert immer die erste Zeile an von wegen "Semikolon wurde erwartet aber nicht gefunden" und zeigt dann 's'. Muß ich das eigentlich als Lotus Script oder als Formel abspeichern????
-
Script ;D
-
Hi,
mal was ganz einfaches.
Was spricht gegen die Archiv-Funktion?
Axel
-
Hi,
mal was ganz einfaches.
Was spricht gegen die Archiv-Funktion?
Axel
Hallo Axel
Wenn ein Mitarbeiterwechsel statt findet und nach einer Übergangsfrist die Dokumente in die neue - schon exisitierende - Mailbox übernommen werden sollten, sehe ich keine andere Lösung als die Mails zu kopieren. Könnte dies auch über die Archivfunktion getan werden?
Lieber Gruss
Manuel
-
In dem Fall kommst du mit der Archiv-Funktion nicht weiter.
Axel