Archivierung Rückwärts

[HarryB]

Hallo zusammen,

wir haben für verschiedene Kunden die Mailfilearchivierung aktiviert. Leider hat der IT-Verantwortliche beim Kunden das nicht so genau mit allen, insbesondere den GFs abgesprochen. Nun habe ich eine Anforderung eines GF das Ganze Rückgängig zu machen.

Gibt es ein fertiges Script oder Tool, was mir dabei helfen kann?

Vielen Dank und viele Grüße
Harry

[Driri]

Trag doch einfach in der Archivdatenbank die Maildatenbank als Archiv ein und laß die Archivierung von dort aus laufen. Würde ich aber vorher mal an unkritischen Datenbanken testen 

[jr]

Hallo,

wahrscheinlich kann man die Archivdatenbank selbst wieder in die Originaldatenbank zurückarchivieren. Also die Archivdatenbank des Archivs ist die Originaldatenbank. Müsste eigentlich gehen, hab ich aber noch nicht probiert, also erst einmal mit einer Testdatenbank versuchen.

Wenn das nichts bringt, hab ich vor ein paar Jahren mal eine Funktion geschrieben, mit der Dokumente aus einer Datenbank in eine andere Datenbank kopiert werden und dabei die Dokumente wieder in die richtigen Ordner geschoben werden. Habs schon lange nicht mehr gemacht, aber sollte immer noch funkionieren.

Code

' ************************************************************************************
' Funktion:	CopyDatabaseDocs, CopyDatabaseDocsUI
' Parameter:	sourceDB			Quelldatenbank
'			targetDB			Zieldatenbank
' Rückgabe:	-
'
' Bedeutung:
' ==========
' Mit dieser Funkion werden alle Dokumente aus einer Datenbank in eine andere
' Datenbank kopiert. Hierbei werden die Dokumente in der Zieldatenbank wieder in 
' genau die gleichen Ordner geschoben.
' ************************************************************************************
Sub CopyDatabaseDocs(sourceDB As NotesDatabase, targetDB As NotesDatabase)
	Dim	session				As New NotesSession
	Dim	sourceFolder			As NotesView				' Ordner (und Ansichten) in der Quelle
	Dim	sourceDocs			As NotesDocumentCollection	' Alle Doklumente der Quelle
	Dim	sourceDoc				As NotesDocument			' Aktuelle Kopierdokument in der Quelle
	Dim	targetDocs			As NotesDocumentCollection	' Alle Dokumente für einen Ordner
	Dim	targetDocList			List As NotesDocument		' Alle kopierten Dokumente mit NoteID-Index
	Dim	i					As Long
	Dim	n					As Long
	
	If (sourceDB Is Nothing)  Then Msgbox "Die Quelldatenbank konnte nicht geöffnet werden!", 16, "Fehler": Exit Sub
	If (targetDB Is Nothing)  Then Msgbox "Die Zieldatenbank konnte nicht geöffnet werden!",  16, "Fehler": Exit Sub
	If (Not(sourceDB.IsOpen)) Then Msgbox "Die Quelldatenbank konnte nicht geöffnet werden!", 16, "Fehler": Exit Sub
	If (Not(targetDB.IsOpen)) Then Msgbox "Die Zieldatenbank konnte nicht geöffnet werden!",  16, "Fehler": Exit Sub
	
	' ===============================================================================
	' 1. Alle Dokumente kopieren und Targetliste erstellen
	'    On Error ist notwendig, weil Papierkorbdokumente nicht kopiert werden
	' ===============================================================================
	On Error Resume Next
	Set	sourceDocs			= sourceDB.AllDocuments
	Set	sourceDoc				= sourceDocs.GetFirstDocument()
	n						= sourceDocs.Count
	While (Not(sourceDoc Is Nothing))
		i					= i + 1
		Print "Kopiere Dokument " & i & " / " & n
		Set targetDocList(sourceDoc.NoteID) = sourceDoc.CopyToDatabase(targetDB)
		
		Set sourceDoc			= sourceDocs.GetNextDocument(sourceDoc)
	Wend
	
	' ===============================================================================
	' 2. Alle Ordner durchlaufen und mit Targetliste die Dokumente verschieben
	' ===============================================================================
	n						= Ubound(sourceDB.Views)
	i						= 0
	Forall folder In sourceDB.Views
		i					= i + 1
		Set sourceFolder		= folder
		
		If (sourceFolder.IsFolder) Then
			Print "Aktualisiere Order " & i & " / " & n & ": " & sourceFolder.Name
			Set	targetDocs	= targetDB.Search("@False", Nothing, 0)
			Set	sourceDoc		= sourceFolder.GetFirstDocument()
			While (Not(sourceDoc Is Nothing))
				Call targetDocs.AddDocument(targetDocList(sourceDoc.NoteID))
				
				Set sourceDoc	= sourceFolder.GetNextDocument(sourceDoc)
			Wend
			Call targetDocs.PutAllInFolder(sourceFolder.Name, True)
		End If
	End Forall
