Domino 9 und frühere Versionen > Entwicklung

Access -> ODBC -> Notes

<< < (3/5) > >>

SnooP:
@harkpabst_meliantrop

danke für Dein TIPP

.... ist LEI nicht Kostenpflichtig ?

habe es mittlerweile mit Excel Import soweit gelöst, würde jedoch trotzdem ODBC bevorzugen !!!

Ich schaue mal ob ich das Prinzip von Excel_Import (mein Excel Import habe ich folgender maßen gelöst: Spaltenwerte je ein Datensatz einem Text Feld übergeben, das Dokument gespeichert und mir daraus ein View (Ansicht) gebastelt) auch auf ODBC übertragen kann.

dasRalph:
Wer ist Le??? Wer ist decs???

Ich hab ein wenig den Überblick verloren, um was gehts eigentlich??? Wie er die Daten von Access nach LoNo bekommt oder wie er diese darstellt???

Für das Auslesen von AccessDB's versuch mal dies

http://www-10.lotus.com/ldd/sandbox.nsf/ecc552f1ab6e46e4852568a90055c4cd/6704c9ebb583859f8525694d004e51b0?OpenDocument&Highlight=0,msaccessreader

ralph

SnooP:
.....jaaaa genau das ist es !!!!!

So habe ich mir das vorgestellt !!!

Danke *SAHNE*

2nd-Dimension:
wie schaffe ich es die Daten nicht aus der Access Tabelle zu holen, sondern aus einer Abfrage ?

2nd-Dimension:
kann denn keiner helfen?

er findet zwar die Felder in Access aber an dem Punkt wo er die Daten holen soll, findet er nix

bei Tabelle ist Notes-Import eingegeben, dabei handelt es sich nicht um ne Access Tabelle sondern um ne Abfrage

hier der code:


--- Code: ---Sub Click(Source As Button)
REM  MS Access Reader by Gary Roberts  08/30/2000  
REM  Copyright Gary Roberts, 2000  (e-mail:  groberts@carolina.rr.com)
REM
REM  Application Name:  MS Access Reader
REM  View Name:  Customers
REM  Action Name:  Read MS Access Database
REM
REM  Purpose:
REM  Read a Microsoft Access (MS Access) MDB file and create a Notes Document for
REM  each record in the MS Access Database.  The newly created documents will be
REM  displayed in the "By Company Name" view in THIS Notes Database.
REM
REM  IMPORTANT NOTES:
REM  You do NOT have to have MS Access installed on your PC to run this program.
REM  You DO have to have the Northwind.mdb file (comes with MS Access)
REM  You DO have to register Northwind.mdb as an ODBC Data Source (System)
REM  You DO have to have nlsxodbc.dll in your Notes directory (NOT the Data Directory)
REM  You DO have to have lsconst.lss in your Notes directory (NOT the Data Directory)
REM  You DO have to have lsxbeerr.lss in your Notes directory (NOT the Data Directory)
REM The ODBC LSX File is declared in the FORM's (Globals) (Options) section
REM  I used the fully qualified filename of the DLL in case yours isn't registered
REM  LotusScript and Error constants are "Included" in the FORM's (Globals) (Declarations) section
REM
REM  Change Log:
REM  ------------------------------------------------------------------------------------------------------
REM  08/30/2000  Gary Roberts    Placed into production
REM
   
REM  Notes Objects Declarations
   Dim session As New NotesSession
   Dim ws As New NotesUIWorkspace
   Dim db As NotesDatabase
   Dim view As NotesView
   Dim doc As NotesDocument
   Dim con As New ODBCConnection
   Dim qry As New ODBCQuery
   Dim result As New ODBCResultSet
   
REM  Miscellaneous module variables
   Dim msg As String
   Dim FieldCount As Integer
   Dim Status As Integer
   
REM  MS Access Database declarations
   Const adbFileName = "Volleyball"  ' This is the DSN Name as registered in ODBC
'     Const adbTableName = "Tabelle1 INNER JOIN Interpret on Tabelle1.[Interpret_ID] = Interpret.[Kennummer]"  ' This is a table in the northwind database
   Const adbTableName = "Notes-Import"  ' This is a table in the northwind database
