E-Mailversand aus Excel geht mit LN 9 nicht mehr

[koehlerbv]

anbei der Code für die Signatur

Bin kurz mal weg (zum Optiker ...). Sorry.

[Benni1988]

da war ich letzte Woche auch schon.. viel Spaß

Allerdings hast du den Code nicht geschrieben

[jBubbleBoy]

Die E-Mail kommt auch an, sobald ich die leere Fehlermeldung wegdrücke.

Welche Fehlermeldung drückst du weg?

[Benni1988]

die Fehlmermeldung, die nicht definiert ist:

^{Fehlernummer: 0
Fehlerbeschreibung:}

[DerVissi]

Hast du vielleicht vergessen auszusteigen vor dem Errorhandling?

[Benni1988]

Habe den "Fehler" bzw. die Fehler MsgBox hinter aufräumen gesetzt. Das funktioniert jetzt, danke.

Nur die Signatur ist nicht vorhanden. An was kann das liegen?

[koehlerbv]

Wird überhaupt die Text-Signatur im CalendarProfile verwendet oder ist nur RT Signature im Einsatz? Dann bleibt mit dem Code natürlich das Lesen / Schreiben des Signature-Itemvalues folgenlos.

Bernhard

[Benni1988]

wir haben dazu strenge Vorgaben, daher muss ich die Datei über den Server öffnen und dann speichern...

Wenn ich Vorgaben öffne, ist Rich-Text angekreuzt.

[koehlerbv]

Du liest aber das Item für einfachen Text aus ...

[Benni1988]

und wie änder ich das?
Hab jetzt sämtliche Foren überflogen, und entweder verwenden die das so, oder nutzen ein Uidocument

[jBubbleBoy]

Ne das verwendet niemand so, also ich kenne keinen bei dem das so geht
Klasse NotesRichtextItem Methode appendToRTItem ist hier die richtige Wahl.

[Benni1988]

mich hatte mal wieder die Grippe erwischt...

Also nicht wundern, ich suche noch was es mit dem ^{appendToRTItem} auf sich hat...Bin aber noch nicht fündig geworden

Viele grüße

[Benni1988]

also ich verzeifle da jetzt langsam echt...
Und versuche wirklich alle eure Tipps anzuwenden, für die ich auch echt dankbar bin...aber ich bekomme die signatur einfach nicht hin...

[DerVissi]

Es sollte "AppendRTItem" heißen nicht "AppendToRTItem"

https://www.ibm.com/support/knowledgecenter/SSVRGU_9.0.1/com.ibm.designer.domino.main.doc/H_APPENDRTITEM_METHOD.html

[Benni1988]

über dies bin ich auch schon gestolpert, allerdings bin ich als
anfänger hier ratlos, wie ich das für die Signatur anwende.

Leider habe ich nämlich keine weitere Anwendungsbeispiele gefunden

[DerVissi]

So wie ich das verstanden habe, brauchst du folgendes:

1. Zuerst das Profildokument "Calendar Profile"
2. Das Item in dem die RichText Signatur steht "Signature_Rich"
3. Die Signatur bekommst du dann rein mit "Call rtitem.AppendRTItem(das signatur item hier rein)"

[Benni1988]

vielen Dank für deine Hilfe


 ^{Set profile = db.GetProfileDocument("CalendarProfile")
 Set RTSig = profile.GetFirstItem("Signature_Rich")
 Set rtitem = NewNotesRichTextItem(doc, "Body")
 Call rtitem.AppendRTItem(RTSig)}


Wie dir bereits geschrieben, kommt hier die Fehlermeldung

^{Objektvariable oder With-Blockvariable nicht festglegt}

[jBubbleBoy]

verwende "New NotesRichTextItem" anstatt "NewNotesRichTextItem".
Verwende bitte den Excel-Debugger um die Fehlerzeile zu finden.
Schließlich machen wir alle mal Tippfehler, siehe "AppendToRTItem"

[jBubbleBoy]

