Alter berechnen

[Notestime]

Hallo!

Wie kann ich in Formelsprache ein Alter berechnen?

Also ich hab in Feld1 das Geburtsdatum als Date/Time Value und ich möchte im brechneten Feld2 das aktuelle alter stehen haben.

Kann mir jemaand helfen?

Danke und Gruß
bernd

[eknori]

_dateOfBirth:="21.10.1959";
_age:=(@TextToNumber(@Text(@TextToTime("Today") - @Date(@TextToTime(_dateOfBirth)))) / 86400) / 365;
@Prompt([Ok];"Alter";@Text(@Integer(_age)))

[Notestime]

Danke!!! Funktioniert Super!
 

[Thomas Schulte]

Aber nur wenn du in diesem Jahr nach dem  12.01.1959 geboren worden bist.

Thomas

[HarryB]

Um keine Probleme mit Schaltjahren und älteren Leuten zu bekommen, kann man das auch wie folgt lösen:

------

 _dateOfBirth:=@TextToTime("21.10.1959");
_age:=@If(@Month(@Today) > @Month(_dateOfBirth);@Year(@Today) - @Year(_dateOfBirth);
    @Month(@Today) < @Month(_dateOfBirth);@Year(@Today) - @Year(_dateOfBirth)-1;
    @If(@Day(@Today) >= @Day(_dateOfBirth);@Year(@Today) - @Year(_dateOfBirth);@Year(@Today) - @Year(_dateOfBirth) - 1));
@Prompt([Ok];"Alter";@Text(@Integer(_age)))

------

Viele Grüße
Harry

[billygates]

Oder auch so (als Formel in einem berechneten Datumsfeld):

datum := [21.10.1959];
tmp1   := @Date(@Year(@Now);@Month(datum);@Day(datum));
tmp2   := (@Now-tmp1)/86400;
tmp3   := @Year(@Now) - @Year(datum);
@If(tmp2 > -1; tmp3; tmp3 - 1)

[koehlerbv]

Achtung - in unten stehender Formel ist ein böser Bug!
Im Beitrag 21 http://atnotes.de/index.php?PHPSESSID=7594h1jjplgptfnvqalc3tcal4&topic=18281.msg359788#msg359788
wird eine korrigierte Fassung dargestellt und auf das Verhalten von @Date, dem 29. Februar und Nicht-Schaltjahren hingewiesen.

BK, 28.02.2013



Warum nicht als Zweizeiler?  

BirthDay sei das Feld mit dem Geburtsdatum, ActDate das Feld mit dem aktuellen Bezugsdatum (was man ggf. durch @Today ersetzen kann). Age ist (in diesem Fall) das berechnete Feld zur Ausgabe des Alters.

Die erste Zeile des berechneten Feldes prüft zunächst, ob man überhaupt etwas berechnen kann. Dies ist ebenso in einer Aktion mit Ausgabe via @Prompt verwendbar.

Die zweite Zeile berechnet stur das die Jahre von Birthdate bis ActDate. Dumm, wenn Birthday = 11.07.1990 und ActDate = 19.01.2008 - die Person ist dann (ungerechtfertigterweise) schon wehrdienstpflichtig.

Die zweite Zeile normiert Birthday dann auf das Jahr von ActDate (aus 11.07.1990 wird so 11.07.2008), vergleicht dies mit ActDate und reduziert das Alter dann gegebenenfalls um ein Jahr. Ergebnis: Mein Sohn darf heute noch nicht zum Bund einberufen werden  

Code

@If (!@IsTime (Birthday) | !@IsTime (ActDate); @Return (Age); "");
_Age1 := @Year (Actdate) - @Year (Birthday);
@If (@Date (@Year (ActDate); @Month (Birthday); @Day (Birthday)) > ActDate; _Age1 - 1; _Age1)

Bernhard

PS: Mehr dazu auf dem EntwicklerCamp am 27. Februar 2008

[billygates]

Zweizeiler??? Also ich kann zählen und komme auf 3! 

[klaussal]

Wenn man bei 0 anfängt zu zählen, dann passt es wieder... 

[koehlerbv]

Die erste Zeile gehört ja "eigentlich" nicht dazu und dient nur der Ordnung und Sauberkeit im Schlachthof 
Und Zeile 2 kann man mit Zeile 3 kombinieren (und dann das Konstrukt aus der neuen Zeile statt der "" in der ersten Zeile einsetzen. Dann hat man einen Einzeiler (kann ihn aber nicht mehr lesen  )

Bernhard

[billygates]

So in etwa also:

datum := [21.10.1959];
@If(@Now-@Date(@Year(@Now);@Month(datum);@Day(datum)))/86400 > -1; @Year(@Now) - @Year(datum); @Year(@Now) - @Year(datum) - 1)

[koehlerbv]