REM  Notes Database declarations
   Const ndbViewName = "spieler"  ' This is an existing View in the target database
   Const ndbFormName = "eing_spieler"  ' This is an existing Form in the target database
   
REM  Instantiate the major Notes objects
   Set db = session.CurrentDatabase    
   Set view = db.GetView( ndbViewName )
   
REM  Connect to the MS Access Database.  Throw an error if it fails
   status = con.ConnectTo( adbFileName )
   If Not con.IsConnected Then
      Messagebox "Could not connect to " & adbFileName & " database -- Did you register the ODBC Data Source???",, "Error"
      Exit Sub
   End If
   If con.GetError <> DBstsSUCCESS Then
      Messagebox con.GetExtendedErrorMessage,, "Connection Error - " & con.GetError & " " & con.GetErrorMessage
      Exit Sub
   End If
   Print "Connected to " & adbFileName & " database"  ' Update the Notes Client Status Bar if we're okay
   
REM  If we got this far, we must be connected, so just for grins,  let's show the user all the fields in this table.
REM  Note:  "fields" has not been declared, so it will be a Variant Array -- that's what we want
   fields = con.ListFields( adbTableName )
   msg = adbTableName & " contains the following fields:" & Chr(10)
   For FieldCount = Lbound( fields ) To Ubound( fields )
      msg = msg & Chr(10) & fields( FieldCount )
   Next
REM  Okay, let's display the Field List to the User...
   Messagebox msg,, "Fields from the " & adbFileName & " database"
   
REM  We made it this far, so let's setup the SQL Query.  Throw an error if it fails
   Set qry.Connection = con
   Set result.Query = qry
   qry.SQL = "SELECT * FROM " & adbTableName  ' Grab all of the fields (columns) from the specified table
   If qry.GetError <> DBstsSUCCESS Then
      Messagebox qry.GetExtendedErrorMessage,, "Query Error" & qry.GetError & " " & qry.GetErrorMessage
      Exit Sub
   End If
   
REM  Update the Notes Client Status Bar
   Print "Reading " & adbFileName & " database"  ' Update the Notes Client Status Bar if we're okay
   
REM  Must be okay -- Get the Data
   result.Execute
   
REM  See if we have data.  If so, loop through the ResultSet.  If not, throw an error
   If result.IsResultSetAvailable Then
      Do
         result.NextRow
        REM  Create a Notes Document, assign values, save the document.  Do it until we're done.
         Set doc = db.CreateDocument  ' Create a new Notes Document for this record
         doc.Form = ndbFormName
        REM  Okay -- Let's get serious -- We'll use the MS Access Database field (Column)
        REM  names for the field names in the Notes Documents
         doc.spieler_vorname = result.GetValue( "Vorname" )
         doc.spieler_name = result.GetValue( "Name" )
         doc.spieler_geburtsdatum = result.GetValue("Geburtsdatum")
         doc.spieler_wohnort = result.GetValue("Nachschlagen in Ort und PLZ")
         doc.spieler_mannschaft = result.GetValue("Mannschafts_ID")
         doc.spieler_groeße = result.GetValue("Groesse")
         doc.spieler_email = result.GetValue("Email")
         Call doc.save( True, False )
      Loop Until result.IsEndOfData
      
    REM  We're done, so let's clean up the mess we've made and bail out  
      result.Close( DB_CLOSE )
      Print "Finished"  ' Update the Notes Client Status Bar if we're okay
   Else
    REM  If we got here, it means there was no data in the table, so throw an error (Informational)
      Messagebox "No data retrieved for " & adbTableName & " table", MB_ICONINFORMATION, "No data"
      Print "DOH!!!!!  Got no data -- Bummer!!!!"  ' Update the Notes Client Status Bar if we're NOT okay
      Exit Sub  
   End If
   
REM  Give up the ODBC Connection like a good little boy
   con.Disconnect
   
REM  Update the view so the new documents will show up without having to press the F9 key
   Call view.Refresh
   Call ws.ViewRefresh
   
End Sub
--- Ende Code ---

Navigation

[0] Themen-Index

[#] Nächste Seite

[*] Vorherige Sete