Domino 9 und frühere Versionen > Entwicklung

eMail per Script

(1/3) > >>

Thunder:
noch mal was einfaches...
Habe in einer Maske ein Feld, in dem mehrere eMail-Adressen gespeichert sind.(Mehrfachwerte !) Jetzt möchte ich über einen Button realisieren, daß diese Adressen automatisch in das 'An:' Feld eingetragen werden. Leider nimmt Notes nur die 1. Adresse. Wo liegt das Problem ?


Sub Click(Source As Button)
   Dim workspace As New NotesUIWorkspace
   Dim session As New NotesSession
   Dim db As NotesDatabase
   Dim doc As NotesDocument
   Dim TheDocument As NotesDocument
   Dim eigener As String
   Dim server As String
   Dim Adresse As String
   Dim Text As String
   
   eigener = session.GetEnvironmentString ("MailFile", True)
   server = session.GetEnvironmentString ("MailServer", True)
   Set uidoc = Workspace.CurrentDocument
   Set TheDocument = uidoc.document
   Set db = New Notesdatabase (server, eigener)
   Set doc = db.createDocument
   
   Adresse = uidoc.FieldGetText("par_eMail")
   Text = "eMail"
   
   doc.Form = "Memo"
   doc.Subject = Text
   doc.SendTo = Adresse
   Call workspace.EditDocument (True, doc)
End Sub

klaussal:
... die einzelnen einträge im feld par_eMail mit "forall" durchgehen (beispiel in der designer-hilfe)..

koehlerbv:
Mehrfachwerte musst Du im Backend holen, also zum Bleistift so:
doc.SendTo = uidoc.Document.par_eMail

HTH,
Bernhard

Axel:
Hi,


versuch's mal so:

Sub Click(Source As Button)
   Dim workspace As New NotesUIWorkspace
   Dim session As New NotesSession
   Dim db As NotesDatabase
   Dim doc As NotesDocument
   Dim TheDocument As NotesDocument
   Dim eigener As String
   Dim server As String
   Dim Adresse As Variant
   Dim Text As String
   
   eigener = session.GetEnvironmentString ("MailFile", True)
   server = session.GetEnvironmentString ("MailServer", True)
   Set uidoc = Workspace.CurrentDocument
   Set TheDocument = uidoc.document
   Set db = New Notesdatabase (server, eigener)
   Set doc = db.createDocument
   
   Adresse = TheDocument.par_eMail
   Text = "eMail"
   
   doc.Form = "Memo"
   doc.Subject = Text
   doc.SendTo = Adresse
   Call workspace.EditDocument (True, doc)
End Sub

oder einfacher:

...
doc.SendTo = TheDocument.par_eMail
...

Axel

Thunder:
Mit folgender Lösung funktioniert es:

Sub Click(Source As Button)
   Dim workspace As New NotesUIWorkspace
   Dim session As New NotesSession
   Dim db As NotesDatabase
   Dim doc As NotesDocument
   Dim TheDocument As NotesDocument
   Dim eigener As String
   Dim server As String
   Dim Adresse As Variant
   Dim Text As String
   
   eigener = session.GetEnvironmentString ("MailFile", True)
   server = session.GetEnvironmentString ("MailServer", True)
   Set uidoc = Workspace.CurrentDocument
   Set TheDocument = uidoc.document
   Set db = New Notesdatabase (server, eigener)
   Set doc = db.createDocument
   
   Adresse = TheDocument.par_eMail
   Text = "eMail aus dem Telefonbuch"
   
   doc.Form = "Memo"
   doc.Subject = Text
   doc.SendTo = uidoc.Document.par_eMail
   Call workspace.EditDocument (True, doc)
End Sub

Besten Dank und grosses Lob an dieses Forum !

Navigation

[0] Themen-Index

[#] Nächste Seite