Domino 9 und frühere Versionen > ND6: Administration & Userprobleme

Nach löschen der Anhänge bleiben die Mails gross...

<< < (2/3) > >>

TMC:
Hi Martin,

evtl. hilft es, alle Items "$FILE" rauszuwerfen.

Den Agenten kannst Du Dir hierzu easy zusammenkopieren, siehe BP "Agenten in Notes/Domino", Kap. 9.3. Theoretisch kann den Agenten dann auch ein DAU bedienen: Einfach Doks in der View markieren und ab geht's.

Wenn das nicht hilft, fällt mir als Lösung nur noch ein, per Script ein neues Doc zu erstellen und alle benötigten Items rüberzuschaufeln, dann Doc speichern. Danach altes Doc löschen. Kann Dir da gerne dabei helfen.

MartinG:
Hallo Matthias,

vielen Dank für Deine Hilfe. Mit einfachen Agenten (Formel und Simple Actions) habe ich es schon versucht, was aber nicht funktioniert hat.

Habe nun mal mit Deiner ausgezeichneten Anleitung einen Script Agent zusammenkopiert welcher aber leider auch nicht funktioniert. Kann das sein das dies nicht auf interne Feldnamen wie $File reagiert? Oder habe ich da einen grundsätzlichen Denkfehler?

Gruss
Martin

PS: @Matthias - ich kann Dir auch gerne mal ein solches Mail in einer leeren DB mailen....

MartinG:
Mit dem Agenten hat es nicht geklappt - habs jetzt aber hinbekommen $File zu löschen mit FieldControl....

Ist ein ganz praktisches Tool: http://fieldcontrol.commed.ru/ - ich weiss nicht ob es allen hier bekannt ist...

Gruss
Martin

PS: Eine praktikable userfreundliche Lösung ist das allerdings nicht...

TMC:
Hab erst jetzt Deine Antworten gesehen.


--- Zitat von: MartinG am 07.07.04 - 13:05:31 ---PS: Eine praktikable userfreundliche Lösung ist das allerdings nicht...
--- Ende Zitat ---

OK, here you go  ;)


--- Code: ---Sub Initialize
   
   On Error Goto ERRORHANDLER
   
   Dim session As New NotesSession
   Dim db As NotesDatabase
   Dim collection As NotesDocumentCollection
   Dim doc As NotesDocument
   Dim item As NotesItem
   Dim vDeleteItems As Variant
   Dim strMsg As String   
   Set db = session.CurrentDatabase
   Set collection = db.UnprocessedDocuments
   
   If collection.Count <1 Then
      Msgbox "Um diese Aktion auszuführen, muss mind. 1 Dokument ausgewählt sein.", 48, "Kein Dokument ausgewählt"
      Exit Sub
   End If
   
   'Are you sure???
   strMsg = "Du hast " & collection.Count & " Dokument(e) ausgewählt." & Chr(10) _
   & "Möchtest Du wirklich diese Dokument(e) bereinigen?"
   If Not Messagebox (strMsg,1 + 32,db.title) = 1 Then Exit Sub
   
   Set doc = collection.GetFirstDocument
   
   '-----> Items to remove
   Redim vDeleteItems(20)
   vDeleteItems(0) = "$FILE"
   '........and so on.........
   '<-----
   
   While Not(doc Is Nothing)
      Forall i In vDeleteItems
         While (doc.HasItem(i))
            Set item = doc.GetFirstItem(i)
            Call item.Remove
            Call doc.Save(True, True)
         Wend
      End Forall      
      Set doc = collection.GetNextDocument(doc)
   Wend
   
   Msgbox collection.Count & " E-Mails wurden bereinigt.", 64, db.Title
   
   
EXIT_SCRIPT:
   Exit Sub
   
ERRORHANDLER:
   Msgbox "Error: " & Err & " - " & Error$ & Chr(10) & Chr(10)_
   & "Procedure: Agent 'Bereinige E-Mails'"& Chr(10) & Chr(10)_
   & "Line: " & Erl & Chr(10), _
   48, "An error occured"
   Resume EXIT_SCRIPT
   
   
End Sub
--- Ende Code ---


Kopiere den Code in einen Agenten (Trigger: On Event, Target: All selected docs).

Habs gerade in einer Mail-DB getestet: Klappt wunderbar, löscht gnadenlos alle $FILE - Items der ausgewählten Dokumente.

Macht dann 1 Bier, bitte  ;D

Y Y

Prost,
Matthias

MartinG:
Genial - dafür gebe ich auch zwei Bier aus  :) :) :)

Navigation

[0] Themen-Index

[#] Nächste Seite

[*] Vorherige Sete