Da fehlt die entscheidende Prüfung auf @IsTime. Davor muss also noch
@If (!@IsTime (Birthday) | !@IsTime (ActDate); @Return (Age); ..............)

[billygates]

Uah, ich bin müde...

[Fineas]

Als Einzeiler hätte ich auch noch eine simple Lösung im Angebot:

@If(@Month(d2) * 31 + @Day(d2) >= @Month(d1) * 31 + @Day(d1); @Year(d2)-@Year(d1); @Year(d2)-@Year(d1) - 1 )

Zwei Datumsfelder d1 und d2, ein berechnetes Ergebnisfeld mit der Formel.

Selbstverständlich korrekterweise mit Validierung:

@if(@IsTime(d1) & @IsTime(d2); ... ;"gibts nicht!")

[iukhdh]

Und was haltet ihr von meiner Einzeilerlösung?

@If(geburtsdatum="";"unbekannt";@Round(((@Year(@Today)*10000+@Month(@Today)*100+@Day(@Today))-(@Year(Geburtsdatum)*10000+@Month(Geburtsdatum)*100+@Day(Geburtsdatum)))/10000))

[koehlerbv]

Nix.

Bernhard

[iukhdh]

Schade. 

Und warum nicht?

[koehlerbv]

Du änderst die Dimensionen von Datums-/Zeit-Werten und rundest dann. Dazu Schaltjahre, @Year ("unbekannt") kommt gar nicht gut und ... wird mir jetzt zu lang.

Bernhard

[iukhdh]

Ups,
das kommt davon, wenn man sich zu einem Schnellschuss hinreissen lässt und auswendig eine alte Idee wieder aufwärmt, die ich in einer berechneten Spalte einer Ansicht verwende. Passt daher nicht ganz zu der Ausgangsfrage mit den Feldern, muss ich zugeben.

Natürlich darf ich nicht kaufmännisch runden, sondern muss immer abrunden.

Also
@If(geburtsdatum="";"unbekannt";@integer(((@Year(@Today)*10000+@Month(@Today)*100+@Day(@Today))-(@Year(Geburtsdatum)*10000+@Month(Geburtsdatum)*100+@Day(Geburtsdatum)))/10000))

Und du meinst, das funktioniert bei Schaltjahren nicht? ... Muss ich echt mal nachprüfen, bisher war ich der Meinung dass das klappt. Aber jetzt bin ich schon etwas verunsichert ... ob ich heute Nacht gut schlafe?

 

[koehlerbv]

Thomas, Du bist auf dem falschen Dampfer.

Ad a) Hier im Thread wurde gutes bereits gepostet und entsprechend bewertet. Du treibst jetzt eine neue Sau durchs Dorf. Wozu? Zur Überprüfung durch uns - das ist okay und sicherlich auch Deine Intention. Das wäre gut.

Ad b) Deine Formel ist ... untauglich. Wenn Martin Leyrer Dein Post bisher schon gelesen hätte, würde er vermutlich mit einem "Schrei" antworten: "***BERNHARD***!!!" Weil:
Man verarbeitet Datums-/Zeitwerte *IMMER* als Datums-/Zeitwerte und "verwurstet" diese nicht.

Der Murks geht los mit

Code

@If(geburtsdatum="";"unbekannt";

Das Item Geburtsdatum sollte (für den Rest Deines Codes) ein Datums-/Zeitwert sein. Und dann prüftst Du gegen einen **STRING**? Geht's noch? Das geht dank der Freundlichkeit von Notes in diesen Dingen x mal gut - bei x + 1 knallt es dann: Weit hergeholt, aber (auch) in Notes möglich: Dort steht kein Datums-/Zeitwert oder auch nicht "nichts" (scheinbar!!), sondern "An einem schönen Tag im Mai". Da scheppert es dann heftig - obwohl das doch so schön formuliert war 

Der Murks geht weiter mit der Alternative: Nix Geburtsdatum, also wird mit dem String "unbekannt" "gerechnet". Hast Du das schon mal ausprobiert)? @Year ("unbekannt")?

Ich finde das Einbringen Deiner Idee sehr gut. Das ist einer der Dinge, wofür wir hier bei AtNotes stehen - Dinge diskutieren. Du betreibst das in einer hervorragenden Art und Weise (und wir alle wissen, dass Notes-Programmierung gar nicht Dein Hauptaufgabengebiet ist). Bleib uns bitte in dieser Art gewogen. Bitte! Aber Dein geposteter Code ist einfach ... vollkommen unbrauchbar.

Ich hoffe sehr, Du verstehst meine Replik (bitte) nicht falsch.

Bernhard

PS: Vor 15 oder 16 oder 17 Jahren habe ich mir genau mit einer solchen Idee wie Deiner ganz übel ein "Kuckucksei" ins Nest gelegt. Damals gab es aber AtNotes oder vergleichbares noch nicht