Domino 9 und frühere Versionen > ND9: Administration & Userprobleme

E-Mailversand aus Excel geht mit LN 9 nicht mehr

<< < (16/17) > >>

DerVissi:
So wie ich das verstanden habe, brauchst du folgendes:

1. Zuerst das Profildokument "Calendar Profile"
2. Das Item in dem die RichText Signatur steht "Signature_Rich"
3. Die Signatur bekommst du dann rein mit "Call rtitem.AppendRTItem(das signatur item hier rein)"

Benni1988:
vielen Dank für deine Hilfe :)


 Set profile = db.GetProfileDocument("CalendarProfile")
 Set RTSig = profile.GetFirstItem("Signature_Rich")
 Set rtitem = NewNotesRichTextItem(doc, "Body")
 Call rtitem.AppendRTItem(RTSig)


Wie dir bereits geschrieben, kommt hier die Fehlermeldung

Objektvariable oder With-Blockvariable nicht festglegt

jBubbleBoy:
verwende "New NotesRichTextItem" anstatt "NewNotesRichTextItem".
Verwende bitte den Excel-Debugger um die Fehlerzeile zu finden.
Schließlich machen wir alle mal Tippfehler, siehe "AppendToRTItem" ;)

jBubbleBoy:
... da fällt mir wieder ein das du ja Excel-Code schreibst, da funktioniert der New-Operator nicht, aber:
set rt = doc.CreateRichTextItem("Body")

Benni1988:
also so geht es :)


 Set profile = db.GetProfileDocument("CalendarProfile")
 Set RTSig = profile.GetFirstItem("Signature_Rich")
 Set rtitem = doc.CreateRichTextItem("body")
  Call rtitem.AppendText(sText)
 Call rtitem.AddNewLine(2)
 Call rtitem.AppendRTItem(RTSig)


Hier noch einmal der ganze Code


Option Explicit
 
Sub lotus()

 Dim sText As String, sEmpfang As String, sBetrifft As String
 Dim session As Object, db As Object, doc As Object, rtobject As Object
 Dim rtitem As Object, sKopie As String
 Dim AttachMe As Object, DerAnhang As Object
 Dim user As String, server As String
 Dim mailfile As String, sBlindKopie As String
 Dim vAn As Variant, vCopy As Variant
 Dim vBlind As Variant, sAnhang As String
 Dim profile As Object
 Dim RTSig As Object
 
 
 On Error GoTo Fehler
 
 sEmpfang = "test@test.de" ' Einträge durch " ; " getrennt
 sBetrifft = "Test"                 ' die Betreffzeile
 sText = "funktioniert es? "                            ' Testtext
 sKopie = " "                       ' Einträge durch " ; " getrennt
  sBlindKopie = " "                  ' Einträge durch " ; " getrennt
  vAn = Split(sEmpfang, " ; ")       ' Empfänger Array
 sAnhang = ""                       ' richtiger Pfad Muss natürlich richtig gesetzt werden
 If Len(sKopie) > 0 Then vCopy = Split(sKopie, " ; ") 'cc Array
 If Len(sBlindKopie) > 0 Then vBlind = Split(sBlindKopie, " ; ")  'bcc Array
 
 
 Set session = CreateObject("Notes.NotesSession") ' Notes muss gestartet sein
 user = session.UserName
 server = session.GetEnvironmentString("MailServer", True)
 mailfile = session.GetEnvironmentString("MailFile", True)
 Set db = session.getdatabase(server, mailfile)
 Set doc = db.createdocument()
 
 doc.form = "Memo"
 doc.sendTo = vAn                                       ' an array
 If Len(sKopie) > 0 Then doc.copyto = vCopy             'cc Array
 If Len(sBlindKopie) > 0 Then doc.blindcopyto = vBlind  'bcc Array
 
 doc.Subject = sBetrifft ' die Betreffzeile
 Set profile = db.GetProfileDocument("CalendarProfile")
 Set RTSig = profile.GetFirstItem("Signature_Rich")
 Set rtitem = doc.CreateRichTextItem("body")
  Call rtitem.AppendText(sText)
 Call rtitem.AddNewLine(2)
 Call rtitem.AppendRTItem(RTSig)

 
 doc.SAVEMESSAGEONSEND = True
 doc.PostedDate = Now
If sAnhang <> "" Then
  Call rtitem.EMBEDOBJECT(1454, "", sAnhang)
End If
rtitem.saveToDisk = True

'*************************
Call doc.Save(True, False)
Call doc.Send(False)
  
Aufraeumen:
 On Error GoTo Fehler
 Set rtitem = Nothing
 Set AttachMe = Nothing
 Set DerAnhang = Nothing
 Set db = Nothing
 Set doc = Nothing
 Set session = Nothing
 Exit Sub
 
Fehler:
 MsgBox "Fehler in Sub Fehler 0 Erste Division" & vbCrLf _
 & "Fehlernummer: " & Err.Number & _
 vbCrLf & "Fehlerbeschreibung: " & Err.Description
 
End Sub



Ich danke allen, die die Geduld mit mir nicht verloren haben und mir echt super geholfen haben, danke euch!

Jetzt versuche ich, den restlichen code einzufügen :)

Navigation

[0] Themen-Index

[#] Nächste Seite

[*] Vorherige Sete