End Sub

Ist wieder mal das berüchtigte "On Error Resume Next" drin, aber vielleicht hilt Dir das ja. Kannst den Code ja entsprechend verändern

Gruß,

Joachim

[jr]

Er war einsam, aber schneller...

Gleiche Idee, ein paar Sekunden zu spät

[HarryB]

Danke, Ingo und Joachim.

Die Idee, die Quell- und Zieldatenbank zu vertauschen, hatte ich auch, war mich aber nicht sicher, ob das zielführend ist. Das müsste ich wirklich mal testen. Allerdings ist das nicht ganz so einfach, da die Archivierung per Policy gesetzt wird und die Archiveinstellungen gesperrt sind.

Viele Grüße
Harry

[jr]

Hi,

dann ist die Version mit der Funktion wahrscheinlich am einfachsten. Du kannst die Funktion in einen Button einbinden und den Anwendern als Mail schicken. Die können die Funktion dann manuell ausführen, weil die Archive ja höchstwahrscheinlich lokal liegen.

Gruß,

Joachim

[Jens_1]

Vorsicht!

Die Idee ist den Archivierungsagenten zu benutzen ist sehr gut - ich mache das genauso.
Aber wenn ich der Quelldatenbank noch die Löschrümpfe vorhanden sind dann werden die Dokumente sang- und klanglos gelöscht.
Und da sich das so anhört, als ob das erst vior wenigen Tagen genmacht wurde würde ich erstmal die Löschrümpfe aus der Datenbank entfernen!

Gruß und schönes WE!
Jens

[HarryB]

Danke für den Hinweis, Jens. Wir haben zwar eine Datensicherung, aber die muss man nicht in Anspruch nehmen wollen, weil man dumm ist.

Viele Grüße
Harry

[jr]

Ich glaube, dass die Lösung mit der Archivierung des Archivs nur für einzelne Dateien sinnvoll ist, denn die Archive liegen ja in der Regel lokal und so müsste man praktisch an jeden Rechner gehen.

Das kommte jetzt natürlich auf das Unternehmen an. Bei 10 Usern mag das ja noch machbar sein, aber bei 5000 Clients hat man da eine Menge zu tun...

Und den Benutzern zu erklären, wie sie das machen sollen, dürfte auch nicht unproblematisch sein. Also ich würde die Funktion mit kopierten Dokumenten vorziehen, auch wenn die dann neue Unique-IDs bekommen. Es ist alles wieder da und an der richtigen Stelle.

Vielleicht kann uns ja Harry dann mal sagen, wie er es letztendlich gelöst hat. Würde mich auch interessieren.

Gruß,

Joachim

[HarryB]

Ich glaube, dass die Lösung mit der Archivierung des Archivs nur für einzelne Dateien sinnvoll ist, denn die Archive liegen ja in der Regel lokal und so müsste man praktisch an jeden Rechner gehen.

Bei uns liegen die Archive auf einem Archiv-Server. ...und es geht auch nur um einen einzigen speziellen Benutzer.

Vielleicht kann uns ja Harry dann mal sagen, wie er es letztendlich gelöst hat. Würde mich auch interessieren.

Es ist noch nicht zu 100% sicher, dass ich das umsetzen muss. Aber wenn, werde ich dein Skript nehmen.

Viele Grüße
Harry