Das Feld EmployeeID ist ein Textfeld.
Da folgende Script kannst Du als Grundlage verwenden. Packe es bspw. in einen Button, den Du per Mail an die User sendest.
Dim session As NotesSession
Dim db As NotesDatabase
Dim nab As NotesDatabase
Dim dc As NotesDocumentCollection
Dim nabdoc As NotesDocument
Dim searchstring As String
Dim persnr As String
Set session = New NotesSession
Set db = session.CurrentDatabase
Set nab = New NotesDatabase( "", "" )
Call nab.Open( db.Server, "names.nsf" )
If Not nab.IsOpen Then
Msgbox "Das Adressbuch konnte nicht geöffnet werden!",0+16,"Abbruch"
Exit Sub
Elseif nab.Server = "" Then
Msgbox "Diese Aktion darf nicht lokal ausgeführt werden!",0+16,"Abbruch"
Exit Sub
End If
'Eingabe der Pers.Nr.
persnr = Inputbox$("Geben Sie die Personalnummer ein:","Personalnummer","")
If persnr = "" Then
Msgbox "Sie haben keine Personalnummer eingegeben!",0+16,"Abbruch"
Exit Sub
End If
'Suche User im NAB
searchstring = |Form = "Person" & @Subset(FullName;1) = "| + session.Username + |"|
Set dc = nab.Search( searchstring, Nothing, 0 )
If dc.Count = 0 Then
Msgbox "Es wurde kein Personendokument gefunden!",0+16,"Abbruch"
Exit Sub
End If
'Schreibe neue Pers.Nr.
Set nabdoc = dc.GetFirstDocument
nabdoc.EmployeeID = persnr
Call nabdoc.Save( False, False, True ) 'Speichern, kein Konflikt erzeugen
Msgbox "Die Personalnummer wurde eingetragen!",0+64,"Hinweis"
Alle Angaben ohne Gewähr !!!
Andreas
