Regeln deaktivieren, löschen geht nicht.

[Znarf]

Hei zusammen  

Habe folgende Regel erstellt: "Wenn Inhalt bla, bla, bla, dann verschiebe in Ordner bla"

Habe die Regel deaktiviert und er verschiebt fröhlich weiter

Habe die Regel gelöscht und er verschiebt immer noch fröhlich weiter

Server, Mailschablone und Client ist auf Version 5.0.10

Bei Erstellung der Relgel war der Server auf 5.0.7a, Mailschablone auch glaub auf 5.0.7 und Client mindestens auf 5.0.8.

Danke für eure Tipps  

Franz

[luna]

hallo Znarf,

das hab ich jetzt leider noch niemals gehoert.

aber mal eine frage: hast du nur einen server und nur eine mail datenbank?

oder hast du cluster / replikationen / offline datenbanken?

gruss,
daniela

[Znarf]

Hei Daniela!

Sind noch langsam am Aufbau.

1 x Notesserver mit ca. 400 Usern
1 x Notesapplikationsserver
5 x Server außerhalb mit jeweils 30 Usern

Cluster, Außenstellen im Ausland, und vieles mehr kommt noch  

Das Problem habe ich inzwischen bei einem User und an meinem Client entdeckt.

Gruß

Franz

[DocNotes]

Hi,

das Problem mit den "gelöschten" Regeln hatte ich auch schon mal.

Nach meiner Vermutung existieren die Regeln, wie jedes gelöschte Notes-Dokument, noch als Löschrumpf in der Datenbank.
Wenn die Löschrümpfe entfernt sind, greift die Regel nicht mehr.

Vielleicht hilft diese Information weiter.

Gruß,
DocNotes

[sotonic]

  Jepp, das Problem hatten wir auch. Wie entferne ich Löschrümpfe?  Meistens hat es gereicht die Regel neu zu erstellen & dann zu deaktivieren. Oder kann ich über den Designer was machen?

gruss
sotonic

[DocNotes]

  Folgender Link zu der KnowledgeBase von IBM:

http://www-1.ibm.com/support/docview.wss?rs=203&q=removing%2Bstubs%2Bdeletion&uid=sim1987a0998b5c8e9be852561cc007d5bf9

Zu beachten ist allerdings, dass die Datenbank dann die Löschungen nicht an eine Replik weitergibt, so dass evtl. in einer anderen Replik alte Datensätze erhalten bleiben.  

Deshalb empfehle ich dieses Vorgehen bei Datenbanken, die keine Repliken haben.

[Znarf]

Und noch mal Hei  

Das mit dem Löschschlumpf hat nicht funktioniert. Um den Löschschlumpf zu entfernen, habe ich mir sagen lassen, ich soll auf dem Server über die Datenbank "upd all" laufen lassen. Und super, das ganze hat dann zwei Minuten funktioniert. Die Regel war wech. Client beendet, neu gestartet und Problem ist wieder da. Den Befehl noch mal ein zwei mal laufen lassen, ohne Erfolg.

Die Regel hatte ich aber damals sauber deaktiviert. Stellte das Problem fest und habe danach die Regel gelöscht. Ohne Erfolg. Das ganze ist jetzt schon ein paar Monate her, also können hier überhaupts noch Löschschlümpfe existieren    

Ich hab mir sagen lassen, das die Regeln irgendwo im Kalenderprofil drin wären. Aber ne Ansicht zu erstellen zu lassen, die jenes anzeigt ist natürlich wieder kostenplichtig mit viel Bürokratie  

Please help me  

PS: Ich habe noch eine lokale Replik auf meinem Rechner

[Znarf]

So, endlich geschaft! Hab nen Agenten geschickt bekommen, der alle Regel deaktiviert.

Bis denn

Franzl

[sotonic]

  Will auch haben!
Kannst Du den Agenten einstellen?

[Znarf]

Hei!

Dann mal ran an die Tastatur und feste tippen  



Content:
From what I've read on this forum, and seen messing around in the Mail files, the rules are stored in your Calendar Profile as $FilterFormula_x where x is an integer starting at 0 and moving up.  I had this same problem and wrote a bit of code to try to help me.

' If someone deletes a rule before he/she disables it, this agent will get rid of those.  In so doing, it will also disable any rules that might be active at that time.
Sub Initialize
   Dim ws As New NotesUIWorkspace
   Dim db As NotesDatabase
   Dim profile As NotesDocument
   Dim doc As NotesDocument
   Dim rules As NotesView
   Dim item As NotesItem
   Dim server As String
   Dim DBPath As String
   Dim count As Integer
   
   count = 0
   server = ws.Prompt(PROMPT_OKCANCELEDIT, "Server", "Specify the name of the server that the DB with the bad rules is on.")
   DBPath = ws.Prompt(PROMPT_OKCANCELEDIT, "DB Filepath", "Specify the filepath to the DB that needs to be fixed.")
   Set db = New NotesDatabase(server, DBPath)
   If Not db.IsOpen Then
      Messagebox "The server or DBPath was entered incorrectly." & Chr(10) & "Server: " & server & Chr(10) & "DB Filepath: " & DBPath
      Exit Sub
   End If
   
   Set profile = db.GetProfileDocument("CalendarProfile")
   Set rules = db.GetView("Rules")
   
   ' Disable all of the rules that there are.  Period!!!
   If Not profile Is Nothing Then
      If rules.AllEntries.Count > 0 Then
         Call profile.ReplaceItemValue("$FilterFormulaCount", Cstr(rules.AllEntries.Count))
      Elseif profile.HasItem("$FilterFormulaCount") Then
         Call profile.RemoveItem("$FilterFormulaCount")
      End If
      Forall items In profile.Items
         If items.type = 1536 Then
            If Lcase(Left(items.name,7)) = "$filter" Then
               Call items.remove()
            End If
         End If
      End Forall
      Call profile.Save(True,True,True)
   End If
   ' Mark the bit on every rules document still present in the rules folder for disabled and be sure that the ordernum starts at 0
   Set doc = rules.GetFirstDocument()
   While Not doc Is Nothing
      Call doc.ReplaceItemValue("Enable", "0")
      Call doc.ReplaceItemValue("OrderNum",count)
      count = count + 1
      Call doc.Save(True,False,True)
      
      Set doc = rules.GetNextDocument(doc)
   Wend
   
   Call rules.Refresh()
End Sub


So, viel Spaß damit!  

Grüße

Franzl