Mailtext in neue DB auslesen

[notesdba]

Frage von Anfänger:

Wie kann ich das Mailtextfeld des aktuellen Benutzers in ein Feld einer neuen DB importieren, d.h. auf Knopfdruck soll der aktuelle Eingang der MailDB in einem Fenster angezeigt werden um dann die gewünschte Mail zum importieren auszuwählen .

[ata]

... sorry, aber ich hab's mehrfach gelesen und nicht begriffen.

Zu den Begrifflichkeiten in Notes:
Eine DB ist eine Datenbank mit Notes-Dokumenten - ein Feld in einer DB generieren  

und was soll nun auf den Knopfdruck genau passieren? - der Inhalt der Mail soll in einem extra Fenster erscheinen - dann öffne doch einfach die Mail oder nimm die Dokumentvorschau...

... mit einem SmartIcon kann mann aus dem aktuell gewählten Dokument Inhalte in den Zwischenspeicher nehmen, eine DB öffnen, ein neues Dokument darin erstellen und den Inhalt einem Feld weitergeben - wenn das dein Vorhaben ist, dann poste ich dir die Formel...

ata

[notesdba]

Ich versuche mich anders auszudrücken:

In einer neuen AnfrageDB habe ich eine Maske generiert mit verschiedenen Feldern.
Diese Maske soll zum erfassen der Anfragen dienen, die per Mail eingehen.
Somit möchte ich den Absender der Mail, das Thema und den Mailtext in diese Maske übernehmen lassen.
Ausgehen von dieser Maske möchte ich zuerst wählen können, welches der Mail im Eingang der MailDB überhaupt ausgelesen werden soll, um danach die erwähnten Bereiche der Mail zu übernehmen.

Wie kann ich dies am einfachsten realisieren?

Ich hoffe die Erklärung war etwas deutlicher.

Würde mich über eine Anregung freuen.

[ata]

... ich habe vor kurzem genau so etwas programmiert. Ich werde versuchen dir den Code in abgespeckter Version näherzubringen...


... in meiner Datenbank habe ich einen Button,
... der mir Mails zur Auswahl gibt,
... für jede selektierte Mail wird in der DB ein Dokument angelegt...

Code

Dim ws As New NotesUIWorkspace
Dim session As New NotesSession
Dim pickList As NotesDocumentCollection
Dim dbThis As NotesDatabaseDim 
Dim docNew As NotesDocument
Dim docMail As NotesDocument
Dim vMailDB As Variant
Dim sFieldImport() As String
Dim i As Long
Dim f As Integer

' # Die zu importierenden Felder bestimmen...
Redim sFieldImport( 0 to 2)
sFieldImport(0) = "Subject"
sFieldImport(1) = "From"
sFieldImport(2) = "Body"

' # ... die Parameter der Mail-Datenbank einlesen.
vMailDB = Evaluate("@MailDBName")
Set dbThis = session.CurrentDatabase
      
' # Auswahl der einzubindenden Mails per PickList,...
Set pickList = ws.PickListCollection( 1, True, vMailDB(0) , vMailDB(1) , "($Inbox)" , "Auswahl Mails" ,"Bitte die Mails wählen.")

' # ... wenn Mails selektiert wurden...      
If pickList.Count > 0 Then
   Set docMail = pickList.GetFirstDocument         
   For i = 1 To pickList.Count  ' # ... aus allen selektierten Mails...
      Set docNew =  dbThis.CreateDocument
      docNew.Form = "Dein_Maskenname_in_der_neuen_Datenbank"
      For f = 0 to Ubound( sFieldImport ) ' # ... die benötigten Felder einbinden...
         If docMail.HasItem( sFieldImport( f ) ) Then  ' # ... wenn vorhanden...
            Call docNew.CopyItem( docMail.GetFirstItem( sFieldImport( f )  , sFieldImport(f) ) )
         End If         
      Next
      Call docNew.Save( True , True ) ' # und dann speichern.
      Set docMail = picklist.GetNextDocument( docMail )
   Next   
   Print "Mailimport abgeschlossen"
End If

ata

[notesdba]

Vielen Dank für die Hilfe  

Das war genau die Lösung für mein Problem.


P.s.: In Zeile
Call docNew.CopyItem( docMail.GetFirstItem( sFieldImport( f )  , sFieldImport(f) )

fehlt noch eine Klammer hinter dem ersten sFieldImport( f )  

Nochmals Danke. Super