... da fällt mir wieder ein das du ja Excel-Code schreibst, da funktioniert der New-Operator nicht, aber:
set rt = doc.CreateRichTextItem("Body")

[Benni1988]

also so geht es


 ^{Set profile = db.GetProfileDocument("CalendarProfile")
 Set RTSig = profile.GetFirstItem("Signature_Rich")
 Set rtitem = doc.CreateRichTextItem("body")
  Call rtitem.AppendText(sText)
 Call rtitem.AddNewLine(2)
 Call rtitem.AppendRTItem(RTSig)}


Hier noch einmal der ganze Code


<sup>Option Explicit
 
Sub lotus()

 Dim sText As String, sEmpfang As String, sBetrifft As String
 Dim session As Object, db As Object, doc As Object, rtobject As Object
 Dim rtitem As Object, sKopie As String
 Dim AttachMe As Object, DerAnhang As Object
 Dim user As String, server As String
 Dim mailfile As String, sBlindKopie As String
 Dim vAn As Variant, vCopy As Variant
 Dim vBlind As Variant, sAnhang As String
 Dim profile As Object
 Dim RTSig As Object
 
 
 On Error GoTo Fehler
 
 sEmpfang = "test@test.de" ' Einträge durch " ; " getrennt
 sBetrifft = "Test"                 ' die Betreffzeile
 sText = "funktioniert es? "                            ' Testtext
 sKopie = " "                       ' Einträge durch " ; " getrennt
  sBlindKopie = " "                  ' Einträge durch " ; " getrennt
  vAn = Split(sEmpfang, " ; ")       ' Empfänger Array
 sAnhang = ""                       ' richtiger Pfad Muss natürlich richtig gesetzt werden
 If Len(sKopie) > 0 Then vCopy = Split(sKopie, " ; ") 'cc Array
 If Len(sBlindKopie) > 0 Then vBlind = Split(sBlindKopie, " ; ")  'bcc Array
 
 
 Set session = CreateObject("Notes.NotesSession") ' Notes muss gestartet sein
 user = session.UserName
 server = session.GetEnvironmentString("MailServer", True)
 mailfile = session.GetEnvironmentString("MailFile", True)
 Set db = session.getdatabase(server, mailfile)
 Set doc = db.createdocument()
 
 doc.form = "Memo"
 doc.sendTo = vAn                                       ' an array
 If Len(sKopie) > 0 Then doc.copyto = vCopy             'cc Array
 If Len(sBlindKopie) > 0 Then doc.blindcopyto = vBlind  'bcc Array
 
 doc.Subject = sBetrifft ' die Betreffzeile
 Set profile = db.GetProfileDocument("CalendarProfile")
 Set RTSig = profile.GetFirstItem("Signature_Rich")
 Set rtitem = doc.CreateRichTextItem("body")
  Call rtitem.AppendText(sText)
 Call rtitem.AddNewLine(2)
 Call rtitem.AppendRTItem(RTSig)

 
 doc.SAVEMESSAGEONSEND = True
 doc.PostedDate = Now
If sAnhang <> "" Then
  Call rtitem.EMBEDOBJECT(1454, "", sAnhang)
End If
rtitem.saveToDisk = True

'*************************
Call doc.Save(True, False)
Call doc.Send(False)
  
Aufraeumen:
 On Error GoTo Fehler
 Set rtitem = Nothing
 Set AttachMe = Nothing
 Set DerAnhang = Nothing
 Set db = Nothing
 Set doc = Nothing
 Set session = Nothing
 Exit Sub
 
Fehler:
 MsgBox "Fehler in Sub Fehler 0 Erste Division" & vbCrLf _
 & "Fehlernummer: " & Err.Number & _
 vbCrLf & "Fehlerbeschreibung: " & Err.Description
 
End Sub</sup>



Ich danke allen, die die Geduld mit mir nicht verloren haben und mir echt super geholfen haben, danke euch!

Jetzt versuche ich, den restlichen code einzufügen