Registry Eintrag erstellen

[oson00]

Hallo,

ich möchte per LotusScript die Registry manipulieren und einen neuen Eintrag machen. Ich habe das Ganze bereits per WSH probiert.

Code

	Dim sRegVal As String
	Set oShell = CreateObject("WScript.Shell")  

        call oShell.RegWrite( "HKEY_CURRENT_USER\ScriptEngine\Test", "1" ,"REG_SZ" )

Das Funktioniert auch wunderbar. Ich möchte allerdings nun nicht eine Zeichenfolge "Test" mit dem Wert "1" einfügen, sondern die Zeichenfolge "C:\Programme\Lotus\Notes\nlnotes.exe" mit einem beliebigen Textwert einfügen. Da im Namen der Zeichenfolge nun leider ein "\" vorkommt, kommt das Scrpit damit nicht klar und macht dafür diverse Schlüssel. Über RegEdit.exe kann ich allerdings einen Wert mit einem Pfad-Namen ablegen.

Hat jemand eine Idee wie gehen könnte? Windows-API?

Vielen Dank

OSon00

[m3]

Escapen: \\

[oson00]

Die Idee hatte ich auch. Hat nicht geholfen. Oder ich habe es falsch gemacht. Das müßte dann doch so aussehen, oder?

Code

Dim sRegVal As String
Set oShell = CreateObject("WScript.Shell") 

        call oShell.RegWrite( "HKEY_CURRENT_USER\ScriptEngine\C:\\Programme\\Lotus\\Notes\\nlnotes.exe", "1" ,"REG_SZ" )

[m3]

IMHO auch im Registry-Pfad.

[oson00]

Ja, OK, aber das ändert ja dennoch nichts daran. Ich bekomme dann Einträge, die so aussehen - vielleicht wird das so deutlicher:

Code

| HKEY_CURRENT_USER\
+--+ ScriptEngine\
     +--+ C:\
           +--+ Programme\
                +--+ Lotus
                     +--+ Notes        Hier liegt die Zeichenfolge nlnotes.exe mit dem Wert "1"

Es soll aber so aussehen:

Code

| HKEY_CURRENT_USER\
+--+ ScriptEngine\                 Hier liegt die Zeichenfolge "C:\Programme\Lotus\Notes\nlnotes.exe" mit dem Wert "1"

[y20frank]

Ein ist das Schreiben (Backslash) aufgrund der Einschränkungen der RegWrite Methode von Windows Script Host in einem Schlüsselname oder einem Wertname nicht möglich.

Schau mal hier => http://support.microsoft.com/kb/281309/de

MfG
Frank

[oson00]

Aha, danke!

Ich habe das nun mal Mittels WMI probiert. Hier bekomme ich den Fehlercode 1775 zurück. Weißt Du zufällig auch noch, wo ich nachsehen kann, was der bedeutet?

[Axel]

Schau mal hier: http://www.keysolutions.com/NotesFAQ/canaccess.html


Außerdem habe ich das in "grauer Vorzeit" mal aus dem Web gefischt:

'ClassRegistry:

Option Public
Option Explicit




'// API Constants
Const REG_SZ = 1
Const REG_DWORD = 4

Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_USERS = &H80000003

Const ERROR_NONE = 0
Const ERROR_BADDB = 1
Const ERROR_BADKEY = 2
Const ERROR_CANTOPEN = 3
Const ERROR_CANTREAD = 4
Const ERROR_CANTWRITE = 5
Const ERROR_OUTOFMEMORY = 6
Const ERROR_INVALID_PARAMETER = 7
Const ERROR_ACCESS_DENIED = 8
Const ERROR_INVALID_PARAMETERS = 87
Const ERROR_NO_MORE_ITEMS = 259

Const KEY_ALL_ACCESS = &H3F
Const REG_OPTION_NON_VOLATILE = 0
Const REG_PARAMETER_IS_RESERVED = 0
Const REG_DEFAULT_VALUE = ""

Const cMAXLEN_BUFFER = 255

'// API Declarations
Declare Function RegCloseKey Lib "advapi32.dll" (Byval hKey As Long) As Long
Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (Byval hKey As Long, Byval lpSubKey As String, Byval ulOptions As Long, Byval samDesired As Long, phkResult As Long) As Long
Declare Function RegQueryValueExString Lib "advapi32.dll" Alias "RegQueryValueExA" (Byval hKey As Long, Byval lpValueName As String, Byval lpReserved As Long, lpType As Long, Byval lpData As String, lpcbData As Long) As Long
Declare Function RegQueryValueExLong Lib "advapi32.dll" Alias "RegQueryValueExA" (Byval hKey As Long, Byval lpValueName As String, Byval lpReserved As Long, lpType As Long, lpData As Long, lpcbData As Long) As Long
Declare Function RegQueryValueExNULL Lib "advapi32.dll" Alias "RegQueryValueExA" (Byval hKey As Long, Byval lpValueName As String, Byval lpReserved As Long, lpType As Long, Byval lpData As Long, lpcbData As Long) As Long
Declare Function RegSetValueExString Lib "advapi32.dll" Alias "RegSetValueExA" (Byval hKey As Long, Byval lpValueName As String, Byval Reserved As Long, Byval dwType As Long, Byval lpValue As String, Byval cbData As Long) As Long
Declare Function RegSetValueExLong Lib "advapi32.dll" Alias "RegSetValueExA" (Byval hKey As Long, Byval lpValueName As String, Byval Reserved As Long, Byval dwType As Long, lpValue As Long, Byval cbData As Long) As Long


Const cREG_COMPONENTS_PATH = "Software\Lotus\Lotus Components\1.0"
Const cREG_COMPONENTS_KEYNAME = "LoaderPath"

Class Registry

'// Declare Member Varaibles
Private hkey As Long

'// Declare Member Code
Declare Public Function GetValue( ItemName$ ) As String
Declare Public Function SetValue( ValueName As String, lType As Long, vValue As Variant) As Long

'// Constructor
Sub New( Section, KeyName$ )
Call RegOpenKeyEx(Section, KeyName$, REG_PARAMETER_IS_RESERVED, KEY_ALL_ACCESS, Me.hKey)
End Sub

'// Destructor
Sub Delete()
Call RegCloseKey (Me.hKey)
End Sub

Public Function GetValue( ItemName$ ) As String
Dim sData As String
Dim lpcbData As Long
Dim lpType As Long

'// First we initialize the buffer
sData = String(cMAXLEN_BUFFER, 0)
lpcbData = Len(sData)

'// Get it
Call RegQueryValueExString( Me.hKey, ItemName$, REG_PARAMETER_IS_RESERVED, lpType, sData, lpcbData)

'// Return
GetValue = Left( sData, Instr( 1, sData, Chr$(0) )-1)


End Function

Public Function SetValue( ValueName As String, lType As Long, vValue As Variant) As Long
Dim lValue As Long
Dim sValue As String

Select Case lType
Case REG_SZ

'//sValue gets assigned the value vValue
sValue = vValue

'// Set value to Windows registry using a string type
SetValue = RegSetValueExString( Me.hKey, ValueName, 0&, lType, sValue, Len(sValue))

Case REG_DWORD

'// IVlale gets assigned the value in vValue
lValue = vValue

'// Set value to Windows registy using a Long variable type
SetValue = RegSetValueExLong( Me.hKey, ValueName, 0&, lType, lValue, 4)
End Select

End Function

End Class
Sub Initialize

End Sub
Sub Terminate

End Sub

Axel

[oson00]

Deine Klasse ist Gold Wert! Das funktioniert! Vielen Dank!!!